返回列表 上一主題 發帖

[發問] 改善大筆資料處理

[發問] 改善大筆資料處理

請問各位大大

小弟我目前有兩個工作表

依據"產品工作表"(A) 的 ID & PartNumber 比對到 "物料工作表"(B) 的 ID & PartNumber

如果有一樣的,則把A的資料COPY到B裡面

如果沒有相同的,則補到B的最下方


資料量小的時候還可以

但我資料有幾千筆會變好慢好慢 大約要跑10分鐘左右

可能是FOR迴圈的問題

不知有什麼改善方法

麻煩各位大大

以下為附檔

P.S. 比對欄位有刪減,所以附檔的處理速度好像還可以

forum.zip (118.3 KB)
用功到世界末日那一天∼∼∼

本帖最後由 GBKEE 於 2014-1-22 14:52 編輯

回復 1# li_hsien

改用 Collection 物件 不用 Dictionary 物件
  1. Option Explicit
  2. Sub Ex()
  3.     Dim d As New Collection, AR(1 To 7), i As Integer, Rng(1 To 2) As Range, E As Variant
  4.     On Error Resume Next              '註解1 :Collection新增的KEY如被使用或有錯誤
  5.     With Worksheets("產品管控清單")
  6.         For i = 2 To .Range("J1").End(xlDown).Row
  7.             AR(1) = .Range("E" & i)             'PRODUCT ID(A)
  8.             AR(2) = .Range("F" & i)             'CHILDPARTNUMBER(B)
  9.             AR(3) = .Range("C" & i)             'MP date(G)
  10.             AR(4) = .Range("A" & i)             '週別(H)
  11.             AR(5) = .Range("B" & i)             '更新週別(I)
  12.             AR(6) = DateDiff("d", Date, AR(3))  '工作日(M)
  13.             AR(7) = .Range("J" & i)             'Product ID & PartNumber
  14.             d.Add AR, .Range("J" & i).Value     '紀錄產品的ID & PartNumber
  15.             
  16.             '**** 所以是以"產品"擁有的為主,不過產出"物料"之前得先刪除"產品"重複的部分->Rng(1)
  17.             '**** 當產品的ID & PartNumber(F)有重複時有->註解1: Err <> 0
  18.             If Err <> 0 Then
  19.                 Err.Clear
  20.                 If Rng(1) Is Nothing Then       'Rng(1)->紀錄有重複產品的ID & PartNumber
  21.                     Set Rng(1) = .Range("J" & i)
  22.                 Else
  23.                     Set Rng(1) = Union(.Range("J" & i), Rng(1))
  24.                 End If
  25.             End If
  26.         Next
  27.     End With
  28.     With Worksheets("物料管控清單")
  29.         For Each E In .Range("F:F").SpecialCells(xlCellTypeConstants).Offset(1)
  30.             .Range("A" & E.Row) = d(E.Value)(1)
  31.             .Range("B" & E.Row) = d(E.Value)(2)
  32.             .Range("G" & E.Row) = d(E.Value)(3)
  33.             .Range("H" & E.Row) = d(E.Value)(4)
  34.             .Range("I" & E.Row) = d(E.Value)(5)
  35.             .Range("M" & E.Row) = d(E.Value)(6)
  36.             .Range("F" & E.Row) = d(E.Value)(7)
  37.             
  38.             '**** "產品"有 "物料"有  則把 "產品" 的資料COPY到 "物料" 原本的位子上
  39.             '**** 產品"有 "物料"有 -> Err = 0
  40.             If Err = 0 Then                     '物料的ID & PartNumber,存在產品的ID & PartNumber中
  41.                 d.Remove E.Value                '除去:產品的ID & PartNumber
  42.             '**** 有第二筆已除去的產品ID & PartNumber-> 已除去(沒有這KEY值): Err <> 0
  43.             ElseIf Err <> 0 And E <> "" Then
  44.             '**** "產品"沒有 "物料"有 則把"物料"整欄刪除掉 -> Rng(2)
  45.                 If Rng(2) Is Nothing Then       '取的儲存格的位置
  46.                     Set Rng(2) = E
  47.                 Else
  48.                     Set Rng(2) = Union(E, Rng(2))
  49.                 End If
  50.             End If
  51.             Err.Clear
  52.         Next
  53.         If d.Count > 0 Then
  54.             
  55.             'C ***產品"有 "物料"沒有 則把新增多出來的增加到 "物料" 最下面
  56.             i = 0
  57.             With .Range("A1").End(xlDown)
  58.                 For Each E In d
  59.                     i = i + 1
  60.                     .Offset(i).Range("A1") = E(1)
  61.                     .Offset(i).Range("B1") = E(2)
  62.                     .Offset(i).Range("G1") = E(3)
  63.                     .Offset(i).Range("H1") = E(4)
  64.                     .Offset(i).Range("I1") = E(5)
  65.                     .Offset(i).Range("M1") = E(6)
  66.                     .Offset(i).Range("F1") = E(7)
  67.                 Next
  68.             End With
  69.         End If
  70.     End With
  71.     If Not Rng(1) Is Nothing Then
  72.     '**** 刪除"產品"重複的部分->Rng(1)
  73.         If MsgBox("刪除重複的[ID & PartNumber]", vbQuestion + vbYesNo, "產品管控清單") = vbYes Then
  74.             Rng(1).EntireRow.Delete
  75.         End If
  76.     End If
  77.    
  78.     If Not Rng(2) Is Nothing Then
  79.         '**** "產品"沒有 "物料"有 則把"物料"整欄刪除掉 -> Rng(2)
  80.         If MsgBox("刪除重複的[ID & PartNumber]", vbQuestion + vbYesNo, "物料管控清單") = vbYes Then
  81.            Rng(2).EntireRow.Delete
  82.         End If
  83.     End If
  84.     MsgBox "Ok"
  85. End Sub
複製代碼
感恩的心......(在麻辣家族討論區.用心學習會有進步的)
但資源無限,後援有限,  一天1元的贊助,人人有能力.

TOP

回復 2# GBKEE

板大我發現了一點問題

我如果在產品那邊刪掉一筆

在物料那並沒有刪除掉

新增加的話還OK


最後板大幫我設置的刪除提示

為什麼刪掉後只剩下4.5筆呀???


我用2007的移除重複,並沒有這麼多重複

不知問題出在哪裡???



麻煩幫我看看

謝謝  :  )
用功到世界末日那一天∼∼∼

TOP

回復 2# GBKEE

謝謝大大的幫忙

可是我發現還是沒有刪除掉耶

產品沒有的,物料那邊還是有出現

我是在產品中間隨便刪一筆測試的


那大大的重複提示

我用2007內建的移除重複測試

發現還是多刪了,可是筆數不多

我要留有重複的第一筆
EX:
A,B,C,A,A,B,C,D
我要留A,B,C,D

不知大大是不是把重複的都刪了


麻煩幫我看看  感謝  :  )
用功到世界末日那一天∼∼∼

TOP

回復 2# GBKEE

版大我又出現了@@

我試了一試還是怪怪的耶

產品如果在資料中有新增

好像抓不到物料那邊

會怪怪的

還是只能在最下面新增


如果我在產品的資料中刪除一筆

物料那邊還是會出現@@

本身有2007的關係
我驗證資料重複應該剩下1026筆
物料那邊OK 不過產品那邊還是不一致


又再次麻煩大大了

謝謝你  :  )
用功到世界末日那一天∼∼∼

TOP

回復 5# li_hsien
[A,B,C,A,A,B,C,D我要留A,B,C,D]
  1. d.Add AR, .Range("J" & i).Value
  2.             '****** A,B,C,A,A,B,C,D我要留A , B, C,D.. 這裡在處理.
  3.             If Err <> 0 Then                   '錯誤: 產品重複的[ID & PartNumber]
  4.                 Err.Clear
  5.                 If Rng(1) Is Nothing Then             '紀錄:產品重複的[ID & PartNumber]的位置
  6.                     Set Rng(1) = .Range("J" & i)
  7.                 Else
  8.                     Set Rng(1) = Union(.Range("J" & i), Rng(1))
  9.                 End If
  10.             End If
複製代碼
[產品沒有的,物料那邊還是有出現]
  1. '******* 我如果在產品那邊刪掉一筆,在物料那並沒有刪除掉??這裡有作處裡
  2.             If Err = 0 Then                     '物料的ID & PartNumber,有存在產品的ID & PartNumber中
  3.                 d.Remove E.Value                '除去:產品的ID & PartNumber
  4.             Else  '-> Err <> 0 有錯誤
  5.             '錯誤1:已除去產品的ID & PartNumber
  6.             '錯誤2:物料的ID & PartNumber,不存在產品的ID & PartNumber中
  7.                 If Rng(2) Is Nothing Then       '紀錄儲存格的位置
  8.                     Set Rng(2) = E
  9.                 Else
  10.                     Set Rng(2) = Union(E, Rng(2)) '紀錄儲存格的位置
  11.                 End If
  12.             End If
  13.             '*********************************************************
  14.             Err.Clear
複製代碼
請上傳測試的檔案看看
感恩的心......(在麻辣家族討論區.用心學習會有進步的)
但資源無限,後援有限,  一天1元的贊助,人人有能力.

TOP

回復 6# GBKEE

我都是直接再次COPY過去

剛剛再次確認

新增應該OK

不過好像都是要按下MSGBOX確認後才可以


可是移除後數量不對

附檔還有兩張圖

一張是原有資料

另一張是用了移除重複後的資料

煩請大大幫我看看


forum.zip (256.48 KB)
用功到世界末日那一天∼∼∼

TOP

本帖最後由 GBKEE 於 2014-1-22 12:02 編輯

回復 7# li_hsien

7#的檔案,執行2#的程式碼

找出 物料管控清單 (產品沒有或物料重複)的ID

EX.JPG
2014-1-22 11:52



1194同列為產品管控清單,物料管控清單的最後一筆資料

EX2.JPG
2014-1-22 11:50


EX1.JPG
2014-1-22 11:54
感恩的心......(在麻辣家族討論區.用心學習會有進步的)
但資源無限,後援有限,  一天1元的贊助,人人有能力.

TOP

回復 8# GBKEE

板大我再測試了一下

在物料或是產品的工作表執行應該都沒有差別吧


我不太懂第一次刪除重複的動作

因為附檔的資料一開始在"產品"那邊有1801項,"物料"那邊有1206項

我先用移除重複篩一次"產品"那邊的項目,只剩下1206項

可是我用了程式跑只剩下1196項

應該是多刪了板大圖示的部分



我的處理流程是先依據"產品"裡的來產出"物料"裡面的

動作 是如果 (都是以ID & PART NUMBER為依據)
"產品"有 "物料"有  則把 "產品" 的資料COPY到 "物料" 原本的位子上
"產品"有 "物料"沒有 則把新增多出來的增加到 "物料" 最下面
"產品"沒有 "物料"有 則把"物料"整欄刪除掉

所以是以"產品"擁有的為主,不過產出"物料"之前得先刪除"產品"重複的部分

最後結果是"產品"跟"物料"的項目數會是一樣的沒有錯


不過就在一開始的移除有些問題

做過第一次動作後,我再測試刪刪減減這些動作,都很順利沒有問題   :  )



有點冗長@@

煩請板大看看

謝謝
用功到世界末日那一天∼∼∼

TOP

回復 9# li_hsien
2#的程式請你修改一下看看產品管控清單重複的ID
  1. '********* "產品管控清單" 刪除重複的[ID & PartNumber]*******************
  2.     If Not Rng(1) Is Nothing Then
  3.         If MsgBox("刪除重複的[ID & PartNumber]", vbQuestion + vbYesNo, "產品管控清單") = vbYes Then           
  4.              Worksheets("產品管控清單").Activate
  5.             Stop                                            '程式會停止 按F8一步一步執行下去看工作表的情形
  6.             Rng(1).EntireRow.Select                  '選取重複的ID
  7.            MsgBox Rng(1).EntireRow.Address
  8.             Rng(1).EntireRow.Delete   '先註解掉不刪除
  9.         End If
  10.     End If
複製代碼
感恩的心......(在麻辣家族討論區.用心學習會有進步的)
但資源無限,後援有限,  一天1元的贊助,人人有能力.

TOP

        靜思自在 : 話多不如話少,話少不如話好。
返回列表 上一主題