如何將台指期的每一分鐘資料都紀錄在sheet 1裡..請教版上高手前輩~~

各位高手前輩：中秋佳節快樂

我曾套用，版上大分享的程式碼，連上[看盤軟體DDE]卻不會動。想請問版大，我該怎麼改才可以使用。
現在我想重新建立新的檔，請先讓我簡單說明我的需求：
1.sheet 4 是看盤軟體DDE輸出到Excel的資料。
2.我希望能將台指期的每一分鐘資料都紀錄在sheet 1裡，不是直接紀錄DDE回傳的資料，
而是紀錄sheet 4每一分鐘的[成交價][最高][最低][成交量]
以上用Excel不知是否可行？請教版上高手前輩~~

附上：我的[看盤軟體DDE]轉出到Excel沒程式碼的(如圖)

TX00a.zip (4.99 KB)

樓主熱帖

50 字節以內
不支持自定義 Discuz! 代碼

c_c_lai

博士班 Rank: 6 Rank: 6

帖子: 2035
主題: 24
精華: 0
積分: 2031
點名: 0
作業系統: Win7
軟體版本: Office2010
閱讀權限: 100
性別: 男
註冊時間: 2012-3-22
最後登錄: 2024-2-1

2^#

發表於 2012-9-29 12:42 | 只看該作者

回復 1# cfuxiong
中秋佳節快樂！
我在 Sheet4 多增加一個欄位，專為處理每一分鐘後之 "成交量" 數據。

如何將台指期的每一分鐘資料都紀錄.rar (17.24 KB)

TOP

cfuxiong

中學生 Rank: 2

帖子: 93
主題: 18
精華: 0
積分: 111
點名: 0
作業系統: XP
軟體版本: OFFICE
閱讀權限: 20
性別: 男
來自: 台灣‧高雄
註冊時間: 2010-10-22
最後登錄: 2023-3-3

論壇贊助勳章

3^#

發表於 2012-9-29 13:21 | 只看該作者

回復 2# c_c_lai
最佳的中秋節禮物...擁滿懷的『感謝』給你[c_c_lai]~~
剛剛測試很滿意，接著等星期一再實測了~~謝謝~~

50 字節以內
不支持自定義 Discuz! 代碼

TOP

c_c_lai

博士班 Rank: 6 Rank: 6

帖子: 2035
主題: 24
精華: 0
積分: 2031
點名: 0
作業系統: Win7
軟體版本: Office2010
閱讀權限: 100
性別: 男
註冊時間: 2012-3-22
最後登錄: 2024-2-1

4^#

發表於 2012-9-29 21:04 | 只看該作者

為了讓更多人進一步明瞭整體的作業過程，未來也可以自己在實務上實際演練
及摩擬，故將作業畫面與程式一併貼附上來分享。
希望每個人都能從中學習領悟、寫出更佳的程式，再將成果分享提供給大家！

Option Explicit
Dim Ov As Single, Hv As Single, Lv As Single, Cv As Single
Dim timerEnabled As Boolean ' 判定開啟本工作表單的時段是否為開盤前啟動。
Public turnKey As Integer
Private Sub Workbook_Open()
timerEnabled = False
Sheets("Sheet4").[I2] = Sheets("Sheet4").[H2] ' 設定前成交量
Call timerStart ' 程式一啟始，便去自動執行 timerStart
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
On Error Resume Next
Application.OnTime Now + TimeValue("00:00:01"), "ThisWorkbook.RTimer", , False
Me.Save
End Sub
Public Sub RTimer(tm As Date)
Dim TimeRange As Range, Rng As Range
Dim pos As Integer
On Error Resume Next
If (TimeValue(Now) > TimeValue("13:45:00")) Then Exit Sub
If (TimeValue(Now) >= TimeValue("08:45:00")) Then ' 開盤、收盤時段設定
' 盤中處理，將資料匯入寫入工作表單內儲存。
With Sheets("Sheet1")
If Not IsError(.[B2]) Then
.[B1] = "成交價"
.[C1] = "最高價"
.[D1] = "最低價"
.[E1] = "成交量"
Set TimeRange = .[A:A].Find(TimeSerial(Hour(tm), Minute(tm), 0)) ' 檢查 "A" 欄位對應之時間資料
Set Rng = TimeRange.Offset(, 1).Resize(1, 4)
Rng(1) = Cv ' 成交價
Rng(2) = Hv ' 最高價
Rng(3) = Lv ' 最低價
Rng(4) = Sheets("Sheet4").[H2] - Sheets("Sheet4").[I2] ' 成交量
Sheets("Sheet4").[I2] = Sheets("Sheet4").[H2] ' 重新設定前成交量
End If
End With
End If
End Sub
Sub timerStart()
turnKey = 0 ' 計數器重新歸零
Sheets("Sheet4").[A3] = "( " & turnKey & " 秒 )"
If timerEnabled Then
' 第二次(含)以後均以設定之 "間隔時段" 來處理執行序的作業。
Application.OnTime (Now + TimeValue("00:00:01")), "ThisWorkbook.inProcess"
Else
timerEnabled = True
' 將第一次啟動時間更改為設定 "開盤時間"前，如果開啟 Excel 時，已經過了設定 "開盤時間"，則一進入系統即直接去執行紀錄作業。
If (TimeValue(Now) <= TimeValue("08:45:00")) Then
Sheets("Sheet1").[B2:E301].ClearContents ' 清除前一日之資料
Application.OnTime (TimeValue("08:45:00")), "ThisWorkbook.inProcess"
Else
' 系統剛連上 DDE 至資料匯入Excel工作表單，須有一個緩衝時段，
' 這時如果馬上去抓取DDE資料，會有型態不符的錯誤訊息產生，並中斷執行序的作業。
Application.OnTime (Now + TimeValue("00:00:05")), "ThisWorkbook.inProcess"
End If
End If
End Sub
Private Sub inProcess()
Static Msg As Boolean ' 用以判定是否為每日第一次執行
Static timeCalc As Date ' 記錄每分鐘的時間
On Error Resume Next
If (TimeValue(Now) < TimeValue("08:45:00") Or TimeValue(Now) > TimeValue("13:46:01")) Then Exit Sub
If Msg = False Then
timeCalc = TimeSerial(Hour(Time), Minute(Time), 0) ' 設定目前起始的時間
Msg = True
End If
If IsError(Sheets("Sheet4").Range("B2").Value) Then
Cv = 0
Else
Cv = Sheets("Sheet4").Range("B2").Value ' 成交價
End If
If (turnKey = 0 Or Ov = 0) Then
Ov = Cv ' 開盤價
Hv = Cv ' 最高價
Lv = Cv ' 最低價
End If
If (Cv > Hv) Then Hv = Cv ' 最高價
If (Cv < Lv) Then Lv = Cv ' 最低價
turnKey = turnKey + 1
Sheets("Sheet4").[A3] = "( " & turnKey & " 秒 )"
If Time >= timeCalc + #12:01:00 AM# Then
If (Cv > 0) Then Call RTimer(Time)
timeCalc = TimeSerial(Hour(Time), Minute(Time), 0) ' 重新設定下一分鐘比對的時間
If timerEnabled Then Call timerStart
Else
Application.OnTime (Now + TimeValue("00:00:01")), "ThisWorkbook.inProcess"
End If
End Sub