只顯示沒有重覆的資料

enoch

各位高手:
有兩欄資料, 如何將兩欄資料合併後
再只顯示沒有重覆的資料
我現時需要加上一欄先將資料合併,
再用countif去顯示, 但可以有更簡方法嗎
請指教:

資料1        資料2        顯示沒有重覆資料
1        a        1a
1        a       
1        b        1b
1        b       
1        c        1c
2        a        2a
2        a       
2        b        2b
2        b       
2        c        2c
2        c       
3        a        3a
3        b        3b
3        c        3c
3        d        3d

oobird

=IF(SUMPRODUCT(1*(A$2:A2&B$2:B2=A2&B2))=1,A2&B2,"")

enoch

多謝oobird
又是用到sumproduct, 我始終唔明白這公式用法
可否講解sumproduct 點用嗎?

oobird

先以SUMPRODUCT
google一下吧。
還有盲點再提出討論

man65boy

=IF(SUM(--(COUNTIF($C$2:$C$18,$C$2:$C$18)=1))>=ROW(A1),INDEX($C$2:$C$18,SMALL(IF(COUNTIF($C$2:$C$18,$C$2:$C$18)=1,ROW($C$2:$C$18),""),ROW(A1))-1),"")

陣列公式輸入完須按 Ctrl+Shift+Enter 三鍵才可得到

0823.rar (3.03 KB)

下載次數: 9

2011-8-24 00:18

enoch

睇過說明後, 始終有問題,
sumproduct 類似sumif 及 countif 但還分唔清點用
若以下面例子, 當種類相同, 可以只顯示最大數量的金額嗎?
例如蘋果 :$18  ;橙 $19
請指教

數量  種類  金額
15    蘋果  $5
20    蘋果  $10
35    蘋果  $18
2     橙    $7
3     橙    $19

oobird

下載 (23.75 KB)

2011-8-25 15:18

man65boy

有點搞不清楚板大標題是在問甚麼，針對在提問的問題

=INDEX($C$2:$C$6,MATCH(MAX(($B$2:$B$6=E2)*($A$2:$A$6)),$A$2:$A$6,0))

陣列公式輸入完須按 Ctrl+Shift+Enter 三鍵

0825.rar (3.58 KB)

下載次數: 8

2011-8-25 20:48

試看看!!!

enoch

不好意思, 是我太懶沒有分開問題,
而兩位高手所教導的使我得益不少

man65boy 的公式出現少少問題:
=INDEX($C$2:$C$6,MATCH(MAX(($B$2:$B$6=E2)*($A$2:$A$6)),$A$2:$A$6,0))
當蘋果與橙的數量相同時, 公式只會取蘋果的金額

man65boy

拍事..驗證太少...沒注意到，在試試以下函數

=IF(ISNA(INDEX($C$2:$C$20,MATCH(E2&MAX(IF(($B$2:$B$20=E2),$A$2:$A$20)),$B$2:$B$20&$A$2:$A$20,0))),"",INDEX($C$2:$C$20,MATCH(E2&MAX(IF(($B$2:$B$20=E2),$A$2:$A$20)),$B$2:$B$20&$A$2:$A$20,0)))

陣列公式輸入完須按 Ctrl+Shift+Enter 三鍵
0827.rar (3.98 KB)

下載次數: 14

2011-8-27 13:15