如何將多個檔案，相同格式的數值，透過VBA加總成一個檔案

lai.k.h

各位老師好，因工作需要一次將30幾個不同檔案但是檔案格式相同的數值彙整為一份檔案，希望能透過VBA的方式完成，請各位老師不吝指導，謝謝。PS.僅需加總附檔中黃色區塊的數值即可。

GBKEE

回復 1# lai.k.h

1. Sub Ex()
   
2.     Dim MyRng(1 To 2) As Range, Rng(1 To 2) As Range, i As Integer, R As Integer, C As Integer
   
3.     Dim OpFile As String
   
4.     With ThisWorkbook.Sheets("Sheet1")
   
5.         Set MyRng(1) = .[B9:AR9]                        '輸入區
   
6.         Set MyRng(2) = .[B13:AR15]                      '輸入區
   
7.     End With
   
8.     OpFile = Dir(ThisWorkbook.Path & "\*.xls")          '尋找檔案   '檔案在同一目錄下
   
9.     'OpFile = Dir("d:\test" & "\*.xls")                 '檔案不在同一目錄下
   
10.     Do While OpFile <> ""                               '找到檔案
    
11.         If OpFile <> "" And OpFile <> ThisWorkbook.Name Then
    
12.             'With Workbooks.Open("d:\test\" & OpFile).Sheets("Sheet1")             '檔案不在同一目錄下
    
13.             With Workbooks.Open(ThisWorkbook.Path & "\" & OpFile).Sheets("Sheet1") '開啟檔案
    
14.                 Set Rng(1) = .[B9:AR9]                      '資料區
    
15.                 Set Rng(2) = .[B13:AR15]                    '資料區
    
16.                 For i = 1 To UBound(MyRng)                  '依序在輸入區
    
17.                     For C = 1 To MyRng(i).Columns.Count     '輸入區的欄位
    
18.                         For R = 1 To MyRng(i).Rows.Count    '輸入區的列位
    
19.                             MyRng(i).Cells(R, C) = MyRng(i).Cells(R, C) + Rng(i).Cells(R, C)                            '讀取紀錄
    
20.                         Next
    
21.                     Next
    
22.                 Next
    
23.                .Parent.Close False    '關閉檔案
    
24.                '.Parent ->(???).Sheets("Sheet1")的父層->Workbooks(ThisWorkbook.Path & "\" & OpFile)
    
25.             End With
    
26.         End If
    
27.         OpFile = Dir                                         '往下一檔案
    
28.     Loop
    
29. End Sub

複製代碼

lai.k.h

回復 2# GBKEE


    Dear GBKEE,
    非常感謝您的回覆，消化中，謝謝。