[發問] 如何VBA不指定軟體開啟特定檔案

morris_lth

之所以要這樣問是因為,下述程式中指定"C:\Program Files\Adobe\Reader 8.0\Reader\AcroRD32.exe"
來開啟PDF檔案,但是此excel 檔案是放在公用資料夾中,開檔的人未必使用的軟體或是路徑會是Reader 8.0,
有可能是9.0,有可能路徑不是C:\........

所以才想詢問是否有方式只給檔案路徑,至於開檔軟體的路徑種類依user本身電腦來決定就行

Private Sub CommandButton1_Click()
Shell "C:\Program Files\Adobe\Reader 8.0\Reader\AcroRD32.exe \\fileserver\PUB\QA\11 SIP\SIP\QCS001-MT1097X.pdf", vbNormalFocus
End Sub

stillfish00

回復 1# morris_lth
try this
ActiveWorkbook.FollowHyperlink "\\fileserver\PUB\QA\11 SIP\SIP\QCS001-MT1097X.pdf"

Joforn

1. #If VBA7 Then
   
2.   Private Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteW" (ByVal hWnd As LongPtr, ByVal lpOperation As LongPtr, ByVal lpFile As LongPtr, ByVal lpParameters As LongPtr, Optional ByVal lpDirectory As LongPtr = 0^, Optional ByVal nShowCmd As ShowCM = 1) As Long
   
3. #Else
   
4.   Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteW" (ByVal hWnd As Long, ByVal lpOperation As Long, ByVal lpFile As Long, ByVal lpParameters As Long, Optional ByVal lpDirectory As Long=0, Optional ByVal nShowCmd As ShowCM = 1) As Long
   
5. #End If
   
6. 
   
7. Public Enum ShowCM
   
8.   SW_SHOWNORMAL = 1&
   
9.   SW_SHOWMINIMIZED = 2&
   
10.   SW_SHOWMAXIMIZED = 3&
    
11.   SW_SHOWNOACTIVATE = 4&
    
12.   SW_SHOW = 5&
    
13.   SW_SHOWMINNOACTIVE = 7&
    
14.   SW_SHOWNA = 8&
    
15.   SW_SHOWDEFAULT = 10&
    
16. End Enum
    
17. 
    
18. 
    
19. Public Function ShellOpenFile(ByVal FileName As String, Optional ByVal ShowMode As ShowCM = 1)
    
20.   If Len(FileName) Then
    
21.     ShellOpenFile = ShellExecute(Application.hWnd, StrPtr("open"), StrPtr(FileName), 0, , ShowMode)
    
22.   End If
    
23. End Function
    
24. 
    
25. Sub Test()
    
26.   ShellOpenFile "\\fileserver\PUB\QA\11 SIP\SIP\QCS001-MT1097X.pdf" '可以是其它的文件名，只要系統能夠識別的文件類型，都會自動以Windows默認程式開啟指定的文件。比如指定的是.TXT文件，將會自動以Notepad.exe開啟
    
27.   ShellOpenFile "https://www.facebook.com/profile.php?id=100010420125898", SW_SHOWMAXIMIZED  '開啟網頁
    
28.   ShellOpenFile "MailTo:Joforn@sohu.com" '發送Email到指定的郵箱地址
    
29. End Sub

複製代碼

准提部林

試試：
VBA.CreateObject("WScript.Shell").Run """\\fileserver\PUB\QA\11 SIP\SIP\QCS001-MT1097X.pdf"""

morris_lth

謝謝,大家的方法都不錯