shuo1125

回復 20# Andy2483
Andy大好!
你這效率太驚人了...我有空再做測試，
還提供多種解法及註解..謝謝你!

shuo1125

回復 20# Andy2483
Andy大!
經測試過後可使用，感謝你屢次協助...

Andy2483

回復 22# shuo1125


    前輩早安,謝謝發表主題與範例給後學學習,謝謝論壇
1.提醒前輩 資料區表的資料在 系統裡排序好才撈出,就不必在excel排序
2.若有後續問題,請不吝再提出,如果偏離此主題,請另開新主題
3.請前輩常上論壇一起學習

shuo1125

回復 23# Andy2483
Andy大!

1.提醒前輩 資料區表的資料在 系統裡排序好才撈出,就不必在excel排序
  >好的，謝謝提醒...
2.若有後續問題,請不吝再提出,如果偏離此主題,請另開新主題
  >有時候是怕耽擱大家時間，若有特別問題在提出了..
3.請前輩常上論壇一起學習
  >我程度不夠，只能慢慢摸索了...謝謝你的協助!

Andy2483

回復 7# shuo1125


    謝謝前輩
以下是後學練習儲存格與陣列對照應用的R欄餘額計算解決方案,請前輩參考

Option Explicit
Sub 資料區餘額()
Dim Arr, T16&, T17&, T18&, i&, S&, T$, T2$, T3$, T20$, xR As Range
'↑宣告變數:Arr是通用型變數,(T16,T17,T18,i)是長整數,
'(T,T2,T3,T20)是字串變數
Set xR = Range([資料區!T1], [資料區!A1].Cells(Rows.Count, 1).End(3))
'↑令xR這儲存格變數是 資料區[T2]到 A欄最後有內容儲存格範圍儲存格
Arr = xR
'↑令Arr這通用型變數是 二維陣列,以 xR儲存格值帶入
For i = 1 To UBound(Arr)
'↑設順迴圈!i從1到 Arr陣列縱向最大索引列號
   If i = 1 Then GoTo i01
   '↑如果i變數是 1!就跳到 i01標示位置繼續執行
   T2 = Arr(i, 2): T3 = Arr(i, 3): T16 = Arr(i, 16)
   T17 = Arr(i, 17): T18 = Arr(i, 18): T20 = Arr(i, 20)
   '↑令T2這字串變數是 i迴圈列第2欄Arr陣列值,依此類推
    If Val(T16) > Val(T17) Then
    '↑如果T16變數經轉化的數值 大於 T17變數經轉化的數值??
       T18 = T16 - T17
       '↑if條件成立!就令 T18變數是 T16 - T17變數
       Else
          T18 = Val(T17) - Val(T16)
          '↑否則!就令 T18變數是 T17變數 - T16變數
    End If
   If T <> T2 & "|" & T3 Then
   '↑如果T這字串變數 不等於 T2變數連接 T3變數組成的新字串
      xR.Range("R" & i).Value = T18
      '↑令xR變數的[R2]儲存格值是 T18變數
      T = T2 & "|" & T3
      '↑令T這字串變數是 T2變數連接 T3變數組成的新字串
      ElseIf T20 = "立帳" Then
         xR.Range("R" & i) = xR.Range("R" & i - 1) + T18
         '↑否則令xR變數的R欄(i迴圈數)列儲存格值是
         'xR變數的R欄(i迴圈數-1)列儲存格值 +T18變數
      ElseIf T20 = "沖帳" Then
         xR.Range("R" & i) = xR.Range("R" & i - 1) - T18
         '↑否則令xR變數的R欄(i迴圈數)列儲存格值是
         'xR變數的R欄(i迴圈數-1)列儲存格值 -T18變數
   End If
i01:
Next
Erase Arr: Set xR = Nothing
'↑令釋放變數
End Sub

Andy2483

回復 24# shuo1125


    謝謝前輩
後學藉此帖發現這字典是個萬能的變數產生器
1.因為變數不會重複,所以key可以濾重複
2.因為key對應一個item(數字.字串.儲存格.陣列....),所以key可當成是一個變數


Option Explicit
Sub 資料區餘額_1()
Dim Y, Arr, T16&, T17&, T18&, i&, S&, T$, T2$, T3$, T20$, xR As Range
'↑宣告變數:(Y,Arr)是通用型變數,(T16,T17,T18,i)是長整數,
'(T,T2,T3,T20)是字串變數,xR是儲存格變數
Set Y = CreateObject("Scripting.Dictionary")
'↑令Y這通用型變數是 字典
Set xR = Range([資料區!T2], [資料區!A1].Cells(Rows.Count, 1).End(3))
'↑令xR這儲存格變數是 資料區[T2]到 A欄最後有內容儲存格範圍儲存格
Arr = xR
'↑令Arr這通用型變數是 二維陣列,以 xR儲存格值帶入
For i = 1 To UBound(Arr)
'↑設順迴圈!i從1到 Arr陣列縱向最大索引列號
   T2 = Arr(i, 2): T3 = Arr(i, 3): T16 = Arr(i, 16)
   T17 = Arr(i, 17): T18 = Arr(i, 18): T20 = Arr(i, 20)
   '↑令T2這字串變數是 i迴圈列第2欄Arr陣列值,依此類推
   T18 = Abs(T16 - T17)
   '↑令T18這長整數變數是 T16變數 - T17變數後的絕對值數值
   T = T2 & "|" & T3
   '↑令T這字串變數是 T2變數連接 T3變數組成的新字串
   If Y(T) = "" And T20 = "沖帳" Then MsgBox "嚴重錯誤": Exit Sub
   '↑如果一開始就是沖帳!是嚴重錯誤得資料
   If T20 = "立帳" Then
   '↑如果 T20變數是 "立帳" ?
      Y(T) = Y(T) + T18
      '↑令T變數在Y字典item值累加 T18變數
      ElseIf T20 = "沖帳" Then
         '↑否則如果 T20變數是 "沖帳" ?
         Y(T) = Y(T) - T18
         '↑令T變數在Y字典item值累扣 T18變數
      Else
         MsgBox "無法辨識": Application.Goto xR(i, 20): Exit Sub
         '↑否則就跳出提示窗,儲存格游標跳到R欄i迴圈列位置:結束程式
   End If
   Arr(i, 18) = Y(T)
   '↑令i迴圈列第18欄Arr陣列值是T變數查Y字典的item值
Next
[A2].Resize(UBound(Arr), UBound(Arr, 2)) = Arr
'↑令[A2]擴展向下Arr縱向最大索引列號數,擴展向右最大索引欄號數,
'這擴展範圍儲存格值以Arr陣列值帶入
Erase Arr: Set xR = Nothing: Set Y = Nothing
'↑令釋放變數
End Sub

shuo1125

回復 25# Andy2483
Andy大!
   經測試可行，感激不盡!!

shuo1125

回復 25# Andy2483
Andy大!
若要將餘額明細表的B1日期考慮進去，假設說餘額區B1日期是2023/01/31(圖A)，
則餘額明細只抓到1月底(圖B)，
請問這樣該如何修改才好?如圖，又要勞煩你了...謝謝!!!

Andy2483

回復 28# shuo1125


    謝謝前輩,謝謝論壇
後學練習運用 刪除指定條件列資料,學習的解決方案如下,請前輩參考
http://forum.twbts.com/thread-23898-1-2.html

Option Explicit
Sub 清除不符條件的列_並排序()
Dim Arr, Brr(), xArea As Range, x&, Xm&, y&, Ym&, N&, Da As Date
'↑宣告變數:Arr是 通用型變數,Brr是陣列,xArea是儲存格變數,其他是長整數變數
Da = Application.Text([科目餘額表!B1], "[$-404]e/m/d;@")
'↑令Da這日期變數是 [B1]以國年格式轉為文字再轉為日期的變數
With Range([資料區!U1], [資料區!A65536].End(3))
'↑以下是關於上述儲存格的程序
     Arr = .Value
     '↑令Arr這通用型變數是二維陣列,以這With程序儲存格值帶入
     Ym = UBound(Arr, 1)
     '↑令Ym這長整數變數是Arr陣列縱向最大索引列號數
     'PS:可以省略為 Ym = UBound(Arr)
     Xm = UBound(Arr, 2)
     '↑令Xm這長整數變數是Arr陣列橫向最大索引欄號數
     Set xArea = .Resize(Ym, Xm + 1)
     '↑令xArea這儲存格變數是 以這With程序儲存格擴展向下Ym變數列,
     '向右(Xm變數 + 1)欄
     '(PS:增加1輔助欄)
     ReDim Brr(1 To Ym, 0): Brr(1, 0) = 0
     '↑宣告Brr這陣列變數是二維的,
     '大小:縱向從1到Ym變數列,橫向1欄,索引號是0到0
     '↑令第1個Brr陣列值是 0
     For y = 2 To Ym
     '↑設順迴圈!y從1到Ym變數
         If CDate(Arr(y, 4)) > Da Then GoTo 101
         '↑如果y迴圈列第4欄Arr陣列值轉成日期後大於 Da變數!就跳到101位置繼續執行
         N = N + 1: Brr(y, 0) = N
         '↑令N這長整數變數累加 1:令y變數列0索引號欄Brr陣列值是 N變數
101: Next y
     If N = Ym - 1 Then Exit Sub
     '↑如果N變數=Ym變數-1!就結束程式執行(代表沒有符合條件的列)
     xArea.Columns(Xm + 1) = Brr
     '↑令xArea變數的(Xm變數+1)欄範圍儲存格以Brr陣列值帶入(PS:輔助欄帶入輔助索引值)
End With
With xArea
'↑以下是關於 xArea變數的程序
     .Sort KEY1:=.Item(Xm + 1), Order1:=xlAscending, Header:=xlNo
     '↑令xArea(儲存格)以(Xm變數+1)欄第1列儲存格所在的欄(AB欄)當基準,
     '做沒有標題列的順排序排序
     .Rows(N + 2 & ":" & Ym).Delete
     '↑令xArea變數範圍裡的第 (N變數 + 2)列到 範圍裡的Ym變數列,
     '這範圍儲存格列刪除
     .Columns(Xm + 1).Delete
     '↑令xArea變數的(Xm變數+1)欄範圍儲存格欄刪除 (PS:輔助欄刪除)
     .Sort _
     KEY1:=[B1], Order1:=xlAscending, _
     Key2:=[C1], Order2:=xlAscending, _
     key3:=[D1], Order3:=xlAscending, _
     Header:=xlYes, Orientation:=xlTopToBottom
     '↑令資料做3層次排序
End With
End Sub

shuo1125

回復 29# Andy2483
Andy大!
這方法可行，可是有個問題..因為該方式是直接整理資料區，若我要再回頭查2023/02/28的資料就沒有了...
範例是我篩選出1月的資料，請問可以在不刪除情況下只抓查詢日的明細嗎?勞煩了...!!