[發問] ChDrive/ ChDir問題

ChDrive可以變更目前的磁碟機, ChDir則是用來改變目前的資料夾
我用下列方式撰寫:
filepath = ActiveWorkbook.Path
ChDrive filepath
ChDir filepath
filt = "excel files (*.xls;*.xlsx),*.xls;*.xlsx"
Filename = Application.GetOpenFilename(FileFilter:=filt, FilterIndex:=5, title:="選擇檔案", MultiSelect:=True)
...
...
我開啟的excel檔案是在某一個資料夾(ActiveWorkbook.Path),且希望執行opne file時開啟的路徑會在同一個資料夾,若是開啟的檔案是網路芳鄰上的電腦(即ActiveWorkbook.Path不是在自己的電腦),就會出現錯誤,請問該如何改才能修正這個錯誤?

樓主熱帖

GBKEE

超級版主 Rank: 8 Rank: 8

帖子: 5923
主題: 13
精華: 1
積分: 5986
點名: 0
作業系統: win10
軟體版本: Office 2010
閱讀權限: 150
性別: 男
來自: 台灣基隆
註冊時間: 2010-5-1
最後登錄: 2022-1-23

2017 雞年全勤獎章 2016猴年全勤獎章 2015羊年全勤獎章 2014馬年全勤獎章 2013蛇年全勤獎章 2012龍年全勤獎章論壇貢獻勳章熱烈參與勳章 2011兔年全勤獎章

2^#

發表於 2016-12-16 19:41 | 只看該作者

回復 1# acdx
試試看

Option Explicit
Sub Ex()
Dim filepath As String, A As String, B As String
filepath = ActiveWorkbook.Path
MsgBox CurDir '***CurDir 函數傳回一個 Variant (String)，用來代表目前的路徑。
A = Split(CurDir, "\")(0)
B = Split(filepath, "\")(0)
If A <> B Then ChDrive B
ChDir filepath
MsgBox CurDir
End Sub

複製代碼

感恩的心......(在麻辣家族討論區.用心學習會有進步的)
但資源無限,後援有限, 一天1元的贊助,人人有能力.

TOP

stillfish00

大學生 Rank: 4

帖子: 1018
主題: 15
精華: 0
積分: 1058
點名: 0
作業系統: win7 32bit
軟體版本: Office 2016 64-bit
閱讀權限: 50
性別: 男
來自: 桃園
註冊時間: 2012-5-9
最後登錄: 2022-9-28

3^#

發表於 2016-12-19 20:14 | 只看該作者

回復 1# acdx
ChDrive : 改變工作磁碟機
ChDir : 改變工作目錄
依題目的意思是希望 GetOpenFilename 選擇檔案時的預設路徑為該檔路徑，
但當檔案在分享資料夾(路經通常為 "\\電腦名稱\資料夾路徑\檔案")
無法用ChDir切換工作目錄到 "\\電腦名稱\資料夾路徑\"

替代方法，這邊舉兩種 :
1. 改用 Application.FileDialog(msoFileDialogOpen)，FileDialog可以直接設定InitialFileName

Sub m1()
Dim filename As String
With Application.FileDialog(msoFileDialogOpen)
.AllowMultiSelect = False
.InitialFileName = ActiveWorkbook.Path
.Filters.Clear
.Filters.Add "Excel files", "*.xlsx;*.xls"
.Show
If .SelectedItems.Count = 0 Then Exit Sub 'cancel
filename = .SelectedItems(1)
End With
MsgBox filename
End Sub

複製代碼

2. 用 windows API : SetCurrentDirectory切換工作目錄，再用 GetOpenFilename

Private Declare Function SetCurrentDirectory Lib "kernel32" _
Alias "SetCurrentDirectoryA" (ByVal lpPathName As String) As Long
Sub m2()
Dim filt As String, filename As String
SetCurrentDirectory ActiveWorkbook.Path
filt = "excel files (*.xls;*.xlsx),*.xls;*.xlsx"
filename = Application.GetOpenFilename(FileFilter:=filt, FilterIndex:=5, Title:="選擇檔案", MultiSelect:=True)
End Sub

複製代碼

表達不清、題意不明確、沒附檔案格式、沒有討論問題的態度~~~~~~以上愛莫能助。

TOP