12
返回列表 上一主題 發帖

[發問] 請教抓取太平洋證卷的DDE 要如何從中抓取每分鐘的最大成交價及最小成交價

c_c_lai

帖子
2035 
主題
24 
精華
0 
積分
2031 
點名
0  
作業系統
Win7 
軟體版本
Office2010 
閱讀權限
100 
性別
男 
註冊時間
2012-3-22 
最後登錄
2024-2-1 
1# 跳轉到 »
發表於 2012-8-21 06:32 | 顯示全部帖子
回復 1# lieh_chun
你要的是不是這支程式內容所描述的？
  1. Sub ExeSelf()
  2.     timerEnabled = True

  4.     Sheets("策略記錄").Cells(2, 1) = Now()
  5.    
  6.     On Error Resume Next
  7.     If (TimeValue(Now) > TimeValue("13:46:01")) Then Exit Sub
  8.    
  9.     If (TimeValue(Now) >= TimeValue("08:45:00")) Then         ' 開盤、收盤時段設定
  10.         If IsError(Sheets("策略記錄").Range("B2").Value) Then ' 假設 B2 欄位為多空力道
  11.             Cv(1) = 0
  12.             Cv(2) = 0
  13.             Cv(3) = 0
  14.         Else
  15.             Cv(1) = Sheets("策略記錄").Range("B2").Value   ' 多空力道成交價
  16.             Cv(2) = Sheets("策略記錄").Range("C2").Value   ' 反向勢力成交價
  17.             Cv(3) = Sheets("策略記錄").Range("D2").Value   ' 主力控盤成交價
  18.         End If
  19.          
  20.         If (turnKey = 0 Or Ov(1) = 0) Then ' 當 turnKey 值為0，表示其為初始值設定。
  21.             ' 為考量系統剛連上DDE，有時在第一根數值產生時Ov = Cv值可能為 0 的狀態)。
  22.             Ov(1) = Cv(1)                  ' 多空力道開盤價初始值設定
  23.             Hv(1) = Cv(1)                  ' 多空力道最高價初始值設定
  24.             Lv(1) = Cv(1)                  ' 多空力道最低價初始值設定
  25.                
  26.             Ov(2) = Cv(2)                  ' 反向勢力開盤價初始值設定
  27.             Hv(2) = Cv(2)                  ' 反向勢力最高價初始值設定
  28.             Lv(2) = Cv(2)                  ' 反向勢力最低價初始值設定
  29.                   
  30.             Ov(3) = Cv(3)                  ' 主力控盤開盤價初始值設定
  31.             Hv(3) = Cv(3)                  ' 主力控盤最高價初始值設定
  32.             Lv(3) = Cv(3)                  ' 主力控盤最低價初始值設定
  33.         End If

  35.         turnKey = turnKey + 1
  36.         Sheets("策略記錄").Cells(10, 2) = turnKey & " 秒"

  38.         If (Cv(1) > Hv(1)) Then Hv(1) = Cv(1) ' 判斷多空力道最高價
  39.         If (Cv(2) > Hv(2)) Then Hv(2) = Cv(2) ' 判斷反向勢力最高價
  40.         If (Cv(3) > Hv(3)) Then Hv(3) = Cv(3) ' 判斷主力控盤最高價
  41.          
  42.         If (Cv(1) < Lv(1)) Then Lv(1) = Cv(1) ' 判斷多空力道最低價
  43.         If (Cv(2) < Lv(2)) Then Lv(2) = Cv(2) ' 判斷反向勢力最低價
  44.         If (Cv(3) < Lv(3)) Then Lv(3) = Cv(3) ' 判斷主力控盤最低價
  45.                
  46.     End If
  47.    
  48.     If (turnKey < nums) Then
  49.         Application.OnTime (Now + TimeValue("00:00:01")), "ThisWorkbook.ExeSelf"
  50.     Else
  51.         If (Cv(1) <> 0) Then Call Timer
  52.         ' Call Timer
  53.         Call timerStart
  54.     End If
  55. End Sub
複製代碼

TOP

c_c_lai

帖子
2035 
主題
24 
精華
0 
積分
2031 
點名
0  
作業系統
Win7 
軟體版本
Office2010 
閱讀權限
100 
性別
男 
註冊時間
2012-3-22 
最後登錄
2024-2-1 
2#
發表於 2012-8-21 14:01 | 顯示全部帖子
回復 3# lieh_chun
上面的實例並非是樣本，它是將每一秒得 O、H、L、C 分別記錄下來，當滿足設定時間(例如一分鐘)
就將資料寫入到指定欄位儲存，如此紀錄上的每分鐘開盤價、最高價、最低價、收盤價都記錄下，
便可做一些統計分析了。

TOP

c_c_lai

帖子
2035 
主題
24 
精華
0 
積分
2031 
點名
0  
作業系統
Win7 
軟體版本
Office2010 
閱讀權限
100 
性別
男 
註冊時間
2012-3-22 
最後登錄
2024-2-1 
3#
發表於 2012-8-22 08:46 | 顯示全部帖子
回復 5# lieh_chun
我只將處理 O、H、L、C 、 以及如何應用的模組 (已貼示) 貼上，其它部分須配合
你實際的應用，因每個人切入角度的不同 (券商、需求、應用面等)，故此處論壇僅能
提供你個人參考、研究、以及彼此間之討論而已 。
你可以將你目前已成形的檔案以附件上傳，大家再看看能否幫得上忙。

TOP

c_c_lai

帖子
2035 
主題
24 
精華
0 
積分
2031 
點名
0  
作業系統
Win7 
軟體版本
Office2010 
閱讀權限
100 
性別
男 
註冊時間
2012-3-22 
最後登錄
2024-2-1 
4#
發表於 2012-8-24 08:09 | 顯示全部帖子
回復 7# lieh_chun
你把檔案當附件傳來，再幫你看看如何要如何處哩，
因為你哪一個欄位是哪一個，實在無法得知。

TOP

c_c_lai

帖子
2035 
主題
24 
精華
0 
積分
2031 
點名
0  
作業系統
Win7 
軟體版本
Office2010 
閱讀權限
100 
性別
男 
註冊時間
2012-3-22 
最後登錄
2024-2-1 
5#
發表於 2012-8-26 07:11 | 顯示全部帖子
回復 10# GBKEE
lieh_chun 他要的是盤中的 Open/High/Low/Close 而不是 Max、Min。
回復 9# lieh_chun
因你無權限下載，所以只好將程式貼上，你將它全部覆蓋到你的 ThisWorkbook 程式區內儲存，再重啟就 OK 了！
  1. Option Explicit
  2. Dim Ov As Single, Hv As Single, Lv As Single, Cv As Single, cIndex As Single
  3. Dim timerEnabled As Boolean    ' 判定開啟本工作表單的時段是否為開盤前啟動。
  4. Public turnKey As Integer

  6. Private Sub Workbook_Open()
  7.     timerEnabled = False

  9.     Call timerStart      ' 程式一啟始，便去自動執行 timerStart
  10. End Sub

  12. Private Sub Workbook_BeforeClose(Cancel As Boolean)
  13.     On Error Resume Next
  14.     Application.OnTime Now + TimeValue("00:00:01"), "ThisWorkbook.ATimer", , False
  15.    
  16.     Me.Save
  17. End Sub

  19. Public Sub ATimer()
  20.     Dim Pos As Long             ' 將每隔 "多少時間" 處理時段，移到此處來處理。
  21.    
  22.     On Error Resume Next
  23.     If (TimeValue(Now) > TimeValue("13:45:00")) Then Exit Sub
  24.    
  25.     If (TimeValue(Now) >= TimeValue("08:45:00")) Then         ' 開盤、收盤時段設定
  26.         ' 盤中處理，將資料匯入寫入工作表單內儲存。
  27.         With Sheets("策略記錄")
  28.             Pos = .Range("B" & Rows.Count).End(xlUp).Row   ' 求出該欄之最後使用列數  ' 目前為 329
  29.             If (Pos < 2) Then Pos = 12
  30.             Pos = Pos + 1                   ' 將變動行號加一行

  32.             If Not IsError(.[B2]) Then
  33.                 .[T1] = "開盤價"
  34.                 .[U1] = "最高價"
  35.                 .[V1] = "最低價"
  36.                 .[W1] = "成交價"
  37.                 .[T2] = Ov      ' 開盤價
  38.                 .[U2] = Hv      ' 最高價
  39.                 .[V2] = Lv      ' 最低價
  40.                 .[W2] = Cv      ' 成交價
  41.                  
  42.                  .Cells(Pos, 1) = Time           ' 時間
  43.                 ' 多空力道、反向勢力、主力控盤、內外盤比%、成交價、漲跌、
  44.                 ' 總量、最高、最低、加權指數、漲跌、累計委買、累委買筆、
  45.                 ' 累計委賣、累委賣筆、基差、委比、委買賣差、
  46.                 ' 開盤價、最高價、最低價、收盤價
  47.                 .Cells(Pos, 2).Offset(0).Resize(, 22) = .[B2:W2].Value
  48.             End If
  49.         End With
  50.     End If
  51. End Sub

  53. Sub timerStart()
  54.     turnKey = 0
  55.     Sheets("策略記錄").Range("B6").Value = 0
  56.    
  57.     If timerEnabled Then
  58.         ' 第二次(含)以後均以設定之 "間隔時段" 來處理執行序的作業。
  59.         Application.OnTime (Now + TimeValue("00:00:01")), "ThisWorkbook.ExeSelf"
  60.     Else
  61.         timerEnabled = True
  62.         
  63.         ' 將第一次啟動時間更改為設定 "開盤時間"前，如果開啟 Excel 時，已經過了設定 "開盤時間"，則一進入系統即直接去執行紀錄作業。
  64.         If (TimeValue(Now) <= TimeValue("08:45:00")) Then
  65.             Application.OnTime (TimeValue("08:45:00")), "ThisWorkbook.ExeSelf"
  66.         Else
  67.             ' 系統剛連上 DDE 至資料匯入Excel工作表單，須有一個緩衝時段，
  68.             ' 這時如果馬上去抓取DDE資料，會有型態不符的錯誤訊息產生，並中斷執行序的作業。
  69.             Application.OnTime (Now + TimeValue("00:00:05")), "ThisWorkbook.ExeSelf"
  70.         End If
  71.     End If
  72. End Sub

  74. Private Sub ExeSelf()
  75.     Dim nums As Integer            ' 預設為 60 秒
  76.    
  77.     nums = 60
  78.     On Error Resume Next
  79.     If (TimeValue(Now) < TimeValue("08:45:00") Or TimeValue(Now) > TimeValue("13:46:01")) Then Exit Sub
  80.       
  81.     If IsError(Sheets("策略記錄").Range("F2").Value) Then
  82.         Cv = 0
  83.     Else
  84.         Cv = Sheets("策略記錄").Range("F2").Value    ' 成交價
  85.     End If
  86.          
  87.     If (turnKey = 0 Or Ov = 0) Then
  88.         Ov = Cv                                      ' 開盤價
  89.         Hv = Cv                                      ' 最高價
  90.         Lv = Cv                                      ' 最低價
  91.     End If
  92.         
  93.     turnKey = turnKey + 1
  94.            
  95.     If (Cv > Hv) Then Hv = Cv                        ' 最高價
  96.     If (Cv < Lv) Then Lv = Cv                        ' 最低價
  97.       
  98.     Sheets("策略記錄").Range("B6").Value = " ( " & turnKey & " 秒 )"
  99.    
  100.     If (turnKey < nums) Then
  101.         Application.OnTime (Now + TimeValue("00:00:01")), "ThisWorkbook.ExeSelf"
  102.     Else
  103.         If (Cv > 0) Then Call ATimer
  104.         If timerEnabled Then Call timerStart
  105.     End If
  106. End Sub
複製代碼
DDE for lieh_chun.rar (62.46 KB)

TOP

c_c_lai

帖子
2035 
主題
24 
精華
0 
積分
2031 
點名
0  
作業系統
Win7 
軟體版本
Office2010 
閱讀權限
100 
性別
男 
註冊時間
2012-3-22 
最後登錄
2024-2-1 
6#
發表於 2012-8-26 07:25 | 顯示全部帖子
回復 10# GBKEE
您的運算方法我會抽空來試試看，它的確也是不錯的處理方式，
我是用比較直接的方式來處哩，變數、與陣列的使用雖結果一樣，
我圖的只是以後好 Maintenance、且易判別之故。

TOP

c_c_lai

帖子
2035 
主題
24 
精華
0 
積分
2031 
點名
0  
作業系統
Win7 
軟體版本
Office2010 
閱讀權限
100 
性別
男 
註冊時間
2012-3-22 
最後登錄
2024-2-1 
7#
發表於 2012-8-26 08:43 | 顯示全部帖子
回復 13# GBKEE
請教您它為何一直不動？ Worksheet_Calculate() 是 User Define Or Worksheet 內定觸發程式？
因為我很少使用 Excel 類似此類的方法 (Method)， 請您指導！
DDE for GBKEE.rar (10.12 KB)

TOP

c_c_lai

帖子
2035 
主題
24 
精華
0 
積分
2031 
點名
0  
作業系統
Win7 
軟體版本
Office2010 
閱讀權限
100 
性別
男 
註冊時間
2012-3-22 
最後登錄
2024-2-1 
8#
發表於 2012-8-26 13:13 | 顯示全部帖子
回復 15# GBKEE
謝謝您讓我體會到 Excel method 的一些使用，但我發覺 DoEvents 幾乎完全佔據了整個作業時間，
再分時分工上會不會造成是一種負擔呢？

TOP

c_c_lai

帖子
2035 
主題
24 
精華
0 
積分
2031 
點名
0  
作業系統
Win7 
軟體版本
Office2010 
閱讀權限
100 
性別
男 
註冊時間
2012-3-22 
最後登錄
2024-2-1 
9#
發表於 2012-8-28 07:43 | 顯示全部帖子
回復 18# lieh_chun
上傳你整理過後之檔案！

TOP

c_c_lai

帖子
2035 
主題
24 
精華
0 
積分
2031 
點名
0  
作業系統
Win7 
軟體版本
Office2010 
閱讀權限
100 
性別
男 
註冊時間
2012-3-22 
最後登錄
2024-2-1 
10#
發表於 2012-9-9 22:28 | 顯示全部帖子
回復  c_c_lai
我是使用EASYWIN的dde訊號，如果要每30秒記錄一趟上面所有的資料該如何寫VBA?因為套表上去 ...
ribbits 發表於 2012-9-9 14:31

貼上程式碼，供你參考：
  1. Option Explicit
  2. Dim timerEnabled As Boolean    ' 判定開啟本工作表單的時段是否為開盤前啟動。

  4. Private Sub Workbook_Open()
  5.     Dim Pos As Long             ' 將每隔 "多少時間" 處理時段，移到此處來處理。
  6.     timerEnabled = False

  8.     Pos = Sheets("Data").Range("A" & Rows.Count).End(xlUp).Row   ' 求出該欄之最後使用列數
  9.     If (Pos <= 1) Then Pos = 1
  10.     Sheets("策略記錄").[A4] = "已匯入 " & (Pos - 1) & " 筆資料"
  11.     Call timerStart      ' 程式一啟始，便去自動執行 timerStart
  12. End Sub

  14. Private Sub Workbook_BeforeClose(Cancel As Boolean)
  15.     On Error Resume Next
  16.     Application.OnTime Now + TimeValue("00:00:01"), "ThisWorkbook.ATimer", , False
  17.    
  18.     Me.Save
  19. End Sub

  21. Public Sub ATimer()
  22.     Dim Pos As Long             ' 將每隔 "多少時間" 處理時段，移到此處來處理。
  23.    
  24.     On Error Resume Next
  25.     ' If (TimeValue(Now) > TimeValue("13:45:00")) Then Exit Sub
  26.    
  27.     If (TimeValue(Now) >= TimeValue("08:45:00")) Then         ' 開盤、收盤時段設定
  28.         ' 盤中處理，將資料匯入寫入工作表單內儲存。
  29.         With Sheets("Data")
  30.             Pos = .Range("B" & Rows.Count).End(xlUp).Row   ' 求出該欄之最後使用列數
  31.             If (Pos <= 1) Then Pos = 1
  32.             Pos = Pos + 1                   ' 將變動行號加一行
  33.             Sheets("策略記錄").[A4] = "已匯入 " & (Pos - 1) & " 筆資料"

  35.             If Not IsError(Sheets("策略記錄").[E2]) Then
  36.                  .Cells(Pos, 1) = Date                              ' 日期
  37.                  .Cells(Pos, 2) = Time                              ' 時間
  38.                  .Cells(Pos, 3) = Sheets("策略記錄").[E2]           ' 成交價
  39.                  .Cells(Pos, 4).Offset(0).Resize(, 3) = Sheets("策略記錄").[G2:I2].Value
  40.                  .Cells(Pos, 7) = Sheets("策略記錄").[K2]           ' 成交量
  41.                 .Cells(Pos, 8).Offset(0).Resize(, 8) = Sheets("策略記錄").[O2:V2].Value
  42.             End If
  43.         End With
  44.     End If
  45.     If timerEnabled Then Call timerStart
  46. End Sub

  48. Sub timerStart()
  49.     If timerEnabled Then
  50.         ' 第二次(含)以後均以設定之 "間隔時段" 來處理執行序的作業。
  51.         Application.OnTime (Now + TimeValue("00:00:30")), "ThisWorkbook.ATimer"
  52.     Else
  53.         timerEnabled = True
  54.         
  55.         ' 將第一次啟動時間更改為設定 "開盤時間"前，如果開啟 Excel 時，已經過了設定 "開盤時間"，則一進入系統即直接去執行紀錄作業。
  56.         If (TimeValue(Now) <= TimeValue("08:45:00")) Then
  57.             Application.OnTime (TimeValue("08:45:00")), "ThisWorkbook.ATimer"
  58.         Else
  59.             ' 系統剛連上 DDE 至資料匯入Excel工作表單，須有一個緩衝時段，
  60.             ' 這時如果馬上去抓取DDE資料，會有型態不符的錯誤訊息產生，並中斷執行序的作業。
  61.             Application.OnTime (Now + TimeValue("00:00:05")), "ThisWorkbook.ATimer"
  62.         End If
  63.     End If
  64. End Sub
複製代碼
因為你目前無權下載，所以將執行畫面貼示，你只要照著修正即可：

EASYWIN0909.rar (12.11 KB)

TOP

        靜思自在 : 愛不是要求對方，而是要由自身的付出。
12
返回列表 上一主題