返回列表 上一主題 發帖

[發問] 如何製作不重複的資料驗證下拉篩選清單?

[發問] 如何製作不重複的資料驗證下拉篩選清單?

K欄上是有資料不斷輸入的日期,從這欄中取出年份,在A2和A3格上製作一個不重複的資料驗證下拉篩選清單?
謝謝!

ABook1.rar (15.7 KB)

回復 1# maiko

參考看看
ABook1.zip (14.91 KB)
學海無涯_不恥下問

TOP

本帖最後由 p212 於 2014-4-1 10:49 編輯

回復 1# maiko
以範例檔 ABook1.xlsx資料欄位配置解
1、定義名稱「Date」,「參照到」輸入 =YEAR(OFFSET(Sheet1!$K$2,,,COUNTA(Sheet1!$K:$K)-1))
2、儲存格S1輸入欄位名Year,儲存格S2輸入陣列公式 =IFERROR(INDEX(Date,MATCH(0,COUNTIF($S$1:S1,Date),0)),""),向下複製公式。
3、定義名稱「Year」,「參照到」輸入=OFFSET(Sheet1!$S$2,,,COUNT(Sheet1!$S:$S)),再於儲存格A2製作清單,清單「來源」輸入 =Year。
請參考!

TOP

回復 1# maiko
Sorry! 補附件

ABook1_參考.zip (16.99 KB)

TOP

S2 =YEAR(LOOKUP(DATE(IF(N(S1),S1,YEAR(MAX(K:K))),1,0),K:K))
下拉
{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

TOP

本帖最後由 p212 於 2014-4-1 16:19 編輯

回復 5# ML089
請教ML089大大
依原問範例檔,以一般公式 S2=YEAR(LOOKUP(DATE(IF(N(S1),S1,YEAR(MAX(K:K))),1,0),K:K)) 下拉複製公式
儲存格S2、S3、S4運算結果分別為2013、2012、#N/A,而不為2014、2013、2012,請問問題出在哪兒?
若將S2改成=YEAR(LOOKUP(DATE(IF(N(S1),S1,YEAR(MAX(K:K))+1),1,0),K:K)) ,似乎可以得到正確答案。
敬請指導,謝謝!

TOP

回復 6# p212

小失誤,公式請修正
=IF(N(S1),YEAR(LOOKUP(DATE(S1,1,0),K:K)),YEAR(MAX(K:K)))
{...} 表示需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

TOP

謝謝各位大大,已經解決了,謝謝賜教。

TOP

        靜思自在 : 看別人不順眼,是自己修養不夠。
返回列表 上一主題