小誌

　暱稱: 小誌
　頭銜: 曾經也是水電工

帖子: 1193
主題: 394
精華: 113
積分: 1747
點名: 1
作業系統: Vista
軟體版本: Office 2003
閱讀權限: 200
性別: 男
來自: 台灣
註冊時間: 2010-5-1
最後登錄: 2024-12-20

2021牛年全勤獎章好學求知勳章熱烈參與勳章 2017 雞年全勤獎章 2018 狗年全勤獎章 2019 豬年全勤獎章 2020鼠年全勤獎章

1^# 跳轉到 » 倒序看帖

打印

字體大小: tT

發表於 2010-5-26 00:43 | 只看該作者

[教學] (實戰專題) 資料庫聯絡簿中篇

留言顯示網頁的管理模式
我們的『家庭聯絡簿』因為必須具備發言內容涉及敏感話題或是涉及私人隱私的家長發言可用『悄悄話』的方式發言與顯示，同時也希望老師能針對某位特定學生家長所發表的意見作出獨立的回應，因此，我們『顯示留言意見』的網頁就必須具備顯示模式選擇的功能，當顯示模式在一般情況時要能顯示家長們的一般性發言，同時還得將『悄悄話』的發言隱藏起來：

當老師以密碼登入成為管理模式時，則必須將一般性發言與悄悄話發言的資料全部顯示出來，同時還得讓老師們可以針對某位特定學生家長所發表的意見作出獨立的回應：

密碼登入管理模式的ASP程式

您應該發現到：當我們在一般顯示模式時(不會顯示悄悄話的發言)，在網頁最下方將會有一個輸入密碼進入『教師管理』模式的欄位，而當我們以密碼登入管理模式時，則在網頁最下方會有一個『離開管理模式』的按鈕！

我們先來看看這兩個情況是如何產生的，請先檢視下列這段網頁敘述：

<form method="post">
<%IF session("checkedit")="yes" then%>
<input type="hidden" value="yes" name="goexit">
<input type="submit" value="離開管理模式">
<%else%>
密碼：
<input type="text" name="password"
size="4"maxlength="4">
&nbsp&nbsp<input type="submit" value="教師管理">
<%End IF%>
</form>

複製代碼

在上面這段網頁敘述中，我們可以清楚的知道要顯示一般模式或管理模式，完全得靠一個Session物件來決定！Session 物件為紀錄使用者的相關資訊，提供使用者再次對此網頁伺服器要求時作確認，例如使用者帳號與密碼的確認，有 Session 物件的建立，來保留身分認證的結果，則使用者不用於每一頁網頁登錄時都需輸入密碼作確認。在本範例中，我們則利用Session物件來記錄目前的工作模式。

　既然我們是利用Session物件來記錄目前的工作模式，那我們該如何變更Session物件記錄的『變數』值呢？很容易！請接著來看看我們管理模式的ASP程式：

'以下為進入管理模式的敘述
password=Request.Form("password")
IF password="test" then '<-----管理密碼
session("checkedit")="yes"
End IF
'以下為脫離管理模式的程式敘述
goexit=Request.Form("goexit")
IF goexit="yes" then
session("checkedit")="no"
End IF

複製代碼

當我們第一次進入『顯示留言意見』網頁的時候，我們所見的網頁畫面一定是一般模式！為什麼？因為Session尚未被建立，因此它的『變數』值一定不會是"yes"，所以網頁中會出現一個輸入密碼進入『教師管理』模式的欄位，只有當我們輸入密碼按下『教師管理』的按鈕引發ASP程式中的進入管理模式敘述後，Session物件才會被建立，同時，『checkedit』Session物件變數值被設定為"yes"，所以我們就進入了能將一般性發言與悄悄話發言的資料全部顯示出來，同時還讓老師們可以針對某位特定學生家長所發表的意見作出獨立回應的管理模式頁面。

當我們進入管理模式頁面後，你將發現網頁最下方，原本的密碼登入欄位不見了，而以『離開管理模式』的按鈕取代，這是因為Session物件被建立了，而且變數值被設定為"yes"，網頁中的敘述就變為：

<input type="hidden" value="yes" name="goexit">
<input type="submit" value="離開管理模式">

複製代碼

在我們要脫離管理模式而按下『離開管理模式』的按鈕後，則會引發脫離管理模式的ASP程式敘述：

'以下為脫離管理模式的程式敘述
goexit=Request.Form("goexit")
IF goexit="yes" then
session("checkedit")="no"
End IF

複製代碼

此時我們將回到一般模式的頁面，而且Session物件變數值被設定為"no"，網頁中的敘述就變為：

<input type="text" name="password" size="4"
maxlength="4">
&nbsp&nbsp<input type="submit" value="教師管理">

複製代碼

而網頁中的『離開管理模式』按鈕，也就變回輸入密碼進入『教師管理』模式的欄位。

提示
這個控制顯示模式的Session物件非常重要，它不僅是控制我們的顯示模式，同時我們還將利用它的變數值來決定是否顯示學生家長的悄悄話發言內容！

樓主熱帖

心安，平安
發表任何無意義的感謝或灌水文章一律砍,珍惜帳號,請詳閱版規!!

小誌

　暱稱: 小誌
　頭銜: 曾經也是水電工

管理員 Rank: 9 Rank: 9 Rank: 9

帖子: 1193
主題: 394
精華: 113
積分: 1747
點名: 1
作業系統: Vista
軟體版本: Office 2003
閱讀權限: 200
性別: 男
來自: 台灣
註冊時間: 2010-5-1
最後登錄: 2024-12-20

2021牛年全勤獎章好學求知勳章熱烈參與勳章 2017 雞年全勤獎章 2018 狗年全勤獎章 2019 豬年全勤獎章 2020鼠年全勤獎章

2^#

發表於 2010-5-26 00:53 | 只看該作者

留言顯示網頁的分頁

到現階段，我們已經完成『顯示留言意見』網頁的『管理模式』處理與『資料庫資料讀取』的ASP程式撰寫。現在我們接著進行『顯示留言意見』網頁的分頁瀏覽程式撰寫。

還為何需要進行分頁瀏覽？因為當家長的發言與老師回覆的資料筆數太多時，一次要將全部的資料內容顯示在網頁中，光是等待網頁下載的時間就嚇死人了，因此我們最好是採用固定筆數分頁瀏覽的方式來顯示網頁。

要進行分頁顯示，首先我們得先知道目前有多少筆的留言資料，而這些留言資料筆數可分解成幾個頁次來瀏覽，要想資料資料檔案中目前有幾筆資料錄，我們可以透過Recordset物件的『RecordCount』屬性得知，例如：本例中我們將每１０筆資料為一單位分頁顯示：

'資料總數Count,總頁數TotalPage
Count=RS.RecordCount
If Count/10 > (Count10) then
TotalPage=(Count10)+1
else TotalPage=(Count10)
End If

複製代碼

我們先利用變數『Count』來記錄資料庫檔案中共有多少筆資料這個總筆數我們將顯示在網頁中，要知道總共有多少頁(TotalPage)我們只要以簡單的數學算式即可得之，請參考上列表格中的敘述。

跳頁選擇的ASP程式敘述

當我們將所有的發言資料採用固定筆數分頁瀏覽的方式來顯示後，最好提供一個跳頁連結顯示的功能，讓瀏覽者可以選擇希望瀏覽的頁次進行瀏覽，因此，我們必須再撰寫一段可以指定瀏覽頁次的ASP程式敘述：

PageCount= 0
RS.MoveFirst
If Request.QueryString("ToPage")<>"" then
PageCount = cint(Request.QueryString("ToPage"))
End If
If PageCount <=0 then PageCount = 1
If PageCount > TotalPage then PageCount = TotalPage
RS.Move (PageCount-1) * 10

複製代碼

在這段指定瀏覽頁次的ASP程式敘述中，我們使用了Recordset物件的『Move』方法來移動資料庫中資料錄的存取位置。

顯示跳頁選擇的程式敘述

完成移動資料庫中資料錄存取位置的Asp程式敘述後，接下來我們要作的就是將這些跳頁選擇的連結資料顯示在網頁中：

在網頁中出現的跳頁選擇列表，瀏覽者正進行瀏覽的頁次將不會有跳頁選擇的超連結功能！非瀏覽中的頁次才具有跳頁選擇的超連結功能！要有這樣的功能，我們則可特過下列這段ASP程式敘述來達成。

<%
for i=1 to TotalPage
If i<>PageCount then
Response.Write "<font color=black>｜</font>
<a href=guest.asp?topage="& i &"><font color=#cb55cc>" & i & "</font></a><font color=black>｜</font>"
else
Response.Write "<font color=black>｜</font>
<font color=#000000>"&i&"</font><font color=black>｜</font>"
end if
next
%>

複製代碼

心安，平安
發表任何無意義的感謝或灌水文章一律砍,珍惜帳號,請詳閱版規!!

TOP

小誌

　暱稱: 小誌
　頭銜: 曾經也是水電工

管理員 Rank: 9 Rank: 9 Rank: 9

帖子: 1193
主題: 394
精華: 113
積分: 1747
點名: 1
作業系統: Vista
軟體版本: Office 2003
閱讀權限: 200
性別: 男
來自: 台灣
註冊時間: 2010-5-1
最後登錄: 2024-12-20

2021牛年全勤獎章好學求知勳章熱烈參與勳章 2017 雞年全勤獎章 2018 狗年全勤獎章 2019 豬年全勤獎章 2020鼠年全勤獎章

3^#

發表於 2010-5-26 00:57 | 只看該作者

完整的留言顯示網頁
終於完成了『顯示留言意見』網頁中各項功能的ASP程式撰寫，最後就簡單的來為您解說一下『資料顯示』的處理原則，我們以『發言內容』為例來說明。

我們如何判斷要不要將『悄悄話』的發言內容顯示出來？有兩個判斷原則：第一為確認是不是在『管理模式』，如果是在管理模式就得將『悄悄話』的發言內容顯示出來，第二就是如果在『一般模式』的時候判斷發言性質是不是『悄悄話』，因此是，則發言的內容就以預設的文字內容代替：

<% IF RS("私人公開") = "NO" OR
session("checkedit")="yes" THEN%>
<font color="#FF0080">留言主題：</font>
<font color="#0000FF"><%=RS("留言主題")%></font>
<br><font color="#000000"><%=RS("留言內容")%></font>
<%ELSE%>
<FONT COLOR=BLUE>:) 這是留給老師的悄悄話...</FONT>
<br><font color="#FF00F00">私人討論</font>
<%END if%>

複製代碼

我們先利用IF判斷資料庫檔案中『私人公開』欄位中的資料內容是否是"NO"，如果為"NO"代表並不是『悄悄話』的發言，則開將發言內容公開出來，又或者Session物件的變數"checkedit"值為"yes"，如果Session物件的變數值為　"yes"，代表在管理模式，就必須將『悄悄話』的發言顯示出來：

guest.asp

<%
'*************開啟資料庫message.mdb
Set CN = Server.CreateObject("ADODB.Connection")
CN.Open "Driver={Microsoft Access Driver (*.mdb)};DBQ="&Server.MapPath("message.mdb")
Set RS=Server.CreateObject("ADODB.Recordset")
SQL="SELECT*From allmessage order by 留言日期 Desc"
RS.Open SQL,CN,1,1
'**************顯示頁選擇與分頁設定
'資料總數Count,總頁數TotalPage
Count=RS.RecordCount
If Count/10 > (Count\10) then
TotalPage=(Count\10)+1
else TotalPage=(Count\10)
End If
PageCount= 0
RS.MoveFirst
if Request.QueryString("ToPage")<>"" then PageCount = cint(Request.QueryString("ToPage"))
if PageCount <=0 then PageCount = 1
if PageCount > TotalPage then PageCount = TotalPage
RS.Move (PageCount-1) * 10
'***************管理模式檢驗
'以下為進入管理模式的敘述
password=Request.Form("password")
IF password="test" then '<-----管理密碼
session("checkedit")="yes"
End IF
'以下為脫離管理模式的程式敘述
goexit=Request.Form("goexit")
IF goexit="yes" then
session("checkedit")="no"
End IF
%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=big5">
<title>家庭聯絡簿</title>
</head>
<body>
<div align="center">
<img src="title.gif"><br><a href="addmsg.asp">家長發言請按此</a>
</div>
<center>
<form method="post" name="formpage">
<table border="0" width="100%" cellpadding="0" cellspacing="0">
<tr>
<td><p align=right>
<%
for i=1 to TotalPage
If i<>PageCount then
Response.Write "<font color=black>｜</font><a href=guest.asp?topage="& i &"><font color=#cb55cc>" & i & "</font></a><font color=black>｜</font>"
else
Response.Write "<font color=black>｜</font><font color=#000000>"&i&"</font><font color=black>｜</font>"
end if
next
%>
</p>
</td>
<td align=right>
共<%=Count%>筆留言&nbsp&nbsp第 <% =PageCount %> 頁 / 共 <% =TotalPage %> 頁</td>
</tr></table>
<hr size="1" align="center" width="100%" >
</form>
<%
i=0
Do While Not RS.EOF and i<10
i=i+1
%>
<table border=0 width=90% bgcolor=#99CCFF>
<tr>
<td><fieldset id=info align=center style='margin:5'>
<img src="<% =RS("爸媽") %>.gif" border="0">&nbsp<%=RS("家長姓名")%>&nbsp於<% =RS("留言時間") %>發表&nbsp&nbsp
<% if len(TRIM(RS("聯絡信箱")))<>0 then %> <a href="mailto:<% =RS("聯絡信箱") %>">
<img src="mail.gif" alt="聯絡信箱 <% =RS("聯絡信箱") %>" border="0"></a>
<% end if %>
<table border="0" width=100%>
<tr>
<td valign="top" align="left">
<% IF RS("私人公開") = "NO" OR session("checkedit")="yes" THEN%>
<font color="#FF0080">留言主題：</font>
<font color="#0000FF"><%=RS("留言主題")%></font>
<br><font color="#000000"><%=RS("留言內容")%></font>
<%ELSE%>
<FONT COLOR=BLUE>:) 這是留給老師的悄悄話...</FONT>
<br><font color="#FF00F00">私人討論</font>
<%END if%>
</td></tr>
<%if RS("老師回覆")<>"" then%>
<tr bgcolor="#3399FF">
<td align="left" valign=top >
<font color="#800000">老師於<%=RS("老師回覆時間")%>回覆：</font>
<br>
<font color="FFFFFF"><%=RS("老師回覆")%></font>
</td></tr>
<% end if%>
<% IF session("checkedit")="yes" then %>
<tr><td>
<DIV ALIGN=RIGHT>【<a href=teachans.asp?ID=<%=RS("編號")%>>老師回覆</a>】</DIV>
</td></tr>
<%END IF%>
</table>
</td></tr></table><br>
<% RS.MoveNext
loop
RS.Close
CN.Close
%>
<p>
<form method="post">
<%IF session("checkedit")="yes" then%>
<input type="hidden" value="yes" name="goexit">
<input type="submit" value="離開管理模式">
<%else%>
密碼：<input type="text" name="password" size="4" maxlength="4">&nbsp&nbsp<input type="submit" value="教師管理">
<%End IF%>
</form>
</center>
</body>
</html>

複製代碼

心安，平安
發表任何無意義的感謝或灌水文章一律砍,珍惜帳號,請詳閱版規!!

TOP

小誌

　暱稱: 小誌
　頭銜: 曾經也是水電工

管理員 Rank: 9 Rank: 9 Rank: 9

帖子: 1193
主題: 394
精華: 113
積分: 1747
點名: 1
作業系統: Vista
軟體版本: Office 2003
閱讀權限: 200
性別: 男
來自: 台灣
註冊時間: 2010-5-1
最後登錄: 2024-12-20

2021牛年全勤獎章好學求知勳章熱烈參與勳章 2017 雞年全勤獎章 2018 狗年全勤獎章 2019 豬年全勤獎章 2020鼠年全勤獎章

4^#

發表於 2010-5-26 01:02 | 只看該作者

發言表單網頁製作
當我們要在網頁中提供一個可以讓學生家長發表意見或反映的聯絡簿時，我們首先必須設計一個『意見發表表單』，讓學生家長可以在上面發表意見，並且要能將這些意見資料送給我們處理家長發言資料的ASP程式『add.asp』來紀錄以及處理這些意見資料。

現在我們就來製作一個可以讓學生家長可以在上面發表意見的表單網頁『addmsg.asp』：

編號	欄位	欄位名稱	表單元件
１	留言主題	subject	單行文字方塊
２	您的大名	parent	單行文字方塊
３	E-Mail	email	單行文字方塊
４	爸爸還是媽媽	dadmam	選擇鈕
５	留言性質	personal	下拉式功能表
６	留言內容	memo	多行文字方塊
７	送出意見	Submit	按鈕
８	清除重寫	／	按鈕

『留言主題』網頁敘述標籤

<input type="text" name="subject" size="50" maxlength="20">

複製代碼

『您的大名』網頁敘述標籤

<input type="text" name="parent" size="20" maxlength="20">

複製代碼

『E-Mail』網頁敘述標籤

<input type="text" name="email" size="35" maxlength="40">

複製代碼

『爸爸還是媽媽』網頁敘述標籤

<input type="radio" name="dadmam" value="1" checked >
<img src="1.gif">
<input type="radio" name="dadmam" value="2">
<img src="2.gif">

複製代碼

『留言性質』網頁敘述標籤

<select name="personal" size="1">
<option value="大家來討論" selected>大家來討論</option><option value="只給老師看">只給老師看</option>
</select>

複製代碼

『留言內容』網頁敘述標籤

<textarea name="memo" cols="50" rows="2" ></textarea>

複製代碼

請特別注意：我們表單的名稱為『Addmsg』，而表單內容資料的傳送方式為『Post』，而且當這些意見資料被送達到 IIS/PWS 後，IIS/PWS 的網路伺服器端負責處理意見資料的ASP程式是『add.asp』.

<form name="addmsg" method="POST" action="add.asp">

複製代碼

相關知識：表單的參數

表單的Action參數：Action參數是用來指定Server端處理此一表單資料內容的程式，在本例中我們已經準備了一個專屬的表單處理ASP程式『add.asp』，所以我們將此參數值定為『add.asp』。
表單的Mothed參數：要將表單資料傳送至Server端的方式有兩種，設定值分別為GET及POST，若設定為POST，則瀏覽器會等Server端來讀取資料，若設定為GET，則當我們按下送出按鈕時，瀏覽器會立即將表單中的資料內傳送出去。利用POST方法，在傳送的資料上將不受限制，利用GET方法傳送的資料量則大約只有２k左右，但是GET方法的執行效能比較高。

addmsg.asp

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=big5">
<title>家庭聯絡簿</title>
</head>
<body>
<div align="center">
<p align="center">
<font size="2">
<img src="title.gif">
</font>
</div>
<div align="center">
<p align="right"><a href="guest.asp" ><font size="2">看家長們的意見</font></a>
</div>
<form name="addmsg" method="POST" action="add.asp">
<div align="center">
<table border="0" cellspacing="1" width="100%">
<tr>
<td bgcolor="#3399FF" align="center" valign="middle" width="147"><font color="#FFFFFF" size="2">留言主題</font></td>
<td height="25" bgcolor="#99CCFF" width="382"><font size="2"><input type="text" name="subject" size="50" value maxlength="20"></font></td>
</tr>
<tr>
<td bgcolor="#3399FF" align="center" valign="middle" width="147"><font color="#FFFFFF" size="2">您的大名</font></td>
<td height="25" bgcolor="#99CCFF" width="382"><font size="2"><input type="text" name="parent" size="20" maxlength="20"></font></td>
</tr>
<tr>
<td bgcolor="#3399FF" align="center" valign="middle" width="147"><font color="#FFFFFF" size="2">E-Mail</font></td>
<td height="25" bgcolor="#99CCFF" width="382"><font size="2"><input type="text" name="email" size="35" maxlength="40"></font></td>
</tr>
<tr>
<td bgcolor="#3399FF" align="center" height="27" valign="middle" width="147"><font color="#FFFFFF" size="2">您是爸爸還是媽媽？</font></td>
<td height="27" bgcolor="#99CCFF" width="382">
<font size="2">
<input type="radio" name="dadmam" value="1" checked ><img src="1.gif">
<input type="radio" name="dadmam" value="2"><img src="2.gif">
</font>
</td>
</tr>
<tr>
<td bgcolor="#3399FF" align="center" width="147"><font color="#FFFFFF" size="2">留言性質</font></td>
<td bgcolor="#99CCFF" width="382">
<font size="2">
<select name="personal" size="1">
<option value="大家來討論" selected>大家來討論</option>
<option value="只給老師看">只給老師看</option>
</select>
</font>
</td>
</tr>
<tr>
<td bgcolor="#3399FF" align="Center" height="98" valign="middle" width="147"><font color="#FFFFFF" size="2">留言內容：</font>
</td>
<td height="98" valign="middle" bgcolor="#99CCFF" width="382">
<font size="2">
<textarea name="memo" cols="50" rows="2" ></textarea>
</font>
</td>
</tr>
</table>
</div><div align="center"><center><p><font size="2"><input type="submit" value="送出意見">
         <input type="reset" value="重填資料"> </font> </p>
</div>
</form>
</center>
</body>
</html>

複製代碼

心安，平安
發表任何無意義的感謝或灌水文章一律砍,珍惜帳號,請詳閱版規!!

TOP