12
返回列表 上一主題 發帖

[原創] 快速穩定排序法測試

jackyq

帖子
319 
主題
6 
精華
0 
積分
309 
點名
0  
作業系統
xp 
軟體版本
2k 
閱讀權限
20 
性別
男 
註冊時間
2015-6-24 
最後登錄
2024-4-27 
11# 跳轉到 »
發表於 2017-2-15 17:01 | 只看該作者
(1) 用 value 會比較快
(2) 當初是因為在你的2維Sub測 AR2D( 1萬 , 300 ) ,看一下 Ram 最高峰可以爆到 600 MB, 才加上去
  現在 Sub 已經改成1維, 遞迴所需量大概會降為 600 MB / 300 = 2 MB , 可以拿掉 ReDim Preserve 會比較快  
(3)  UBound(原始二維陣列, 2) 也先代入變數會比較快, 但通常無感

TOP

linyancheng

帖子
228 
主題
73 
精華
2 
積分
333 
點名
0  
作業系統
Windows 10 
軟體版本
Office 2000, 2019 
閱讀權限
100 
性別
男 
來自
彰化縣 
註冊時間
2013-7-18 
最後登錄
2024-10-13 
12#
發表於 2017-2-15 18:02 | 只看該作者
回復 11# jackyq


    感謝指教，看來你蠻專業的！

TOP

linyancheng

帖子
228 
主題
73 
精華
2 
積分
333 
點名
0  
作業系統
Windows 10 
軟體版本
Office 2000, 2019 
閱讀權限
100 
性別
男 
來自
彰化縣 
註冊時間
2013-7-18 
最後登錄
2024-10-13 
13#
發表於 2017-2-17 00:44 | 只看該作者
最後優化，從原本的0.198秒→0.089秒
  1. Option Explicit
  2. Option Base 1
  3. Option Compare Text

  5. Public Sub S_二維陣列快速插入穩定遞增排序_01(ByRef 原始二維陣列 As Variant, ByVal 排序維度 As Long, ByVal 排序鍵值 As Long, ByVal 起限 As Long, ByVal 迄限 As Long)

  7.     On Error Resume Next
  8.    
  9.     If 起限 >= 迄限 Then
  10.         Exit Sub
  11.     End If
  12.    
  13.     '------------------------------------------------------
  14.    
  15.     Dim X As Long
  16.     Dim Y As Long
  17.    
  18.     Dim 擷取成一維陣列 As Variant
  19.     Dim 索引陣列() As Long
  20.    
  21.     '------------------------------------------------------
  22.    
  23.     ReDim 擷取成一維陣列(起限 To 迄限) As Variant
  24.     ReDim 索引陣列(起限 To 迄限) As Long
  25.    
  26.     If 排序維度 = 1 Then
  27.         For X = 起限 To 迄限
  28.             擷取成一維陣列(X) = 原始二維陣列(X, 排序鍵值)
  29.             索引陣列(X) = X
  30.         Next X
  31.     Else
  32.         For Y = 起限 To 迄限
  33.             擷取成一維陣列(Y) = 原始二維陣列(排序鍵值, Y)
  34.             索引陣列(Y) = Y
  35.         Next Y
  36.     End If
  37.    
  38.     '------------------------------------------------------
  39.    
  40.     二維陣列快速插入穩定遞增排序 擷取成一維陣列, 索引陣列, 起限, 迄限
  41.    
  42.     '------------------------------------------------------
  43.    
  44.     Dim 複製原始二維陣列 As Variant
  45.    
  46.     複製原始二維陣列 = 原始二維陣列
  47.    
  48.     If 排序維度 = 1 Then
  49.         For X = 起限 To 迄限
  50.             For Y = LBound(原始二維陣列, 2) To UBound(原始二維陣列, 2)
  51.                 原始二維陣列(X, Y) = 複製原始二維陣列(索引陣列(X), Y)
  52.             Next Y
  53.         Next X
  54.     Else
  55.         For Y = 起限 To 迄限
  56.             For X = LBound(原始二維陣列, 1) To UBound(原始二維陣列, 1)
  57.                 原始二維陣列(X, Y) = 複製原始二維陣列(X, 索引陣列(Y))
  58.             Next X
  59.         Next Y
  60.     End If

  62. End Sub

  64. Public Sub 二維陣列快速插入穩定遞增排序(ByRef 原始一維陣列 As Variant, ByRef 索引陣列() As Long, ByVal 起限 As Long, ByVal 迄限 As Long)

  66.     On Error Resume Next
  67.    
  68.     If 起限 >= 迄限 Then
  69.         Exit Sub
  70.     End If
  71.    
  72.     '------------------------------------------------------
  73.    
  74.     Dim X As Long
  75.     Dim Y As Long
  76.     Dim S As Long
  77.     Dim M As Long
  78.     Dim E As Long
  79.     Dim N As Long
  80.    
  81.     Dim 暫存 As Variant
  82.     Dim 索引暫存 As Long
  83.     Dim 基準 As Variant
  84.    
  85.     '------------------------------------------------------
  86.    
  87.     If 迄限 - 起限 < 16 Then
  88.         For X = 起限 + 1 To 迄限
  89.             暫存 = 原始一維陣列(X)
  90.             索引暫存 = 索引陣列(X)
  91.             
  92.             For Y = X - 1 To 起限 Step -1
  93.                 If 暫存 >= 原始一維陣列(Y) Then
  94.                     Exit For
  95.                 End If
  96.                
  97.                 原始一維陣列(Y + 1) = 原始一維陣列(Y)
  98.                 索引陣列(Y + 1) = 索引陣列(Y)
  99.             Next Y
  100.             
  101.             原始一維陣列(Y + 1) = 暫存
  102.             索引陣列(Y + 1) = 索引暫存
  103.         Next X
  104.     Else
  105.         Dim 基準陣列(3) As Variant
  106.         
  107.         基準陣列(1) = 原始一維陣列(起限)
  108.         基準陣列(2) = 原始一維陣列((起限 + 迄限) \ 2)
  109.         基準陣列(3) = 原始一維陣列(迄限)
  110.         
  111.         For X = 2 To 3
  112.             暫存 = 基準陣列(X)
  113.             
  114.             For Y = X - 1 To 1 Step -1
  115.                 If 暫存 >= 基準陣列(Y) Then
  116.                     Exit For
  117.                 End If
  118.                
  119.                 基準陣列(Y + 1) = 基準陣列(Y)
  120.             Next Y
  121.             
  122.             基準陣列(Y + 1) = 暫存
  123.         Next X
  124.         
  125.         基準 = 基準陣列(2)
  126.         
  127.         '------------------------------------------------------
  128.         
  129.         Dim 起陣列 As Variant
  130.         Dim 基陣列 As Variant
  131.         Dim 迄陣列 As Variant
  132.         Dim 索引起陣列() As Long
  133.         Dim 索引基陣列() As Long
  134.         Dim 索引迄陣列() As Long
  135.         
  136.         ReDim 起陣列(迄限 - 起限) As Variant
  137.         ReDim 基陣列(迄限 - 起限 + 1) As Variant
  138.         ReDim 迄陣列(迄限 - 起限) As Variant
  139.         ReDim 索引起陣列(迄限 - 起限) As Long
  140.         ReDim 索引基陣列(迄限 - 起限 + 1) As Long
  141.         ReDim 索引迄陣列(迄限 - 起限) As Long
  142.         
  143.         S = 0
  144.         M = 0
  145.         E = 0
  146.         For X = 起限 To 迄限
  147.             暫存 = 原始一維陣列(X)
  148.             索引暫存 = 索引陣列(X)
  149.             
  150.             If 暫存 < 基準 Then
  151.                 S = S + 1
  152.                 起陣列(S) = 暫存
  153.                 索引起陣列(S) = 索引暫存
  154.             ElseIf 暫存 = 基準 Then
  155.                 M = M + 1
  156.                 基陣列(M) = 暫存
  157.                 索引基陣列(M) = 索引暫存
  158.             Else
  159.                 E = E + 1
  160.                 迄陣列(E) = 暫存
  161.                 索引迄陣列(E) = 索引暫存
  162.             End If
  163.         Next X
  164.         
  165.         '------------------------------------------------------
  166.         
  167.         If S > 1 Then
  168.             二維陣列快速插入穩定遞增排序 起陣列, 索引起陣列, 1, S
  169.         End If
  170.         
  171.         If E > 1 Then
  172.             二維陣列快速插入穩定遞增排序 迄陣列, 索引迄陣列, 1, E
  173.         End If
  174.         
  175.         '------------------------------------------------------
  176.         
  177.         N = 起限 - 1
  178.         For X = 1 To S
  179.             N = N + 1
  180.             原始一維陣列(N) = 起陣列(X)
  181.             索引陣列(N) = 索引起陣列(X)
  182.         Next X
  183.         
  184.         For X = 1 To M
  185.             N = N + 1
  186.             原始一維陣列(N) = 基陣列(X)
  187.             索引陣列(N) = 索引基陣列(X)
  188.         Next X
  189.         
  190.         For X = 1 To E
  191.             N = N + 1
  192.             原始一維陣列(N) = 迄陣列(X)
  193.             索引陣列(N) = 索引迄陣列(X)
  194.         Next X
  195.     End If

  197. End Sub
複製代碼

TOP

        靜思自在 : 【行善要及時】行善要及時，功德要持續。如燒開水一般，未燒開之前千萬不要停熄火候，否則重來就太費事了。
12
返回列表 上一主題