標題:
[發問]
公式怎麼寫
[打印本頁]
作者:
shootingstar
時間:
2013-1-3 13:33
標題:
公式怎麼寫
如果A1=10730526、 B1=24201766，
我要怎麼讓C1= INT(((1*2)+(0*4)+(7*2)+(3*0)+(0*1)+(5*7)+(2*6)+(6*6))/10)
="09"
要讓C1取兩碼，不足時用"0"補齊，謝謝。
作者:
p212
時間:
2013-1-3 13:49
本帖最後由 p212 於 2013-1-3 13:52 編輯
回復
1#
shootingstar
供您參考，請試試看！
=
CONCATENATE(REPT("0",
2
-LEN(
INT(((1*2)+(0*4)+(7*2)+(3*0)+(0*1)+(5*7)+(2*6)+(6*6))/10))
),
INT(((1*2)+(0*4)+(7*2)+(3*0)+(0*1)+(5*7)+(2*6)+(6*6))/10)
)
說明：藍字「2」，表顯示「二」位數，個位數者其十位數以"0"填補，如"09"。
作者:
shootingstar
時間:
2013-1-3 13:53
回復
2#
p212
謝謝p212 的回答，有達到我要補"0"的需求，可是因為A1的數字會一直變動，我不能每次A1變動時，都在公式裡一個一個數字去改，我想知道的是在INT這個公式裡我要怎麼去帶A1跟B1的儲存格，謝謝。
作者:
p212
時間:
2013-1-3 14:03
本帖最後由 p212 於 2013-1-3 14:05 編輯
回復
3#
shootingstar
1.請問A1儲存格的數字每次位碼皆相同?
2.底線標示部份為固定?可否將您的問題再清楚地描述一下?
INT(((1*
2
)+(0*
4
)+(7*
2
)+(3*
0
)+(0*
1
)+(5*
7
)+(2*
6
)+(6*
6
))/10)
作者:
shootingstar
時間:
2013-1-3 14:18
回復
4#
p212
謝謝p212的回覆
A1儲存格是固定的8碼，可是每次數字都會不同，可是B1的24201766就都不會變動
如果A1=70730526
那麼C1=INT(((7*2)+(0*4)+(7*2)+(3*0)+(0*1)+(5*7)+(2*6)+(6*6))/10)=11
如果C1=10730526
那麼C1=INT(((7*2)+(0*4)+(7*2)+(3*0)+(0*1)+(5*7)+(2*6)+(6*6))/10)=9
如果以我自己寫的公式，就沒辦法取兩碼，將剛剛您的公式套進去後就OK，可是因為A1是變動的，所以才想說能不能直接帶儲存格的值？謝謝。
作者:
p212
時間:
2013-1-3 15:16
本帖最後由 p212 於 2013-1-3 15:18 編輯
回復
5#
shootingstar
1.請將您C1儲存格原有的公式=INT(((7*2)+(0*4)+(7*2)+(3*0)+(0*1)+(5*7)+(2*6)+(6*6))/10)
直接以文字函數_LEFT、MID、RIGHT改為下列公式即可
=INT(((LEFT(A1,1)*2)+(MID(A1,2,1)*4)+(MID(A1,3,1)*2)+(MID(A1,4,1)*0)+(MID(A1,5,1)*1)+(MID(A1,6,1)*7)+(MID(A1,7,1)*6)+(RIGHT(A1,1)*6))/10)
2.為免公式複雜，請另於D1儲存格寫入=CONCATENATE(REPT("0",2-LEN(C1)),C1)以顯示您所要的答案。(建議運用_隱藏C欄_即可減少不必要的欄位出現)
作者:
zz5151353
時間:
2013-1-3 15:59
本帖最後由 zz5151353 於 2013-1-3 16:09 編輯
很忙沒時間想短的公式
請參考 C1
{=TEXT(INT(SUM(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)*MID(B1,ROW(INDIRECT("1:"&LEN(B1))),1))/10),"00")}
作者:
Hsieh
時間:
2013-1-3 16:12
回復
5#
shootingstar
=TEXT(INT(SUMPRODUCT(--MID(A1,ROW(INDIRECT("A1:A"&LEN(A1))),1),--MID(B1,ROW(INDIRECT("A1:A"&LEN(A1))),1))/10),"00")
作者:
p212
時間:
2013-1-3 16:45
請問Hsieh版大，為何公式
=TEXT(INT(SUMPRODUCT(--MID(A1,ROW(INDIRECT("A1:A"&LEN(A1))),1),--MID(B1,ROW(INDIRECT("A1:A"&LEN(A1))),1))/10),"00")
不可使用? (以A1儲存格輸入70730526，答案為0，並不是11。)
作者:
p212
時間:
2013-1-3 16:50
Hsieh版大：對不起！是我疏忽。公式漂亮、無誤，謝謝！
作者:
Hsieh
時間:
2013-1-3 16:52
回復
9#
p212
[attach]13771[/attach]
歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)
