1234567
返回列表 上一主題 發帖

[發問] 怎麼抓取A資料表假日上班的日期與時間到B資料表的儲存格中

GBKEE

帖子
5923 
主題
13 
精華
1 
積分
5986 
點名
0  
作業系統
win10 
軟體版本
Office 2010 
閱讀權限
150 
性別
男 
來自
台灣基隆 
註冊時間
2010-5-1 
最後登錄
2022-1-23 

2017 雞年全勤獎章2016猴年全勤獎章2015羊年全勤獎章2014馬年全勤獎章2013蛇年全勤獎章2012龍年全勤獎章論壇貢獻勳章熱烈參與勳章2011兔年全勤獎章
22# 跳轉到 »
發表於 2013-11-20 11:06 | 只看該作者
本帖最後由 GBKEE 於 2013-11-20 12:23 編輯

回復 21# prince0413
  1. Const 早 = "10:00~18:00"
  2. Const 全日 = "10:30~18:30"
  3. Const 晚 = "11:00~19:00"
  4. Sub Ex()
  5.     Dim Rng(1 To 3) As Range, i As Integer, ii As Integer, 出勤 As String, 日期 As Range, Print_x As Integer
  6.     Dim 出勤單 As Range, E As Range
  7.     Set 出勤單 = Sheets("假日出勤單").Range("B3,D3,A5,B5,D5")   '第1張出勤單要導入資料的位置
  8.     For i = 0 To 3                                              '出勤單: 第1張到 第4張的位置 間格 14 列
  9.         出勤單.Offset(i * 14) = ""                              '清除 資料
  10.     '************    但第 2- 3張出勤單 間格 15 列 你需調整一下   *************************************
  11.     Next
  12.     Print_x = 0                                                 '印列 A4紙張 的變數
  13.     Set Rng(1) = Sheets("假日出勤單").Range("J2")               '設定社員 英文,中文,編號 (可以是 Abby,丁千芸,136)
  14.     Do While Rng(1) <> ""                                       '執行迴圈的條件: 社員<>""
  15.         With Sheets("11月")
  16.              Set Rng(3) = Nothing                               '物件: 釋放
  17.              Set Rng(2) = Sheets("中英文姓名對照表").Range("A:C").Find(Rng(1), LOOKAT:=xlWhole)
  18.                                                                  '英文,中文,編號:裡搜尋
  19.              If Not Rng(2) Is Nothing Then
  20.                 Set Rng(2) = Rng(2).Parent.Range("A" & Rng(2).Row)  '英文,中文,編號的第一欄 (英文)
  21.                 For i = 1 To 3                                      '如社員為中文 Sheets("11月")沒有 中文
  22.                     Set Rng(3) = Sheets("11月").Range("A:B").Find(Rng(2).Cells(i), LOOKAT:=xlWhole)
  23.                     If Not Rng(3) Is Nothing Then Exit For           '找到 英文 或 編號
  24.                 Next
  25.             End If
  26.             If Not Rng(3) Is Nothing Then
  27.                 i = 3                                         '第3欄 :C
  28.                 Do While IsNumeric(.Cells(4, i))              '執行迴圈的條件:第4列是數字
  29.                     If (.Cells(5, i) = "六" Or .Cells(5, i) = "日") And Trim(.Cells(Rng(3).Row, i)) <> "" Then
  30.                         出勤 = ""                             '歸零
  31.                         Set 日期 = .Cells(4, i)
  32.                         If .Cells(Rng(3).Row, i) Like "*早*" Then
  33.                             出勤 = 早
  34.                         ElseIf .Cells(Rng(3).Row, i) Like "*晚*" Then
  35.                             出勤 = 晚
  36.                         ElseIf .Cells(Rng(3).Row, i) Like "*全日*" Then
  37.                             出勤 = 全日
  38.                         End If
  39.                         If 出勤 <> "" Then                                  '預防沒有 [全日,早,晚]的班別
  40.                             Print_x = IIf(Print_x = 4, 1, Print_x + 1)
  41.                             With 出勤單.Offset((Print_x - 1) * 14)          '第 Print_x 的位置
  42.                                 .Range("A1") = Rng(2).Offset(, 1)           '社員中文
  43.                                 .Range("C1") = Rng(2).Offset(, 2)           '社員編號
  44.                                 .Cells(3, 0) = DateSerial(2013, 11, 日期)   '日期
  45.                                 .Range("A3") = 出勤                         '時間
  46.                                 .Range("C3") = IIf(日期.Offset(1) = "六", "(星期六)", "(星期日)") & "沙龍營業"
  47.                             End With
  48.                             If Print_x = 4 Then                             '滿4筆印列
  49.                                 出勤單.Parent.PrintOut                      '印列出勤單
  50.                                 For ii = 0 To 3
  51.                                    出勤單.Offset(ii * 14) = ""              '清空已印列資料
  52.                                 Next
  53.                             End If
  54.                         End If
  55.                     End If
  56.                     i = i + 1
  57.                 Loop
  58.             End If
  59.             Rng(1).Offset(, 1) = IIf(Rng(3) Is Nothing, "請檢查 : 假日出勤單 , 對照表 找不到 ", "")
  60.         End With
  61.         Set Rng(1) = Rng(1).Offset(1)    '下一位姓名
  62.     Loop
  63.     If Print_x > 0 And Print_x <= 3 Then 出勤單.Parent.PrintOut 1, Round(Print_x / 2) ' 未滿 4 筆的資料沒印列
  64. End Sub
複製代碼
感恩的心......(在麻辣家族討論區.用心學習會有進步的)
但資源無限,後援有限,  一天1元的贊助,人人有能力.

TOP

prince0413
　暱稱: 香澄

中學生Rank: 2

帖子
108 
主題
23 
精華
0 
積分
140 
點名
0  
作業系統
WIN7 
軟體版本
OFFICE 2003 
閱讀權限
20 
性別
男 
來自
台灣 
註冊時間
2013-11-2 
最後登錄
2019-12-31 
21#
發表於 2013-11-19 20:35 | 只看該作者
回復 19# GBKEE

大大您好

剛誤會您了，我先KEYIN姓名後進去程式碼裡按執行發現有列印出來!
真是太厲害了

疑問:
1.一開始我設這麼多空白的申請表是因為想要一張紙印兩份剛剛好，有這種方式是可以一張A4印兩張申請表的嗎(想節省紙資源)

2.中英文姓名對照表後方我新增了社員編號(如圖)，如果社員編號我想跟姓名一樣在假日出勤申請單裡對照過去的話，那我要從哪裡修改程式碼呢?

感恩
不會EXCALL的笨蛋

TOP

prince0413
　暱稱: 香澄

中學生Rank: 2

帖子
108 
主題
23 
精華
0 
積分
140 
點名
0  
作業系統
WIN7 
軟體版本
OFFICE 2003 
閱讀權限
20 
性別
男 
來自
台灣 
註冊時間
2013-11-2 
最後登錄
2019-12-31 
20#
發表於 2013-11-19 20:13 | 只看該作者
回復 19# GBKEE

大大您好

我剛貼您的程式進去巨集後，再J2儲存格輸入英文姓名都沒有反應呢
怎麼會這樣呢?

-------------------------------------------------------------------------------
疑問1:
Sheets("假日出勤單").PageSetup.PrintArea = "A1:H13"      '一頁就夠了

上面程式碼請問大大這甚麼意思呢，照道理說一個人一個月至少會有很多天假日出勤單，代表不只會有一份而以，但大大為什麼範圍只抓"A1:H13"一張而已呢?

不好意思，一直請教您問題~
麻煩了
不會EXCALL的笨蛋

TOP

GBKEE

帖子
5923 
主題
13 
精華
1 
積分
5986 
點名
0  
作業系統
win10 
軟體版本
Office 2010 
閱讀權限
150 
性別
男 
來自
台灣基隆 
註冊時間
2010-5-1 
最後登錄
2022-1-23 

2017 雞年全勤獎章2016猴年全勤獎章2015羊年全勤獎章2014馬年全勤獎章2013蛇年全勤獎章2012龍年全勤獎章論壇貢獻勳章熱烈參與勳章2011兔年全勤獎章
19#
發表於 2013-11-19 19:45 | 只看該作者
回復 18# prince0413
  1. Const 早 = "10:00~18:00"
  2. Const 全日 = "10:30~18:30"
  3. Const 晚 = "11:00~19:00"
  4. Sub Ex()
  5.     Dim Rng(1 To 2) As Range, i As Integer, 出勤 As String, M As Variant
  6.     Sheets("假日出勤單").PageSetup.PrintArea = "A1:H13"      '一頁就夠了
  7.     Set Rng(1) = Sheets("假日出勤單").Range("J2")            '設定姓名
  8.     Do While Rng(1) <> ""                                    '執行迴圈的條件:姓名<>""
  9.         With Sheets("11月")
  10.             Set Rng(2) = .Range("B:B").Find(Rng(1), LOOKAT:=xlWhole)
  11.             M = Application.Match(Rng(1), Sheets("中英文姓名對照表").Range("A:A"), 0)  'Match : 工作表函數
  12.             If IsError(M) Then MsgBox "中英文姓名對照表 中沒有 : " & Rng(1): Exit Sub
  13.             If Not Rng(2) Is Nothing Then
  14.                 i = 3                                         '第3欄 :C
  15.                 Do While IsNumeric(.Cells(4, i))              '執行迴圈的條件:第4列是數字
  16.                     If .Cells(5, i) = "六" Or .Cells(5, i) = "日" Then
  17.                         出勤 = ""                             '歸零
  18.                         If .Cells(Rng(2).Row, i) Like "*早*" Then
  19.                             出勤 = 早
  20.                         ElseIf .Cells(Rng(2).Row, i) Like "*晚*" Then
  21.                             出勤 = 晚
  22.                         ElseIf .Cells(Rng(2).Row, i) Like "*全日*" Then
  23.                             出勤 = 全日
  24.                         End If
  25.                         If 出勤 <> "" Then
  26.                             Sheets("假日出勤單").Range("B3") = Sheets("中英文姓名對照表").Cells(M, "B")     '姓名: 對照出在B欄的 M列
  27.                             Sheets("假日出勤單").Range("D3") = Rng(2).Offset(, -1)                          '社員編號
  28.                             Sheets("假日出勤單").Range("A5") = DateSerial(2013, 11, .Cells(4, i))           '日期
  29.                             Sheets("假日出勤單").Range("B5") = 出勤                                         '時間
  30.                             Sheets("假日出勤單").Range("D5") = IIf(.Cells(4, i) = "六", "(星期六)", "(星期日)") & "沙龍營業"
  31.                             Sheets("假日出勤單").PrintOut                                                   '印列出勤單
  32.                         End If
  33.                     End If
  34.                     i = i + 1
  35.                 Loop
  36.             End If
  37.         End With
  38.         Set Rng(1) = Rng(1).Offset(1)    '下一位姓名
  39.     Loop
  40. End Sub
複製代碼
感恩的心......(在麻辣家族討論區.用心學習會有進步的)
但資源無限,後援有限,  一天1元的贊助,人人有能力.

TOP

prince0413
　暱稱: 香澄

中學生Rank: 2

帖子
108 
主題
23 
精華
0 
積分
140 
點名
0  
作業系統
WIN7 
軟體版本
OFFICE 2003 
閱讀權限
20 
性別
男 
來自
台灣 
註冊時間
2013-11-2 
最後登錄
2019-12-31 
18#
發表於 2013-11-19 18:36 | 只看該作者
Ex.zip.zip (48.05 KB) 回復 17# GBKEE

大大您好

附件為加入中英姓名對照資料表，以及在"Ex"巨集貼入您的程式後的結果

請您再指教一下

感恩
不會EXCALL的笨蛋

TOP

GBKEE

帖子
5923 
主題
13 
精華
1 
積分
5986 
點名
0  
作業系統
win10 
軟體版本
Office 2010 
閱讀權限
150 
性別
男 
來自
台灣基隆 
註冊時間
2010-5-1 
最後登錄
2022-1-23 

2017 雞年全勤獎章2016猴年全勤獎章2015羊年全勤獎章2014馬年全勤獎章2013蛇年全勤獎章2012龍年全勤獎章論壇貢獻勳章熱烈參與勳章2011兔年全勤獎章
17#
發表於 2013-11-19 17:10 | 只看該作者
回復 16# prince0413
中英文對照表,請放在工作表好對照(注意個人資料),弄好後上傳檔案,我再看看.
感恩的心......(在麻辣家族討論區.用心學習會有進步的)
但資源無限,後援有限,  一天1元的贊助,人人有能力.

TOP

prince0413
　暱稱: 香澄

中學生Rank: 2

帖子
108 
主題
23 
精華
0 
積分
140 
點名
0  
作業系統
WIN7 
軟體版本
OFFICE 2003 
閱讀權限
20 
性別
男 
來自
台灣 
註冊時間
2013-11-2 
最後登錄
2019-12-31 
16#
發表於 2013-11-19 16:45 | 只看該作者
本帖最後由 GBKEE 於 2013-11-19 17:11 編輯

Ex.zip.zip (49.98 KB) 回復 15# GBKEE

大大您好

我剛貼您的程式進去"Ex"巨集裡
但在"假日出勤單"資料表J2儲存格輸入"英文姓名"後卻沒有反應呢

ps:我忽略姓名中英文對照了(假日出勤單是要轉換成中文姓名)，已在下方補上，請大大再幫我看看是否我忽略了甚麼~


Abby  丁X芸
Masumi 吳X錚
Jessica 林X燕
Hitomi 林X婷
Jason 許X豪
Red 陳X呈
Lynn 戴X伶
Prince 許X強
Edge 蘇X祐
Joyce 侯X雯
Jack 黃X傑
不會EXCALL的笨蛋

TOP

GBKEE

帖子
5923 
主題
13 
精華
1 
積分
5986 
點名
0  
作業系統
win10 
軟體版本
Office 2010 
閱讀權限
150 
性別
男 
來自
台灣基隆 
註冊時間
2010-5-1 
最後登錄
2022-1-23 

2017 雞年全勤獎章2016猴年全勤獎章2015羊年全勤獎章2014馬年全勤獎章2013蛇年全勤獎章2012龍年全勤獎章論壇貢獻勳章熱烈參與勳章2011兔年全勤獎章
15#
發表於 2013-11-19 15:57 | 只看該作者
回復 14# prince0413
試試看
  1. Const 早 = "10:00~18:00"
  2. Const 全日 = "10:30~18:30"
  3. Const 晚 = "11:00~19:00"
  4. Sub Ex()
  5.     Dim Rng(1 To 2) As Range, i As Integer, 出勤 As String
  6.     Sheets("假日出勤單").PageSetup.PrintArea = "A1:H13"      '一頁就夠了
  7.     Set Rng(1) = Sheets("假日出勤單").Range("J2")            '設定姓名
  8.     Do While Rng(1) <> ""                                    '執行迴圈的條件:姓名<>""
  9.         With Sheets("11月")
  10.             Set Rng(2) = .Range("B:B").Find(Rng(1), LOOKAT:=xlWhole)
  11.             If Not Rng(2) Is Nothing Then
  12.                 i = 3                                         '第3欄 :C
  13.                 Do While IsNumeric(.Cells(4, i))              '執行迴圈的條件:第4列是數字
  14.                     If .Cells(5, i) = "六" Or .Cells(5, i) = "日" Then
  15.                         出勤 = ""                             '歸零
  16.                         If .Cells(Rng(2).Row, i) Like "*早*" Then
  17.                             出勤 = 早
  18.                         ElseIf .Cells(Rng(2).Row, i) Like "*晚*" Then
  19.                            
  20.                             出勤 = 晚
  21.                         ElseIf .Cells(Rng(2).Row, i) Like "*全日*" Then
  22.                             出勤 = 全日
  23.                         End If
  24.                         If 出勤 <> "" Then
  25.                             Sheets("假日出勤單").Range("B3") = Rng(1)                               '姓名
  26.                             Sheets("假日出勤單").Range("D3") = Rng(2).Offset(, -1)                  '社員編號
  27.                             Sheets("假日出勤單").Range("A5") = DateSerial(2013, 11, .Cells(4, i))   '日期
  28.                             Sheets("假日出勤單").Range("B5") = 出勤                                 '時間
  29.                             Sheets("假日出勤單").Range("D5") = IIf(.Cells(4, i) = "六", "(星期六)", "(星期日)") & "沙龍營業"
  30.                             Sheets("假日出勤單").PrintOut    '印列出勤單
  31.                         End If
  32.                     End If
  33.                     i = i + 1
  34.                 Loop
  35.             End If
  36.         End With
  37.         Set Rng(1) = Rng(1).Offset(1)    '下一位姓名
  38.     Loop
  39. End Sub
複製代碼
感恩的心......(在麻辣家族討論區.用心學習會有進步的)
但資源無限,後援有限,  一天1元的贊助,人人有能力.

TOP

prince0413
　暱稱: 香澄

中學生Rank: 2

帖子
108 
主題
23 
精華
0 
積分
140 
點名
0  
作業系統
WIN7 
軟體版本
OFFICE 2003 
閱讀權限
20 
性別
男 
來自
台灣 
註冊時間
2013-11-2 
最後登錄
2019-12-31 
14#
發表於 2013-11-19 14:14 | 只看該作者
請假&出勤申請單(上傳用).zip.zip (48.27 KB) 回復 11# luhpro


大大您好:
這是我整理出完整的班表

目的:
在"假日出勤單"內 J2 儲存格下方輸入人名後，旁邊休日出勤單會自動抓取該人"11月"資料表全部的假日上班日期與時間
紅字部分內是要抓取的資料

請問這樣我該怎麼寫程式呢

請大大指導
不會EXCALL的笨蛋

TOP

prince0413
　暱稱: 香澄

中學生Rank: 2

帖子
108 
主題
23 
精華
0 
積分
140 
點名
0  
作業系統
WIN7 
軟體版本
OFFICE 2003 
閱讀權限
20 
性別
男 
來自
台灣 
註冊時間
2013-11-2 
最後登錄
2019-12-31 
13#
發表於 2013-11-16 19:24 | 只看該作者
回復 11# luhpro


了解~我會將完整檔修正後po上來
再完整重新敘述需求的~

因為一開始我只show出我自己的班表想藉由大大的教學程式碼理解   
然後在把所有人的班表也加進來該月份裡     將所學的程式碼當範本套用在很多人身上
但這樣好像造成反效果     反而自己看不懂也麻煩到大大您一直修改來修改去了

我這幾天會把所有人的班表key in整理好     再傳上來~
到時候麻煩您教學了

真不好意思     一直麻煩您
不會EXCALL的笨蛋

TOP

        靜思自在 : 自己害自己，莫過於亂發脾氣。
1234567
返回列表 上一主題