ML089

還不是很完美，參考看看
陣列公式
AQ3 =MAX(--TEXT(INDEX(INDIRECT(MID($AQ$1,3,3)),MID($AP3,2,3),),"[>="&IF(AO13,AO13,999)&"]!0"))
AR3 =INDEX(INDIRECT(MID($AQ$1,3,3)),2,MATCH(AQ3,INDEX(INDIRECT(MID($AQ$1,3,3)),MID($AP3,2,3),),))
兩式下拉

複製 AQ3:AR7 至AS3:AV7

ML089

要一式全部拉到底，需要將資料欄位對齊，不然公式會又臭又長。

ML089

回復 12# ziv976688

剛好六日都有事沒有辦法立即回覆
(1)
AQ3 =MAX(--TEXT(INDEX($B:$G,$AP3,),"[>="&IF(AO3,AO3,999)&"]!0"))
AR3 =INDEX($B:$G,2,MATCH(AQ3,INDEX($B:$G,$AP3,),))
複製 AQ3:AR3
貼上 AQ4:AR7
複製 AQ3:AR7
貼上 AS3:AV7

(2)
複製 AQ3:AR3
貼上各區的左上角儲存格
將公式中的 $B:$G 修改為
  木($H:$P)
  水($Q:$X)
  火($Y:$AF)
  土($AG:$AN)                       

如(1) 複製及貼上 該區公式

(3) 當然公式也可以自動抓取 第一列中如下的文字，利用INDIRECT轉為區域，但不需付出超長公式作為代價，建議用手動修改比較容易維護公式。
  金($B:$G)
  木($H:$P)
  水($Q:$X)
  火($Y:$AF)
  土($AG:$AN)

比大小&重複取其1的函數公式(1).rar (20.29 KB)

下載次數: 2

2019-9-9 20:40

ML089

回復 14# ziv976688

(1)        AQ3 =MAX(--TEXT(INDEX($B:$G,$AP3,),"[>="&IF(AQ$1="",AO3,999)&"]!0"))
        AR3 =INDEX($B:$G,2,MATCH(AQ3,INDEX($B:$G,$AP3,),))
        陣列公式

(2)        AQ3 =MAX(--TEXT(INDEX($B:$G,$AP3,),"[>="&IF(AQ$1="",AO3,999)&"]!0"))
        AR3 =SUBSTITUTE(TEXT(SUM(LARGE(IF(INDEX($B:$G,$AP3,)=AQ3,$B$2:$G$2,0),{1,2,3,4,5})*10^{0,2,4,6,8}),"00"&REPT("!,00",4)),"00,",)
        陣列公式

(1)式的AR7會顯示 21  (數字)
(2)式的AR7會顯示 21,22 (文字)

比大小&重複取其1的函數公式(2).rar (20.94 KB)

下載次數: 5

2019-9-10 21:06

ML089

回復 17# ziv976688

取大至小
AQ3 =MAX(--TEXT(INDEX($B:$G,$AP3,),"[>="&IF(AQ$1="",AO3,999)&"]!0"))

取小至大
AQ3 =MIN(--TEXT(INDEX($B:$G,$AP3,),"[<="&IF(AQ$1="",AO3,-1)&"]!9!9"))

ML089

回復 20# ziv976688

因為次數的顯示值9999，會讓比大小的作用失真，所以是否能不要顯示"9999"，而能顯示"0"，
當然能顯示"空白"是最好不過了~但不敢強求，包括前3大的次數顯示"0"能改顯示"空白"亦同。

我習慣用 999 9999 這樣的數字代表 溢位
公式是看前面的數字用TEXT的數字大小篩選功能來決定哪些數字要留下，若前面是 "" 時公式就沒有判斷依據
當然你講的都能做，公式變複雜
不習歡看到 9999 也可以用 儲存格格式功能來遮蔽 "[=9999] ;0"，或 設定格式化條件 當9999時字的顏色與底色相同。