[發問] Selenium

t8899

下載 (21.38 KB)

2023-6-1 17:13

請教我要抓圖中的綠色部份(含倒三角形),怎麼抓(語法)?
https://tw.stock.yahoo.com/quote/2330
從網頁得知FindElementByXPath
//*[@id="qsp-overview-realtime-info"]/div[2]/div[2]/div/ul/li[8]/span[2]
這是倒三角形含數字
//*[@id="qsp-overview-realtime-info"]/div[2]/div[2]/div/ul/li[8]/span[2]/span
這只有倒三角形

singo1232001

回復 1# t8899


<div class="Jc(fe) Mend(4px) Fw(600) D(f) Ai(c) C($c-trend-up)"   ' 這是紅色向上
<div class="Jc(fe) Mend(4px) Fw(600) D(f) Ai(c) C($c-trend-down)"  '這是綠色 向下


所以   
if  網頁元素物件.Attribute("class") Like "*C($c-trend-up)*" Then
debug.print "▲"  '正數
else
debug.print "▼"  '負數
end if


你也可以試著一個一個
debug.print  網頁元素物件.Attribute("class")  
觀察是不是你要的

singo1232001

回復 1# t8899


Sub ttt()
Set driver = CreateObject("Selenium.ChromeDriver")
driver.get "https://tw.stock.yahoo.com/quote/2330"
driver.Wait 1000
Set ID_0 = driver.findelementbyID("qsp-overview-realtime-info")
Set ID_0_ul_S = ID_0.findelementsbytag("ul")
Set ID_0_ul_S_1_li_S = ID_0_ul_S(1).findelementsbytag("li")

For i = 1 To ID_0_ul_S_1_li_S.Count
Set x = ID_0_ul_S_1_li_S(i).findelementsbytag("span")
  If x(1).Text Like "*漲跌*" Then

      Select Case True
      Case x(2).Attribute("class") Like "*C($c-trend-up)*": tx = "▲ " & x(2).Text
      Case x(2).Attribute("class") Like "*C($c-trend-down)*": tx = "▼ " & x(2).Text
      Case Else: tx = x(2).Text
      End Select
  
      Debug.Print x(1).Text & " " & tx
  Else
      Debug.Print x(1).Text & " " & x(2).Text
  End If
Next
Stop
End Sub

singo1232001

回復 1# t8899


如果你用xpath 就是這樣
Sub tttt()
Set driver = CreateObject("Selenium.ChromeDriver")
driver.get "https://tw.stock.yahoo.com/quote/2330"
driver.Wait 1000

Set xp = driver.findelementbyxpath("//*[@id=""qsp-overview-realtime-info""]/div[2]/div[2]/div/ul/li[8]")
      Set sn = xp.findelementsbytag("span")

Select Case True
Case sn(2).Attribute("class") Like "*C($c-trend-up)*": tx = "▲ "
Case sn(2).Attribute("class") Like "*C($c-trend-down)*": tx = "▼ "
Case Else: tx = " - "
End Select
Debug.Print sn(1).Text & " " & tx & " " & sn(2).Text
  
Stop
End Sub

t8899

回復 4# singo1232001

謝謝指導

t8899

回復 4# singo1232001

drIVER.get "https://finance.yahoo.com/quote/TSM/"
請教如果連線超過3秒有問題?則跳出的語法?

singo1232001

回復 6# t8899


Sub 時間內沒加載完就算失敗()
t = Timer '測試用可刪
Set driver = CreateObject("selenium.chromedriver")
driver.Timeouts.pageload = 10000 '要是秒數過低 沒加載完 就會強制關閉 可以試著測試3秒以下
On Error Resume Next
driver.get "https://finance.yahoo.com/quote/TSM/"
If Err.Number <> 0 Then
Err.Clear
driver.Quit
End If
On Error GoTo 0
Debug.Print Timer - t  '測試用可刪
End Sub




因為不曉得你的需求
所以我順便把重連三次的寫法也給你

Sub 重連三次每次等三秒_第四次就失敗()
Set driver = CreateObject("selenium.chromedriver")
On Error Resume Next
Do
driver.Get "https://finance.yahoo.com111111111/quote/TSM/"
If Err.Number <> 0 Then
    Err.Clear
    Application.Wait Now + TimeValue("00:00:03")
    rT = rT + 1
    If rT = 3 Then driver.Quit: Exit Do
Else
    Exit Do
End If
Loop
On Error GoTo 0
End Sub

t8899

回復 7# singo1232001

謝謝指導

Scott090

回復 8# t8899

    請問如何在此網頁 "https://finance.yahoo.com/quote/TSM/"
        取得下列這一些資料 ?  
    謝謝

   Previous Close        549.00
Open        551.00
Bid        552.00 x 0
Ask        553.00 x 0
Day's Range        546.00 - 553.00
52 Week Range        370.00 - 594.00
Volume        10,650,708
Avg. Volume        22,277,577

singo1232001

回復 9# Scott090


    Sub test()
Set driver = CreateObject("selenium.chromedriver")
driver.get "https://finance.yahoo.com/quote/TSM/"

Do: Set ids = driver.findelementsbyId("quote-summary")
    If ids.Count > 0 Then Exit Do
    Loop
Do: Set tby = ids(1).findelementsbytag("tbody")
    If tby.Count > 0 Then Exit Do
    Loop
   
Debug.Print tby(1).Text


Set trs = tby(1).findelementsbytag("tr")
ReDim ar(1 To trs.Count, 1)
For i = 1 To trs.Count
    Set tds = trs(i).findelementsbytag("td")
    ar(i, 0) = tds(1).Text
    ar(i, 1) = tds(2).Text
Next

Cells.ClearContents
Range("a1").Resize(UBound(ar), 2) = ar
End Sub