返回列表 上一主題 發帖

擷取數字

Qin

帖子
207 
主題
61 
精華
0 
積分
270 
點名
0  
作業系統
Vista 
軟體版本
office2003 
閱讀權限
20 
性別
女 
註冊時間
2011-3-20 
最後登錄
2023-6-25 
1# 跳轉到 » 倒序看帖
打印
tT
發表於 2012-12-10 21:40 | 只看該作者

擷取數字

如何只擷取數字:

秋刀魚(AAA)(5g/Pc)
鱔魚(AAAA)(4.5g/Pc)
鰻魚(AA)(3.5g/Pc)
魚(A)(0.55g/Pc)

答案:
5
4.5
3.5
0.55
收藏 分享

Hsieh

帖子
4901 
主題
44 
精華
24 
積分
4916 
點名
103  
作業系統
Windows 7 
軟體版本
Office 20xx 
閱讀權限
150 
性別
男 
來自
台北 
註冊時間
2010-4-30 
最後登錄
2025-4-29 

2024年全勤獎章2023年全勤獎章2022虎年全勤獎章2021牛年全勤獎章2020鼠年全勤獎章2019 豬年全勤獎章2018 狗年全勤獎章2017 雞年全勤獎章2016猴年全勤獎章2015羊年全勤獎章2014馬年全勤獎章2013蛇年全勤獎章2012龍年全勤獎章論壇貢獻勳章熱心公益勳章2011兔年全勤獎章
2#
發表於 2012-12-10 22:14 | 只看該作者
回復 1# Qin
陣列公式
=LOOKUP(9999,--MID(A1,MATCH(1,1/ISNUMBER(--MID(A1,ROW(INDIRECT("A1:A"&LEN(A1))),1)),0),ROW(INDIRECT("A1:A"&LEN(A1)))))
學海無涯_不恥下問

TOP

Qin

帖子
207 
主題
61 
精華
0 
積分
270 
點名
0  
作業系統
Vista 
軟體版本
office2003 
閱讀權限
20 
性別
女 
註冊時間
2011-3-20 
最後登錄
2023-6-25 
3#
發表於 2012-12-10 22:39 | 只看該作者
回復 2# Hsieh

不行, 答案是 #N/A

TOP

Qin

帖子
207 
主題
61 
精華
0 
積分
270 
點名
0  
作業系統
Vista 
軟體版本
office2003 
閱讀權限
20 
性別
女 
註冊時間
2011-3-20 
最後登錄
2023-6-25 
4#
發表於 2012-12-10 22:41 | 只看該作者
回復 3# Qin


  Sorry, 可以了

TOP

p212

帖子
618 
主題
17 
精華
0 
積分
663 
點名
1  
作業系統
WINDOWS 7 
軟體版本
OFFICE 2013 
閱讀權限
50 
性別
男 
來自
Pingtung 
註冊時間
2011-9-2 
最後登錄
2025-1-2 

2014馬年全勤獎章2013蛇年全勤獎章熱烈參與勳章
5#
發表於 2012-12-11 14:44 | 只看該作者
回復 1# Qin
假設A1儲存格的值為  秋刀魚(AAA)(5g/Pc)
B1儲存格組合函數為  =MID(A1,SEARCH(")",A1)+2,SEARCH("g",A1)-(SEARCH(")",A1)+2))

說明1_SEARCH(")",A1)+2目的在找出第二個左括弧之後數字所在位置  ---即為MID函數的start_num
說明2_找出「g」座落的位置用  SEARCH("g",A1)
說明3_說明_2的結果減去說明_1的結果SEARCH("g",A1)-(SEARCH(")",A1)+2) ---即為MID函數的num_chars

TOP

zz5151353

帖子
206 
主題
3 
精華
0 
積分
218 
點名
0  
作業系統
WIN10 
軟體版本
OFFICE 365 
閱讀權限
100 
性別
男 
來自
台灣台北 
註冊時間
2010-5-15 
最後登錄
2023-6-18 
6#
發表於 2012-12-13 16:18 | 只看該作者
如何只擷取數字:

秋刀魚(AAA)(5g/Pc)
鱔魚(AAAA)(4.5g/Pc)
鰻魚(AA)(3.5g/Pc)
魚(A)(0.55g/Pc)

答 ...
Qin 發表於 2012-12-10 21:40


{=LOOKUP(9^9,--MID(A1,MIN(FIND(ROW($1:$10)-1,A1&1234567890)),ROW(INDIRECT("1:"&LEN(A1)))))}
300 字節以內
不支持自定義 Discuz! 代碼

TOP

alex_wu

帖子
60 
主題
18 
精華
0 
積分
83 
點名
0  
作業系統
NT 
軟體版本
OFFICE2003 
閱讀權限
20 
性別
男 
註冊時間
2010-7-9 
最後登錄
2024-12-13 
7#
發表於 2012-12-13 18:35 | 只看該作者
資料擺在A列 , 使用MID+FIND作法如下
=MID(A1,FIND(")(",A1,1)+2,FIND("g/Pc",A1,1)-FIND(")(",A1,1)-2)

TOP

ML089

帖子
2025 
主題
13 
精華
0 
積分
2053 
點名
0  
作業系統
WIN7 
軟體版本
Office2007 
閱讀權限
100 
性別
男 
來自
台北市 
註冊時間
2011-3-2 
最後登錄
2024-3-14 

論壇榮譽勳章論壇贊助勳章熱烈參與勳章2014馬年全勤獎章2015羊年全勤獎章2016猴年全勤獎章
8#
發表於 2013-5-9 01:57 | 只看該作者
本帖最後由 ML089 於 2013-5-9 02:00 編輯

LOOKUP很適用於陣列公式，但多層的ROW()也推不動

將6樓公式下修改一下，就不用陣列公式輸入法(CSE輸入方式)輸入公式
  1. =-LOOKUP(,-MID(A1,MIN(FIND({0,1,2,3,4,5,6,7,8,9},A1&5/19)),ROW($1:$15)))
複製代碼
5/19 = 0.2631578947 數字包含 0~9都有
將ROW(1:10)-1改為{0,1,2,3,4,5,6,7,8,9}就可以免用 CSE 輸入法。
另外ROW(1:20)改為ROW(1:15)，因為最大有效位數只有15位，節省一點CPU時間。
將9^9刪除，因為此公式只能找正數字，用-MID(...)變成負數再用0來找，最後用-LOOKUP(...)還原為正數。
{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

TOP

        靜思自在 : 慈悲沒有敵人，智慧不起煩惱。
返回列表 上一主題