標題: [發問] 查表計算 [打印本頁]

---

作者: babesia    時間: 2012-3-19 21:24     標題: 查表計算

sheet1
薪點 待遇
210  20000
220  21548
230  25874
245  27584
260  25874

sheet2
220  B1

若想在SHEET2的B1儲存格
計算A1儲存格的薪點(220)與其低一等級之薪點(210)之待遇差額(查SHEET1工作表)
在B1應如何下公式呢

---

作者: register313    時間: 2012-3-19 21:47

回復 1# babesia

B2=VLOOKUP(A2,Sheet1!A2:B6,2,0)-VLOOKUP(A2-0.1,Sheet1!A2:B6,2,1)
B2=LOOKUP(A2,Sheet1!A2:A6,Sheet1!B2:B6)-LOOKUP(A2-0.1,Sheet1!A2:A6,Sheet1!B2:B6)
B2=INDEX(Sheet1!A2:B6,MATCH(A2,Sheet1!A2:A6,0),2)-INDEX(Sheet1!A2:B6,MATCH(A2,Sheet1!A2:A6,0)-1,2)
B2=OFFSET(Sheet1!A2,MATCH(A2,Sheet1!A2:A6)-1,1)-OFFSET(Sheet1!A2,MATCH(A2,Sheet1!A2:A6)-2,1)

---

作者: babesia    時間: 2012-3-19 22:39

B2=VLOOKUP(A2,Sheet1!A2:B6,2,0)-VLOOKUP(A2-0.1,Sheet1!A2:B6,2,1)

請問公式中A2-0.1是代表什麼意思?

---

作者: register313    時間: 2012-3-19 23:36

回復 3# babesia

設A2=220
B2=VLOOKUP(A2,Sheet1!A2:B6,2,0)-VLOOKUP(A2-0.1,Sheet1!A2:B6,2,1)
    =VLOOKUP(220,Sheet1!A2:B6,2,0)-VLOOKUP(219.9,Sheet1!A2:B6,2,1)
      找220 傳回21548                 找219.9(若找不到則找僅次於219.9之值,即200) 傳回20000

    =21548-20000

---

作者: Hsieh    時間: 2012-3-20 08:20

本帖最後由 Hsieh 於 2012-3-20 08:25 編輯

回復 1# babesia


    210點的差額計算標準為何?
若210點差額是20000
Sheet2!B1陣列公式
=LOOKUP(A1,Sheet1!$A$2:$A$6,Sheet1!$B$2:$B$6-IF(ISNUMBER(Sheet1!$B$1:$B$5),Sheet1!$B$1:$B$5,0))

---

作者: ANGELA    時間: 2012-3-20 12:07

=LOOKUP(A1,Sheet1!A2:A6,(Sheet1!B2:B6-Sheet1!B1:B5))

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)