[發問] 請問如何計算單月中之出現次數

棋語鳥鳴

如附件所示!請問各位大大:有什麼函數，可以計算單月中出現次數??
出現次數.rar (7.78 KB)

下載次數: 14

2011-10-12 21:29

進階統計
出現次數2.rar (8.43 KB)

下載次數: 4

2011-10-15 06:58

Hsieh

回復 1# 棋語鳥鳴

G9=SUMPRODUCT((TEXT(OFFSET($A$1,1,,COUNTA($A:$A),),"yyyym")=$G$6&$I$6)*(OFFSET($A$1,1,1,COUNTA($A:$A),)=$F9))
G14=SUMPRODUCT((TEXT(OFFSET($A$1,1,,COUNTA($A:$A),),"yyyym")=$G$6&$I$6)*(OFFSET($A$1,1,2,COUNTA($A:$A),)=$F14))

diabo

1. G9 =SUMPRODUCT(--($A$2:$A$20>=DATE($G$6, $I$6,1)), --($A$2:$A$20<DATE($G$6, $I$6+1,1)), --($B$2:$B$20=F9))
   
2. 
   
3. G14 =SUMPRODUCT(--($A$2:$A$20>=DATE($G$6, $I$6,1)), --($A$2:$A$20<DATE($G$6, $I$6+1,1)), --($C$2:$C$20=F14))

複製代碼

棋語鳥鳴

回復 2# Hsieh
回復 3# diabo
感謝2位大大的回覆~針對我所需要的快速解決了我的疑惑!
h大的~函數簡單明瞭!
至於d大函數內的東西很少看過~想請教一下~函數中的"--"是什麼意思??

diabo

回復  Hsieh
回復  diabo
至於d大函數內的東西很少看過~想請教一下~函數中的"--"是什麼意思??
順便問一下:
如果要統計那個月份總共有幾筆數據(意思就是日期中只要符合"年/月")，要如何設其函數??
棋語鳥鳴 發表於 2011-10-13 18:16

-- 是把邏輯值(True/False)轉為1/0
第1個引數是判斷日期是否大於等於指定年月的1日，是為True，不是為False，再利用--轉為1與0
第2個引數是判斷日期是否大於指定年月的下一個月的1日，是為True，不是為False，再利用--轉為1與0
第3個引數是判斷指定欄是否為指定物品，是為True，不是為False，再利用--轉為1與0

最後SUMPRODUCT就可以算出符合多條件的數量....

棋語鳥鳴

回復 5# diabo


    原來如此!所以我把最後那個引數刪掉，剛好等於月數~受教了!

棋語鳥鳴

回復 2# Hsieh


    請問一下h大~或其他高手~如果我想將此函數~改成統計此月份內"包含"某值，要如何修改其函數~還是有其他還數可用~
我目前作法是將後面改成"*"&F9&"*"不過好像無法用!

Hsieh

回復 7# 棋語鳥鳴


    G9=SUMPRODUCT((TEXT(OFFSET($A$1,1,,COUNTA($A:$A)-1,),"yyyym")=$G$6&$I$6)*ISNUMBER(FIND($F9,OFFSET($A$1,1,1,COUNTA($A:$A)-1,))))
如果還不是你要的答案請上傳檔案說明

棋語鳥鳴

回復 8# Hsieh


    檔案在此，麻煩您了!
出現次數2.rar (8.43 KB)

下載次數: 12

2011-10-15 06:56

diabo

沒想到還有 Part2

G9 公式如下，接著複製G9， 貼公式到其他G10-G12, G14-G15

1. =SUMPRODUCT(--($A$2:$A$20>=DATE($G$6,$I$6,1)),--($A$2:$A$20<DATE($G$6,$I$6+1,1)), --(ISNUMBER(FIND(F9,$B$2:$B$20))))

複製代碼

改第三個引數...