返回列表 上一主題 發帖

[發問] 請問如何從多個關聯工作表中取得所需資料？

准提部林

帖子
2848 
主題
10 
精華
0 
積分
2903 
點名
0  
作業系統
〔略〕 
軟體版本
〔略〕 
閱讀權限
100 
性別
男 
來自
〔略〕 
註冊時間
2013-5-13 
最後登錄
2026-7-25 
1# 跳轉到 »
發表於 2015-9-5 10:58 | 顯示全部帖子
如果〔表Ｂ〕同一〔客戶代碼〕有一個以上的〔送貨地址〕，
主表無〔送貨地址〕索引是無法查！

若〔表Ｂ．客戶代碼〕具唯一性：
Ｄ３：=LOOKUP(,0/(A3=J$3:J$16)/(VLOOKUP(A3,F$13:G$19,2,)=K$3:K$16),L$3:L$16)
　

TOP

准提部林

帖子
2848 
主題
10 
精華
0 
積分
2903 
點名
0  
作業系統
〔略〕 
軟體版本
〔略〕 
閱讀權限
100 
性別
男 
來自
〔略〕 
註冊時間
2013-5-13 
最後登錄
2026-7-25 
2#
發表於 2015-9-7 11:24 | 顯示全部帖子
本帖最後由 准提部林 於 2015-9-7 11:26 編輯

回復 8# 97forum

這是〔雙條件〕找查：
條件１：客戶代碼＝Ｊ欄，(A3=J$3:J$16)
條件２：送貨地址＝Ｋ欄，但〔送貨地址〕須從〔表Ｂ〕抓出，故須先配一次　VLOOKUP(A3,F$13:G$19,2,)　以抓出相對應值，
　　　　然後再與Ｋ欄比對：(VLOOKUP(A3,F$13:G$19,2,)=K$3:K$16)

以上兩公式合併：=(A3=J$3:J$16)/(VLOOKUP(A3,F$13:G$19,2,)=K$3:K$16)，
會產生含〔０，１．錯誤值〕的陣列，
例如：{0;1;0;0;0;0;0;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!}

透過：0/(A3=J$3:J$16)/(VLOOKUP(A3,F$13:G$19,2,)=K$3:K$16)　轉化，只會出現〔０．錯誤值〕陣列，
轉化結果：{#DIV/0!;0;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!}

　
=LOOKUP(0,0/(A3=J$3:J$16)/(VLOOKUP(A3,F$13:G$19,2,)=K$3:K$16),L$3:L$16)

LOOKUP即可找出０的位置，並取出與其相對應位置Ｌ欄的內容，
註：LOOKUP第一參數，使用0,1或更大值，其效果相用∼
　

TOP

        靜思自在 : 難行能行，難捨能捨，難為能為，才能昇華自我的人格。
返回列表 上一主題