標題:
[發問]
個數加總
[打印本頁]
作者:
shootingstar
時間:
2012-12-13 11:24
標題:
個數加總
我在A1到A7分別輸入A、B、C、D、E、F、G，如果我要計算除了A*3+B~G都*5的加總，目前我只想到以下公式
=if(countif(A1:A7,"A")=1,counta(A1:A7)*5-countif(A1:A7,"A")*2,counta(A1:A7)*5)=33
不知道有沒有其他方式可達成？
又或著我要計算A~B*3+C~G*5=31，要怎麼寫公式，謝謝。
作者:
zz5151353
時間:
2012-12-13 15:38
{=SUM(MMULT(N(A1:A7={"A","B","C","D","E","F","G"})*ROW(1:7)^0,{3;5;5;5;5;5;5}))}
OR
{=SUM(MMULT(N(A1:A7=TRANSPOSE(A1:A7))*ROW(1:7)^0,{3;5;5;5;5;5;5}))}
作者:
shootingstar
時間:
2012-12-13 17:34
回復
2#
zz5151353
謝謝zz5151353 版主的回答，公式看得有點吃力，不過有達到需求，可是如果今天我的資料是從A1到C100，或是我的資料沒有照順序排，那,{3;5;5;5;5;5;5}這幾個數字不是要輸入300次，而我也不知道A是在那一欄位，那3也就不知道要放在那個位置了，謝謝。
作者:
Hsieh
時間:
2012-12-13 17:45
回復
3#
shootingstar
=SUM(SUMPRODUCT((A1:A7="A")*3),SUMPRODUCT((A1:A7<>"A")*5))
作者:
zz5151353
時間:
2012-12-13 18:13
本帖最後由 zz5151353 於 2012-12-13 18:19 編輯
回復 zz5151353
謝謝zz5151353 版主的回答，公式看得有點吃力，不過有達到需求，可是如果今天我的資 ...
shootingstar 發表於 2012-12-13 17:34
只告訴你一思維,沒附件用猜的
如果 3 的位置不定 且沒有規律,公式就沒辦法著手了
{=SUM((A1:A7="A")*3+(A1:A7<>"A")*5)}
作者:
shootingstar
時間:
2012-12-14 15:53
謝謝Hsieh及zz5151353 的回覆，有學到新方法可以算出答案，不過因為沒有檔案所以問題也沒描述清楚，如果A1到A7有七個欄位，但我沒有全部輸入資料，以這樣的原則去計算答案，一開始是假設只有A是*3，但如果以後資料越來越多，可能有H或T都是*3，這樣的公式又該如何下，謝謝。
作者:
Hsieh
時間:
2012-12-14 16:46
回復
6#
shootingstar
陣列公式
=SUMPRODUCT(IF(ISNUMBER(MATCH(F4:F36,{"A"},0)),3,5)*(F4:F36<>""))
作者:
ML089
時間:
2012-12-22 18:32
原F38公式
=IF(COUNTIF(F$4:F$36,"A")=1,COUNTA(F$4:F$36)*5-COUNTIF(F$4:F$36,"A")*2,COUNTA(F$4:F$36)*5)
可以改為
=COUNTA(F$4:F$36)*5-COUNTIF(F$4:F$36,"A")*2
如果要擴增 A、B、...H的減項
可以改為
=COUNTA(F$4:F$36)*5-SUMPRDUCT(COUNTIF(F$4:F$36,{"A","B","C"})*{1,2,3})
或將比對資料放在儲存格
B44:B55 = {"A";"B";"C" ....}
C44:C55 = {1;2;3 ....}
可以改為
=COUNTA(F$4:F$36)*5-SUMPRDUCT(COUNTIF(F$4:F$36,B44:B55)*C44:C55)
歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)
