麻辣家族討論版版 - Powered by Discuz! Board

標題: [發問] 多頁工作表挑出符合資格彙整到新的工作頁 [打印本頁]

作者: pilied2k 時間: 2012-9-30 09:45 標題: 多頁工作表挑出符合資格彙整到新的工作頁

如範例表格
範列中有多個分頁我想在總表弄一個可以查詢某日能挑出符合訊號的分頁工作表彙整到總表
請問該如何做

作者: pilied2k 時間: 2012-9-30 09:46

[attach]12640[/attach]
剛忘了上傳

作者: ANGELA 時間: 2012-9-30 10:32

符合的條件是什麼?看不出來,是多還是空.

作者: pilied2k 時間: 2012-9-30 10:45

[attach]12641[/attach]
做這樣調整
麻煩了

作者: ANGELA 時間: 2012-9-30 11:14

=VLOOKUP(LOOKUP(2,1/($A$1:$A2<>""),$A$1:$A2),INDIRECT($B2&"!a:K"),COLUMN(I1),)
同一個公式往下拉不能顯示不同的結果.日期最好用日期格式,方便計算
=VLOOKUP(LOOKUP(9^9,$A$1:$A2),INDIRECT($B2&"!a:K"),COLUMN(I1),)

作者: pilied2k 時間: 2012-9-30 11:25

[attach]12644[/attach]
請問版主  日期要改成什麼樣的日期格式

我做這個目的主要是想輸入日期
讓各分頁符合條件的個股
自動在總表秀出來  沒符合條件的個股就不會出現
所以  日期格式還麻煩版大提醒教導

作者: ANGELA 時間: 2012-9-30 11:58

符合條件,是符合什麼條件,要讓別人了解你的需求,才能幫上忙.
你範例的資料應是copy下來的所以看似日期,其實不是,254列看似空格其實也不是空格
5樓是假設已知A2的日期及B2:B4的代號求出的C3到E4的結果

作者: pilied2k 時間: 2012-9-30 12:08

[attach]12645[/attach]
謝謝版大提醒
我想先將問題簡單化
符合條件只要個股分頁對應查詢的日期該 (訊號1)為"空"
則都匯入總表這裡
這樣不知能否可行

作者: ANGELA 時間: 2012-9-30 17:37

多維還是用vba會簡單些,公式要用到補助列及定義名稱很麻煩.

作者: pilied2k 時間: 2012-9-30 17:47

完蛋了我都沒有vba的基礎
還有沒有救阿

作者: ANGELA 時間: 2012-9-30 19:24

[attach]12648[/attach]
1101:1203的O1=RIGHT(表名,4)
i1=CELL("filename",INDIRECT(1100+ROW(A1)&"!a1"))
j1={RIGHT(IF(tot<ROW(),"",INDEX(I:I,SMALL(IF(ISTEXT($I$1:$I$200),ROW($A$1:$A$200)),ROW(A1)))),4)}
k1=IF($J1="","",IF(INDIRECT($J1&"!"&"i253")="空","空",""))

B1{=INDEX(J:J,SMALL(IF($K$1:$M$20="空",ROW($A$1:$A$20),99),ROW(1:1)))&""}
C1=IF($J1="","",VLOOKUP(B2,J1:K9,2,))
定義名稱
tot=COUNTA(總表!$I$1:$I$300)-SUM(ISERROR(總表!$I$1:$I$300)*1)
表名=CELL("filename",!C1)

作者: pilied2k 時間: 2012-9-30 20:14

請問  版大
定義名稱
我該去哪做設定
能否請版大  將檔案寄到我的信箱 [email protected]
讓我參考一下  我在定義名稱那邊看不懂

作者: pilied2k 時間: 2012-9-30 20:32

[attach]12650[/attach]
定義表名 ok
但 tot 定義完沒反應
是我用office 2003的關係嗎?

作者: pilied2k 時間: 2012-10-1 08:23

研究一整晚  終於知道我哪邊錯了
貼上公式時" {}"  要先去掉  然後按Ctrl+Shift+Enter  就會自動產生
這樣我就完全可以輸出跟板大貼的圖片一樣的結果了非常感謝

還請教板大  為何我改變日期後  資料都不會變動
是我的日期格式錯誤還是哪邊出錯

作者: ANGELA 時間: 2012-10-1 09:31

A欄日期看似日期，實際是文字模式。
選A欄。再用資料剖析。欄位資料格式選日期的YMD。
或在任一儲存格輸入1，=> COPY =>選A欄=>右鍵=>選擇性貼上=>乘。再設成日期格式。

作者: pilied2k 時間: 2012-10-1 10:59

[attach]12655[/attach]
請教版主
我把日期刪除  確可以留下資料
然而  我只要在
k=IF($J1="","",IF(INDIRECT($J1&"!"&CHAR(64+COLUMN(I1))&"253")="空","空",""))
把253  更改252或251  資料便會更改了
那麼這樣看來  好像日期那欄位  無效
沒辦法由日期來對應到當日的資料欄位

作者: ANGELA 時間: 2012-10-1 13:12

k1=IF($J1="","",IF(INDIRECT($J1&"!i"&MATCH(A$2,INDIRECT(J1&"!a:a"),))="空","空",""))

作者: pilied2k 時間: 2012-10-1 14:45

[attach]12657[/attach]
感謝版主指導:victory:
可由日期叫出資料了
目前剩下最後一個問題了
剛我測試時我若直接將1101內的日期 copy貼到總表日期欄位時可以執行
但若手動在總表的日期欄位改日期就無法執行

作者: ANGELA 時間: 2012-10-1 16:35

用15樓的方法全部改成日期格式。試試。
資料應是copy來的，是文字模式,日期用手動輸入是日期格式。若怕麻煩可把總表A欄改成文字模式也可以。

作者: pilied2k 時間: 2012-10-2 08:45

k1=IF($J1="","",IF(INDIRECT($J1&"!"&CHAR(64+COLUMN(I1))&MATCH(TEXT(A$2,"yyyy/mm/dd"),INDIRECT($J1&"!A:A"),0))="空","空",""))

修改成這樣就可以了
終於完成了
謝謝版大指導

歡迎光臨麻辣家族討論版版 (http://forum.twbts.com/)