[發問] 搜尋計算後的指定相同值及5個文字任取3個文字的不重複組合。

papaya

先祝福各位大大︰
豬年快樂!心想事成!

以下3個需求，
請各位大大不吝指教!謝謝!
1_Q2右拉下拉一式到位MS2003版的函數公式
2_AI2右拉下拉一式到位MS2003版的函數公式
3_W1:AF1右拉一式到位MS2003版的函數公式


範例附檔 :
搜尋計算後的指定相同值&5任取3的不重複組合.rar (3.65 KB)

下載次數: 6

2019-2-8 09:56

papaya

不好意思，需求1和2有一個規則忘了說明~補充如下:
當J2:N2的某一個數值+1或-1得值=0時，則視得值=39
即
=IF(MOD(N2+1,39)=0,39,MOD(N2+1,39))
=IF(MOD(N2-1,39)=0,39,MOD(N2-1,39))

另外:當J2:N2的某一個數值+2或-2得值=0時，則視得值=39；如得值=-1時，則視得值=38
即
=IF(MOD(N2+2,39)=0,39,MOD(N2+2,39))
=IF(MOD(N2-2,39)=0,39,MOD(N2-2,39))
其餘K2:N2同理類推。
謝謝!

ML089

回復 1# papaya


需求1_Q2右拉下拉一式到位MS2003版的函數公式
=LOOKUP(1,IF({1;0},{0,""},{-1,1}*SMALL(IF(MMULT({1,1,1},1-ISNA(RANK(MOD($D2:$H2+{-1;0;1}-1,39)+1,$J2:$N2))),$D2:$H2),COLUMN(A1))))
陣列公式

需求2_AI2右拉下拉一式到位MS2003版的函數公式
=LOOKUP(1,IF({1;0},{0,""},{-1,1}*SMALL(IF(MMULT({1,1,1,1,1},1-ISNA(RANK(MOD($D2:$H2+{-2;-1;0;1;2}-1,39)+1,$J2:$N2))),$D2:$H2),COLUMN(A1))))
陣列公式

需求3_W1:AF1右拉一式到位MS2003版的函數公式
=LOOKUP(LARGE(IF(LEN(SUBSTITUTE(DEC2BIN(ROW($7:$28),5),0,))=3,ROW($7:$28)),COLUMN(A1)),IF({1,0},ROW($7:$28),IF(MID(DEC2BIN(ROW($7:$28),5),1,1)="1","D","")&IF(MID(DEC2BIN(ROW($7:$28),5),2,1)="1","E","")&IF(MID(DEC2BIN(ROW($7:$28),5),3,1)="1","F","")&IF(MID(DEC2BIN(ROW($7:$28),5),4,1)="1","G","")&IF(MID(DEC2BIN(ROW($7:$28),5),5,1)="1","H","")))
陣列公式

papaya

回復 3# ML089
版主大大 :
感謝回覆^^
需求1&2->OK了!
需求3答案為#NAME?
可能是DEC2BIN->2003版不適用(我胡猜的)^^"
煩請修正~謝謝您!

ML089

回復 4# papaya


如果無法使用此函數，且傳回 #NAME? 錯誤，請執行程式以安裝「分析工具箱」。

作法

在 [工具] 功能表上，按一下 [增益集]。
在 [現有的增益集] 清單中，選取 [分析工具箱] 方塊，再按一下 [確定]。
如有需要，依循安裝程式上的指示動作。

papaya

回復 5# ML089
不好意思，"增益集"->"分析工具箱"->"確定"後~公式答案不變。
"分析工具箱"->"瀏覽"後~AddIns資料夾是空的^^"

改成這樣好了~以V1作輔助儲存格填入DEFGH~
然後再進行W1的需求(3)公式。
煩請再指導!謝謝您!

ML089

回復 6# papaya


    V1作輔助儲存格填入DEFGH~

可以之前之公式中的
"D" 以 MID(V1,1,1)
"E" 以 MID(V1,2,1)
"F" 以 MID(V1,3,1)
"G" 以 MID(V1,4,1)
"H" 以 MID(V1,5,1)

papaya

回復 7# ML089
如果同樣以之前公式套用"DEFGH"5個字母，那"DEC2BIN"還是無法適用^^"
如果只能用"DEC2BIN"解題，那就只好放棄了~還好，只有10個組合，用人工鍵入也沒有關係^^

謝謝您的耐心指導!感恩b^_^d

ML089

以V1作輔助儲存格填入DEFGH

1. =IF(MID(LARGE(IF(SUBSTITUTE(TEXT(ROW(111:11100),"00000"),0,)="111",ROW(111:11100)+10^5),COLUMN(A1)),2,1)="1",MID($V1,1,1),"")
   
2. &IF(MID(LARGE(IF(SUBSTITUTE(TEXT(ROW(111:11100),"00000"),0,)="111",ROW(111:11100)+10^5),COLUMN(A1)),3,1)="1",MID($V1,2,1),"")
   
3. &IF(MID(LARGE(IF(SUBSTITUTE(TEXT(ROW(111:11100),"00000"),0,)="111",ROW(111:11100)+10^5),COLUMN(A1)),4,1)="1",MID($V1,3,1),"")
   
4. &IF(MID(LARGE(IF(SUBSTITUTE(TEXT(ROW(111:11100),"00000"),0,)="111",ROW(111:11100)+10^5),COLUMN(A1)),5,1)="1",MID($V1,4,1),"")
   
5. &IF(MID(LARGE(IF(SUBSTITUTE(TEXT(ROW(111:11100),"00000"),0,)="111",ROW(111:11100)+10^5),COLUMN(A1)),6,1)="1",MID($V1,5,1),"")

複製代碼

papaya

回復 9# ML089

版主大大:
謝謝您的無私指導!答案正確!感恩