[發問] 增寫向左填滿的公式

https://blog.xuite.net/hcm19522/twblog/590097036

hcm19522

大學生 Rank: 4

帖子: 1391
主題: 4
精華: 0
積分: 1401
點名: 0
作業系統: WIN
軟體版本: 2007
閱讀權限: 50
性別: 男
註冊時間: 2015-9-11
最後登錄: 2024-12-16

熱烈參與勳章

14^#

發表於 2021-10-29 10:12 | 只看該作者

google"EXCEL迷" blog 或google網址:https://hcm19522.blogspot.com/

ziv976688

高中生 Rank: 3 Rank: 3

帖子: 678
主題: 147
精華: 0
積分: 799
點名: 0
作業系統: win 8
軟體版本: MS 2003
閱讀權限: 50
性別: 男
註冊時間: 2016-2-9
最後登錄: 2022-1-20

13^#

發表於 2021-10-29 02:29 | 只看該作者

回復 11# ML089
版大 :
您的函數公式修為真是爐火純青~佩服 !

最後末學採用的是 :
B12 =INDEX(5：5,SMALL(IF(COUNTIF($B7：$K7,$B5：$I5)=0,COLUMN($B5：$I5),99),COLUMN(A1)))&""
B14 =LOOKUP(1,IF({1;0},{0,""},INDEX(5：5,SMALL(IF(COUNTIF($B7：$K7,$B5：$I5)=0,COLUMN($B5：$I5)),COLUMN(A1)))^{0,1}))
因為這2個公式可以不綁定位址~在B：AY浮動的範圍內都可適用。

謝謝您耐心的指導多個公式~受惠良多~感恩

ziv976688

高中生 Rank: 3 Rank: 3

帖子: 678
主題: 147
精華: 0
積分: 799
點名: 0
作業系統: win 8
軟體版本: MS 2003
閱讀權限: 50
性別: 男
註冊時間: 2016-2-9
最後登錄: 2022-1-20

12^#

發表於 2021-10-29 02:00 | 只看該作者

回復 7# ML089
1_瞭解為何要採取MOD函數的用意了~謝謝您的耐心說明~感恩
2_多種將公式超拉的欄位顯示""的說明~受惠良多

帖子: 2025
主題: 13
精華: 0
積分: 2053
點名: 0
作業系統: WIN7
軟體版本: Office2007
閱讀權限: 100
性別: 男
來自: 台北市
註冊時間: 2011-3-2
最後登錄: 2024-3-14

論壇榮譽勳章論壇贊助勳章熱烈參與勳章 2014馬年全勤獎章 2015羊年全勤獎章 2016猴年全勤獎章

11^#

發表於 2021-10-28 23:42 | 只看該作者

回復 6# ziv976688

若是 2003版沒有 IFERROR 函數可以使用，也可用其他方式，例如lookup

B14 =LOOKUP(1,IF({1;0},{0,""},INDEX(5:5,SMALL(IF(COUNTIF($B7:$K7,$B5:$I5)=0,COLUMN($B5:$I5)),COLUMN(A1)))^{0,1}))
三鍵輸入右拉

{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

帖子: 2025
主題: 13
精華: 0
積分: 2053
點名: 0
作業系統: WIN7
軟體版本: Office2007
閱讀權限: 100
性別: 男
來自: 台北市
註冊時間: 2011-3-2
最後登錄: 2024-3-14

論壇榮譽勳章論壇贊助勳章熱烈參與勳章 2014馬年全勤獎章 2015羊年全勤獎章 2016猴年全勤獎章

10^#

發表於 2021-10-28 23:23 | 只看該作者

回復 6# ziv976688

B13 =IFERROR(INDEX(5:5,SMALL(IF(COUNTIF($B7:$K7,$B5:$I5)=0,COLUMN($B5:$I5)),COLUMN(A1))),"")
以錯誤來製造空格 IFERROR( …, "")

{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

帖子: 2025
主題: 13
精華: 0
積分: 2053
點名: 0
作業系統: WIN7
軟體版本: Office2007
閱讀權限: 100
性別: 男
來自: 台北市
註冊時間: 2011-3-2
最後登錄: 2024-3-14

論壇榮譽勳章論壇贊助勳章熱烈參與勳章 2014馬年全勤獎章 2015羊年全勤獎章 2016猴年全勤獎章

9^#

發表於 2021-10-28 23:19 | 只看該作者

回復 6# ziv976688

B12 =INDEX(5:5,SMALL(IF(COUNTIF($B7:$K7,$B5:$I5)=0,COLUMN($B5:$I5),99),COLUMN(A1)))&""

這是採用 column 99 位置為空格 & "" 來製造空格

{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

帖子: 2025
主題: 13
精華: 0
積分: 2053
點名: 0
作業系統: WIN7
軟體版本: Office2007
閱讀權限: 100
性別: 男
來自: 台北市
註冊時間: 2011-3-2
最後登錄: 2024-3-14

論壇榮譽勳章論壇贊助勳章熱烈參與勳章 2014馬年全勤獎章 2015羊年全勤獎章 2016猴年全勤獎章

8^#

發表於 2021-10-28 23:15 | 只看該作者

回復 6# ziv976688

B11 =IF(COLUMN(A1)>COUNT(0/(COUNTIF($B7:$K7,$B5:$I5)=0)),"",SMALL(IF(COUNTIF($B7:$K7,$B5:$I5)=0,$B5:$I5),COLUMN(A1)))
三鍵輸入，右拉

以數字大小排列方式，用 IF(超過數量時, "", 計算)

{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

帖子: 2025
主題: 13
精華: 0
積分: 2053
點名: 0
作業系統: WIN7
軟體版本: Office2007
閱讀權限: 100
性別: 男
來自: 台北市
註冊時間: 2011-3-2
最後登錄: 2024-3-14

論壇榮譽勳章論壇贊助勳章熱烈參與勳章 2014馬年全勤獎章 2015羊年全勤獎章 2016猴年全勤獎章

7^#

發表於 2021-10-28 23:07 | 只看該作者

回復 6# ziv976688

B10
=IF(ISERROR(MOD(SMALL(IF(COUNTIF(7:7,$B5:$Z5)=0,$B5:$Z5+COLUMN($B:$Z)*10^5),COLUMN(A1)),10^5)),"",MOD(SMALL(IF(COUNTIF(7:7,$B5:$Z5)=0,$B5:$Z5+COLUMN($B:$Z)*10^5),COLUMN(A1)),10^5))
1_末學不太理解~公式中為何會需要用到取餘數的MOD函數?
說明：為了排列位置不變，要以COLUMN NO 作為排序主導，$B5:$Z5 + COLUMN($B:$Z)*10^5 = {200017, ....} 使用SMALL排序，取出值用 MOD( 200017, 10^5) 取出 17 值

2_如果第5列有顯示數字的欄位不確定，如何將公式超拉的欄位顯示""。
超拉變成 "" 方式很多
1 製造錯誤，用IFERROR( ..., "") 來變成 ""
2 製造空格位置，空格用 &"" 會變成 ""，不然會成為 0 ，但其他數字都會變成文字型數字
3 計算有多少量要顯示，超過數量時為 ""，IF( 超量判斷, "", 計算式)
4 其他方式

{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式