[發問] 如何將表格內的資料轉變為出貨單樣式？

bvge

請看附件比較清楚
也就是要利用金額工作表的資料轉變為出貨單這種格式

我目前是用篩選的方式(選非空格)，再將資料COPY到出貨單
然後更改表頭的區域名稱最後列印出來

困擾：
第一區篩選完之後，要將篩選資料回復(選全部)，這樣才能做第二區篩選
而且還要將第一區隱藏起來，這樣COPY才不會COPY到第一區資料
如此反覆，24個地區要重複24次，累死人了！

拜託前輩們
幫我想想辦法，看能否簡化，或是用其他方法
只要能夠用金額工作表的資料轉變為出貨單這種格式就可以
謝謝！

零件.rar (45.62 KB)

下載次數: 18

2011-2-20 17:24

Hsieh

回復 1# bvge
定義名稱
x=金額!$F$3:$AC$3
y=OFFSET(金額!$A$3,1,MATCH('出貨單(公式)'!$H$6,金額!$3:$3,0)-1,146,)
**************************************
H6驗證:清單=x
**************************************
C1="服務零件交貨明細表 ("&MID(H6,FIND(CHAR(10),H6),256)&")"
A8:C8陣列公式
=IF(ROW($A1)>COUNT(y),"",INDIRECT("金額!R"&SMALL(IF(y<>"",ROW(y),""),ROW($A1))&"C",0))
D8陣列公式
=IF(ROW($A1)>COUNT(y)+6,"",IF(ROW($A1)-COUNT(y)>0,CHOOSE(ROW($A1)-COUNT(y),"","總計本批共交貨：","","共     件","","收貨簽章："),INDIRECT("金額!R"&SMALL(IF(y<>"",ROW(y),""),ROW($A1))&"C",0)))
E8陣列公式
=IF((ROW($A1)-COUNT(y)=1)+(ROW($A1)>COUNT(y)+2),"",IF(ROW(A1)-COUNT(y)=2,COUNT(y)&"   項目",INDIRECT("金額!R"&SMALL(IF(y<>"",ROW(y),""),ROW($A1))&"C"&MATCH($H$6,金額!$3:$3,0),0)))
*****************************************
F8=IF(B8="","",VLOOKUP(B8,Sheet3!$A$2:$D$100,4,FALSE))

下載 (28.19 KB)

2011-2-21 10:29

零件.rar (55.77 KB)

下載次數: 10

2011-2-21 10:30

ANGELA

回復 1# bvge


    試試.
A6=INDEX(金額!$A$1:$A$150,SMALL(IF(ISNUMBER(OFFSET(金額!$A$4:$A$150,,MATCH(金額!$F$3,金額!$A$3:$AC$3,)-1)),ROW($B$4:$B$150),150),ROW(A1)))&""
CTRL+SHIFT+ENTER 陣列公式
向右向下COPY
E6=INDEX(金額!$F$1:$F$150,SMALL(IF(ISNUMBER(OFFSET(金額!$A$4:$A$150,,MATCH(金額!$F$3,金額!$A$3:$AC$3,)-1)),ROW($B$4:$B$150),150),ROW(E1)))&""
E12=SUMPRODUCT(ISNUMBER(--A6:A11)*1)&"    項目"

bvge

請問 Hsieh 超版
依照你的公式及陣列帶入都沒有出現錯過訊息
應該是在H6驗證選擇地區後就會顯示該區的資料
但是選擇後都是一遍空白

又重做一次
定義 "y" 名稱時會尋找 出貨單 "公式" 的位置.....
是不是這緣故？

我權限不夠無法下載！

bvge

Hsieh 超版你好
很感謝您幫助，實在很方便又好用
再請問一下
E8陣列公式
資料與 X項目是隔著一列空白
如果要隔著二或三列空白不知道要修改那裡
才能讓資料與X項目是隔著二或三列空白
敬請再幫忙
謝謝！

零件.rar (86.16 KB)

下載次數: 8

2011-3-6 10:34

Hsieh

回復 5# bvge


    E8陣列公式
{=IF(ROW(A1)-COUNT(y)=2,COUNT(y)&"   項目",IF((ROW($A1)-COUNT(y)>0),"",INDIRECT("數量!R"&SMALL(IF(y<>"",ROW(y),""),ROW($A1))&"C"&MATCH(數量!$D$1,數量!$3:$3,0),0)))}
紅色的2就是空一列填入項目數
改成3就空白2列，以此類推

bvge

Hsieh 超版你好

可以了
感謝
再感謝！