EXCEL 函數 選出前11名資料 無解

abba9817

下載 (182.79 KB)
圖1

2014-8-25 15:31

目標:將左側1-20名資料選出前11名 於右表列出
我的寫法如下
1.D欄先跑出名次'
=RANK(C2,$C$2:$C$21)
2.H欄選出1-11名成績(分數1)
'=LARGE(分數,F2)
3.G欄(名稱)依程式次序驗算結果
功2.功3.功4公式並驗算(F9)結果(如圖表都OK)輸入完成按 Ctrl+Shift+Enter 鍵
問題是:=VLOOKUP的步驟,出現問題#REF #N/A... ,就是無法顯示我要的名稱
請問'=VLOOKUP(SMALL(IF(H2=分數,編號,FALSE),COUNTIF($H$2:H2,H2)),資料,2)那裡出問題  謝謝!

p212

回復 1# abba9817
依1#圖例解
1、D欄「名次」建議改命名為「輔助」，儲存格D2輸入
=C2+(1000-ROW())/10000
向下複製公式
2、選取B1:D21範圍，按Ctrl+Shift+F3，以「頂端列」為名稱進行「定義名稱」。
3、F欄維持1#圖例配置
4、儲存格G2輸入一般公式=INDEX(名稱,MATCH(LARGE(輔助,F2),輔助,0))
儲存格H2輸入一般公式=INDEX(分數,MATCH(LARGE(輔助,F2),輔助,0))
向下複製公式
請參考！

abba9817

回復 2# p212
今早看到回信.太感謝了.我會利用空檔時測試修改.結果.再告知.再說聲感謝

leiru

回復 2# p212


    請問為何D2要輸入此公式呢?
    D2=C2+(1000-ROW())/10000

謝謝

p212

回復 4# leiru
處理同分者相同排名問題
將原有來源資料的「分數」加上(1000-ROW())/10000所產生的不重複小數(列號愈大，加上的數字愈小)，以製造出「輔助」欄位新的不重複的「分數」。
請參考！

Hsieh

回復 1# abba9817
定義名稱
Rng
=OFFSET(工作表1!$C$2,,,COUNT(工作表1!$C:$C),)
H2:K21陣列公式
=INDEX($A$2:$D$21,MATCH(SMALL(RANK(Rng,Rng)+COUNTIF(OFFSET(Rng,-1,,ROW(INDIRECT("A1:A"&COUNT(Rng)))),Rng),ROW(INDIRECT("A1:A"&COUNT(Rng)))),RANK(Rng,Rng)+COUNTIF(OFFSET(Rng,-1,,ROW(INDIRECT("A1:A"&COUNT(Rng)))),Rng),0),{1,2,3,4})

下載 (26.29 KB)

2014-8-28 08:59

    Rank.zip (9.31 KB)

下載次數: 10

2014-8-28 09:00