ML089

回復 10# PJChen

最好 一張派車執行一項任務，這樣派車單號就是資料庫的KEY(索引號碼)容易查詢。

若是 派車單號 有多筆任務，放資料時又是歸檔再一起，查詢也不困難，就是 先查詢第一筆位置再加1列就是

查詢第一筆
B3 =INDEX(派車!$A:$Q,MATCH($A$2,派車!B:B,),MATCH($A3,派車!$1:$1,))

查詢第二筆
B3 =INDEX(派車!$A:$Q,MATCH($A$2,派車!B:B,)+1,MATCH($A3,派車!$1:$1,))

查詢第三筆
B3 =INDEX(派車!$A:$Q,MATCH($A$2,派車!B:B,)+2,MATCH($A3,派車!$1:$1,))   

若要防止沒有第二筆或第三筆，可以使用 COUNTIF 來計算有幾筆
B3 =IF(COLUMN(A1)>COUNTIF(派車!$B:$B,$A$2),"",INDEX(派車!$A:$Q,MATCH($A$2,派車!$B:$B,)+COLUMN(A1)-1,MATCH($A3,派車!$1:$1,)))
右拉 (第一筆、第二筆、...)
下拉

PJChen

回復 11# ML089

謝謝！也行，這也是一個方法.

zz5151353

派車單工作表
B3 下拖拉
=VLOOKUP($A$2,派車!$B:$O,MATCH($A3,派車!$B$1:$O$1,),)

PJChen

回復 13# zz5151353

謝謝你,這公式也可以用,只是都無法解決同一張訂單,同一天派車2次但不同貨運公司,資料會帶不出來的問題.

PJChen

回復 11# ML089

請大大再指導下,為什麼類似的用法,在這個檔案中，卻帶不出結果？

LAMP.rar (142.4 KB)

下載次數: 12

2017-7-4 13:19

ML089

回復 15# PJChen

B2儲存格
=INEDX(庫存!$A:$AH,MATCH($A2,庫存!$F:$F,),MATCH(B$1,庫存!$1:$1,))
修改為
=INDEX(庫存!$A:$AH,MATCH($A2,庫存!$F:$F,),MATCH(B$1,庫存!$1:$1,))

aer

回復 15# PJChen

B2公式函數名稱鍵錯為 inedx，修正為 index 後，公式即可正常運作

B3=VLOOKUP($A3,庫存!$F:$R,MATCH(B$1,庫存!$F$1:$R$1,),)

PJChen

回復 17# aer
回復 16# ML089

我看了半天也沒看出錯誤在哪！...感謝了.

平心靜氣

請教 15# PJChen
LAMP附加檔,欄位名稱上方的...+...-，類似小計的縮放是如何做出來的??
此功能對工作上,顯示含有大量資料的表單，還滿實用的。