Board logo

標題: [發問] 清除重覆的資料 [打印本頁]
作者: xbzxbzxbz    時間: 2013-6-26 15:57     標題: 清除重覆的資料

請問各位大大：
假設如下資料：
產品A及產品D因立帳錯誤，故做銷帳動作
請問有什麼公式可以讓產品A及產品D這種又立帳又銷帳的重覆資料直接刪除整列
感謝您!


產品        立銷帳        單價        銷售量        金額
A        立帳        5        10        50
A        銷帳        5        10        50
A        立帳        5        5        25
B        立帳        10        2        20
C        立帳        2        2        4
D        立帳        6        8        48
D        銷帳        6        8        48
E        立帳        1        10        10
F        立帳        3        6        24
G        立帳        2        5        10
作者: sunnyso    時間: 2013-6-26 23:01

銷帳是否總是跟在立賬後面
作者: sunnyso    時間: 2013-6-26 23:04

條件不足， 如下情況A 產品應該刪除哪幾列哪？

產品        立銷帳        單價        銷售量        金額
A        立帳        5        10        50
A        銷帳        5        10        50
A        立帳        5        5        25
B        立帳        10        2        20
A        立帳        5        10        50
D        立帳        6        8        48
D        銷帳        6        8        48
E        立帳        1        10        10
F        立帳        3        6        24
G        立帳        2        5        10
作者: Hsieh    時間: 2013-6-27 16:39

回復 1# xbzxbzxbz

如圖:增加輔助欄1、輔助欄2
F2=A2&E2
向下複製
G2陣列公式
=IF(ROW(A1)>SUMPRODUCT((COUNTIF($F$2:$F$11,$F$2:$F$11)=1)*1),"",SMALL(IF(COUNTIF($F$2:$F$11,$F$2:$F$11)=1,ROW($F$2:$F$11),""),ROW(A1)))
向下複製
H3=IF($G2="","",INDEX($A$1:$E$11,$G2,COLUMN(A$1)))
向右向下複製
[attach]15328[/attach]
作者: xbzxbzxbz    時間: 2013-6-28 09:11

回復 3# sunnyso


沒錯
銷帳總是跟在立帳後面
辛苦了

要刪除的包含同一筆產品的立帳及銷帳
作者: xbzxbzxbz    時間: 2013-6-28 09:12

回復 4# Hsieh


    H大
感謝您
我先試試
作者: Bodhidharma    時間: 2013-6-28 10:04

回復  xbzxbzxbz

如圖:增加輔助欄1、輔助欄2
F2=A2&E2
向下複製
G2陣列公式
=IF(ROW(A1)>SUMPRODUC ...
Hsieh 發表於 2013-6-27 16:39


這樣子寫的話，同產品同金額的立帳或銷帳如果有兩筆(如：兩個50元A產品的立帳)，也會被刪掉
F2是否應該為A2&B2&C2&D2&E2？
作者: sunnyso    時間: 2013-6-28 13:09

增加輔助欄F
F2=IF(OR(B3="銷帳", B2="銷帳"),"v",ROW())
向下複製

H2=IFERROR(INDEX(A:A,SMALL($F:$F,ROW($A1))),"")
向右向下複製
作者: xbzxbzxbz    時間: 2013-6-28 15:35

回復 8# sunnyso

感謝各位大大協助
再次感謝您
作者: softsadwind    時間: 2013-6-28 16:01

回復 9# xbzxbzxbz


F2=A2&E2
向下複製
G2==IF(IF(B2="銷帳",COUNTIFS(A$2:A2,A2,B$2:B2,B2,C$2:C2,C2)>COUNTIFS(A$2:A$18,A2,B$2:B$18,"立帳",C$2:C$18,C2),COUNTIFS(A$2:A2,A2,B$2:B2,B2,C$2:C2,C2)>COUNTIFS(A$2:A$18,A2,B$2:B$18,"銷帳",C$2:C$18,C2)),ROW(),"")
向下複製
H2=IFERROR(INDEX(A:A,SMALL($G:$G,ROW($A1))),"")
向右下複製
作者: sunnyso    時間: 2013-7-1 10:19

回復 5# xbzxbzxbz
增加輔助欄F
F2=IF(OR(B3="銷帳", B2="銷帳"),"v",ROW())
向下複製

H2=IFERROR(INDEX(A:A,SMALL($FF ...
sunnyso 發表於 2013-6-28 13:09


不加輔助欄方法，要用陣列公式。當資料大時，不建議使用陣列公式，因爲慢。

H2={IFERROR(INDEX(A:A,SMALL(IF(($B$3:$B$22="銷帳")+($B$2:$B$21="銷帳")=1,"v",ROW($A$2:$A$21)),ROW($A2:$A21)-1)),"")}
此式輸入方式不可以用ENTER輸入，需用三鍵(CTRL+SHIFT+ENTER)齊按方式輸入公式



歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)