想找出與前一列重複的數字

帖子: 1425
主題: 40
精華: 0
積分: 1449
點名: 0
作業系統: Windows 7
軟體版本: Excel 2010 & 2016
閱讀權限: 50
性別: 男
來自: 台灣
註冊時間: 2020-7-15
最後登錄: 2024-4-16

16^#

發表於 2023-5-29 14:36 | 只看該作者

謝謝論壇,謝謝各位前輩
後學藉此帖練習陣列,學習方案如下,請各位前輩指教

執行結果:

Option Explicit
Sub TEST()
Dim Brr, i&, j%, A$, Q$, TT$, T$
'↑宣告變數
Brr = Range([M1], [A65536].End(xlUp))
'↑令Brr變數是二維陣列,以A~M欄儲存格值帶入陣列中
For i = 1 To UBound(Brr)
'↑設順迴圈i
For j = 1 To UBound(Brr, 2)
'↑設順迴圈j
   T = Brr(i, j)
   '↑令T變數是迴圈Brr陣列值
   If InStr(A, "/" & T & "/") Then TT = TT & "," & T
   '↑如果A變數包含了以(T變數在前後包夾"/"的新字串)??
   '↑令T變數納入TT變數後方,以逗點隔開,成為新字串
   '(當i=1時,A是初始值"",所以條件都不會成立)
   Q = Q & "/" & T & "/"
   '↑令Q變數收集該迴圈的陣列值,做為下一迴圈的A變數
Next j
Brr(i, 1) = Mid(TT, 2): TT = "": A = Q: Q = ""
'↑令Brr陣列第1欄寫入符合條件的數字
Next i
[P1].Resize(UBound(Brr)) = Brr
'↑令Brr陣列值從[P1]開始寫入儲存格裡,超過此範圍的陣列值忽略
End Sub

用行動裝置瀏覽論壇學習很方便,謝謝論壇經營團隊
請大家一起上論壇來交流

版主 Rank: 7 Rank: 7 Rank: 7

准提部林

帖子: 2798
主題: 10
精華: 0
積分: 2854
點名: 0
作業系統: 〔略〕
軟體版本: 〔略〕
閱讀權限: 100
性別: 男
來自: 〔略〕
註冊時間: 2013-5-13
最後登錄: 2024-4-20

15^#

發表於 2021-6-7 13:02 | 只看該作者

回復 14# samwang

12F

讓字典的key夾帶 i 值
當 i=1 時
將 xd(T & "/" & 1)=1 加入字典,
同時檢查 xd(T & "/" & 0) 是否在字典中, 因是第1行, 所以都為"空值",

當 i=2 時
將 xd(T & "/" & 2)=1 加入字典,
同時檢查 xd(T & "/" & 1) 是否在字典中, 因是第2行, 只要字典key帶1的, 即是上下行相同

類推~~
這方法讓所有數字都因行號不同而全部納入字典, 各自成為獨立的key值,
缺點: 字典會放太多資料

帖子: 976
主題: 7
精華: 0
積分: 1018
點名: 0
作業系統: Win10
軟體版本: Office 2016
閱讀權限: 50
性別: 男
註冊時間: 2013-4-19
最後登錄: 2023-9-21

14^#

發表於 2021-6-7 08:12 | 只看該作者

回復 13# 准提部林

字典隨取隨消, 減少佔用資源~~
>> 感謝准大分享，寫得精簡了，發現自己寫的太複雜，#12樓的寫法第1次看過，
真的不好理解，要好好的研究學習一下，謝謝。

版主 Rank: 7 Rank: 7 Rank: 7

准提部林

帖子: 2798
主題: 10
精華: 0
積分: 2854
點名: 0
作業系統: 〔略〕
軟體版本: 〔略〕
閱讀權限: 100
性別: 男
來自: 〔略〕
註冊時間: 2013-5-13
最後登錄: 2024-4-20

13^#

發表於 2021-6-6 12:39 | 只看該作者

字典隨取隨消, 減少佔用資源~~

Sub TEST_A02()
Dim Arr, Brr, xD, i&, j%, TT$
Set xD = CreateObject("Scripting.Dictionary")
Arr = Range([m1], [a65536].End(xlUp))
ReDim Brr(1 To UBound(Arr), 0)
For i = 2 To UBound(Arr)
For j = 1 To UBound(Arr, 2)
xD(Arr(i - 1, j) & "") = 1
Next j
For j = 1 To UBound(Arr, 2)
If xD(Arr(i, j) & "") = 1 Then TT = TT & "," & Arr(i, j)
Next j
Brr(i, 0) = Mid(TT, 2): TT = "": xD.RemoveAll
Next i
[p1].Resize(UBound(Brr)) = Brr
End Sub

.==============================

版主 Rank: 7 Rank: 7 Rank: 7

准提部林

帖子: 2798
主題: 10
精華: 0
積分: 2854
點名: 0
作業系統: 〔略〕
軟體版本: 〔略〕
閱讀權限: 100
性別: 男
來自: 〔略〕
註冊時間: 2013-5-13
最後登錄: 2024-4-20

12^#

發表於 2021-6-6 12:09 | 只看該作者

P欄設為文字格式~~

Sub TEST_A01()
Dim Arr, xD, i&, j%, T$, TT$
Set xD = CreateObject("Scripting.Dictionary")
Arr = Range([m1], [a65536].End(xlUp))
For i = 1 To UBound(Arr)
For j = 1 To UBound(Arr, 2)
T = Arr(i, j): xD(T & "/" & i) = 1
If xD(T & "/" & i - 1) = 1 Then TT = TT & "," & T
Next j
Arr(i, 1) = Mid(TT, 2): TT = ""
Next i
[p1].Resize(UBound(Arr)) = Arr
End Sub

'==============================

f00l01

中學生 Rank: 2

帖子: 17
主題: 6
精華: 0
積分: 63
點名: 0
作業系統: Windows 10
軟體版本: Excel 2016
閱讀權限: 20
性別: 男
註冊時間: 2021-1-7
最後登錄: 2021-7-22

11^#

發表於 2021-5-24 09:50 | 只看該作者

好的，我再測試看看，謝謝大大

帖子: 976
主題: 7
精華: 0
積分: 1018
點名: 0
作業系統: Win10
軟體版本: Office 2016
閱讀權限: 50
性別: 男
註冊時間: 2013-4-19
最後登錄: 2023-9-21

10^#

發表於 2021-5-20 08:31 | 只看該作者

回復 1# f00l01

比對後結果顯示在同一格儲存格，請測試看看，謝謝。
Sub 結果顯示同一格()
Dim Arr, Ar(), xD, xD2, T, i&, C%
Set xD = CreateObject("Scripting.Dictionary")
Set xD2 = CreateObject("Scripting.Dictionary")
Arr = Range("a1").CurrentRegion
ReDim Ar(1 To UBound(Arr), 0)
For i = 1 To UBound(Arr)
For j = 1 To UBound(Arr, 2)
      T = Arr(i, j)
      If i = 1 Then xD(T & "") = T: GoTo 99
      If C = 0 Then
         M = xD(T & ""): xD2(T & "") = T
         If M > 0 Then Ar(i, 0) = Ar(i, 0) & "," & xD(T & "")
      Else
         M = xD2(T & ""): xD(T & "") = T
         If M > 0 Then Ar(i, 0) = Ar(i, 0) & "," & xD2(T & "")
      End If
99: Next
If i > 1 Then
      If C = 0 Then
         Ar(i, 0) = Mid(Ar(i, 0), 2): C = 1: Set xD = Nothing
         Set xD = CreateObject("Scripting.Dictionary")
      Else
         Ar(i, 0) = Mid(Ar(i, 0), 2): C = 0: Set xD2 = Nothing
         Set xD2 = CreateObject("Scripting.Dictionary")
      End If
End If
Next
Range("N1").Resize(UBound(Arr)) = Ar
End Sub

擷取1.PNG (15.12 KB)

帖子: 976
主題: 7
精華: 0
積分: 1018
點名: 0
作業系統: Win10
軟體版本: Office 2016
閱讀權限: 50
性別: 男
註冊時間: 2013-4-19
最後登錄: 2023-9-21

9^#

發表於 2021-5-20 08:02 | 只看該作者

本帖最後由 samwang 於 2021-5-20 08:07 編輯

簡化一下#8樓程式，不好意思，後學思慮不夠細心，一直再修改簡化，請再測試看看，謝謝。
Sub test3()
Dim Arr, xD, xD2, Ar(), T, i&, C%
Set xD = CreateObject("Scripting.Dictionary")
Set xD2 = CreateObject("Scripting.Dictionary")
Arr = Range("a1").CurrentRegion
For i = 1 To UBound(Arr)
ReDim Ar(1 To 1, 1 To UBound(Arr, 2))
For j = 1 To UBound(Arr, 2)
      T = Arr(i, j)
      If i = 1 Then xD(T & "") = T: GoTo 99
      If C = 0 Then
         M = xD(T & ""): xD2(T & "") = T
         If M > 0 Then N = N + 1: Ar(1, N) = xD(T & "")
      Else
         M = xD2(T & ""): xD(T & "") = T
         If M > 0 Then N = N + 1: Ar(1, N) = xD2(T & "")
      End If
99: Next
If i > 1 Then
      If C = 0 Then
         Cells(i, 15).Resize(1, N) = Ar
         C = 1: Erase Ar: Set xD = Nothing: N = 0
         Set xD = CreateObject("Scripting.Dictionary")
      Else
         Cells(i, 15).Resize(1, N) = Ar
         C = 0: Erase Ar: Set xD2 = Nothing: N = 0
         Set xD2 = CreateObject("Scripting.Dictionary")
      End If
End If
Next
End Sub

擷取.PNG (16.88 KB)

帖子: 976
主題: 7
精華: 0
積分: 1018
點名: 0
作業系統: Win10
軟體版本: Office 2016
閱讀權限: 50
性別: 男
註冊時間: 2013-4-19
最後登錄: 2023-9-21

8^#

發表於 2021-5-17 15:36 | 只看該作者

本帖最後由 samwang 於 2021-5-17 15:47 編輯

簡化一下#7樓程式，請測試看看，謝謝。
寫得不好，不知其他大大有無其他寫法可分享，感謝。

Sub test2()
Dim Arr, xD, xD2, Ar(), T, i&, C%
Set xD = CreateObject("Scripting.Dictionary")
Set xD2 = CreateObject("Scripting.Dictionary")
Arr = Range("a1").CurrentRegion
For i = 1 To UBound(Arr)
ReDim Ar(1 To 1, 1 To UBound(Arr, 2))
For j = 1 To UBound(Arr, 2)
      T = Arr(i, j)
      If i = 1 Then xD(T & "") = T: GoTo 99
      If C = 0 Then
          M = xD(T & "")
         If M > 0 Then N = N + 1: Ar(1, N) = xD(T & "")
         xD(T & "") = T: xD2(T & "") = T
      Else
          M = xD2(T & "")
         If M > 0 Then N = N + 1: Ar(1, N) = xD2(T & "")
         xD(T & "") = T: xD2(T & "") = T
      End If
99: Next
If i > 1 Then
      If C = 0 Then
         Cells(i, 15).Resize(1, N) = Ar
         C = 1: Erase Ar: Set xD = Nothing: N = 0
         Set xD = CreateObject("Scripting.Dictionary")
      Else
         Cells(i, 15).Resize(1, N) = Ar
         C = 0: Erase Ar: Set xD2 = Nothing: N = 0
         Set xD2 = CreateObject("Scripting.Dictionary")
      End If
End If
Next
End Sub

擷取.PNG (13.66 KB)