[發問] =NOW() 不會自動更新當下時間

cslu37

請問各位大大：
我之前是用excel2003，只有在欄位中輸入「=NOW()」，欄位就會自動帶出時間日期，且會一直更新。
但現在改用excel2010，在欄位中輸入「=NOW()」卻只會顯示當下的時間日期，都要手動點一下欄位，欄位的時間才會更新...
請問要如何才能讓2010自動一直更新當下時間呢？

請各位大大指導！謝謝各位大大！！

rouber590324

DEAR SIR
  於 Private Sub Workbook_Open() 加註如下

Private Sub Workbook_Open()
  Sheet1.Range("C4") = Now
  Application.OnTime Now + TimeValue("00:00:01"), "AA"
End Sub

rouber590324

Private Sub Workbook_Open()
  AA
End Sub

Sub AA()
  Sheet1.Range("C4") = Now
  Application.OnTime Now + TimeValue("00:00:01"), "AA"
End Sub

cslu37

回復 3# rouber590324


   感謝 rouber590324 指導，現在會一直跳動了^^~

   只是游標一直跳來跳去...請問這樣正常嗎@@?

rouber590324

正常
把01秒執行一次改30秒執行一次.就不會如此刺眼拉

Sub AA()
  Sheet1.Range("C4") = Now
  Application.OnTime Now + TimeValue("00:00:30"), "AA"
End Sub

cslu37

回復 5# rouber590324

    對ㄝ~這樣就不會一直轉了~不然看得我眼都花花@@ 哈哈
    謝謝rouber590324大大的指導^^~

准提部林

一般模組區:
Public xTime

Sub AA()
Range("C4").Calculate
xTime = Now + TimeValue("00:00:01")
Application.OnTime xTime, "AA"
End Sub

Sub STOP_AA()
On Error Resume Next
Application.OnTime xTime, "AA", Schedule:=False
On Error GoTo 0
End Sub
'================================
活頁簿事件區:
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Call STOP_AA
End Sub

Private Sub Workbook_Open()
With Sheet1.Range("C4")
     .Formula = "=NOW()"
     .NumberFormatLocal = "hh:mm:ss"
End With
Call AA
End Sub

時間改變, 但不影響在其它儲存格操作後, 而無法使用[復原/複製/貼上]的功能,
不過, 若公式太多, 可能會讓整個檔案卡死~~
===================

cslu37

回復 7# 准提部林


   感謝 准提部林 指導！！
   現在游標轉圈圈，都還可以複製、貼上....等等。

   想問 准提部林 大大～
   您說的「一般模組區」、「活頁簿事件區」是指這2區，對嗎@@?
   一般對ThisWorkbook 是怎麼稱呼呢??
   謝謝您！！

准提部林

回復 8# cslu37

ThisWorkbook  活頁簿事件區
Module??? 一般模組區
Sheet???  工作表事件區

cslu37

回復 9# 准提部林


    感謝 准提部林 大大的說明！！
　原來是我放錯了...難怪不動>"<
　現在終於搞清楚了！！太謝謝您了！！