麻辣家族討論版版 - Powered by Discuz! Board

標題: 請問LOOKUP有進階版嗎? [打印本頁]

作者: vpower 時間: 2010-6-3 20:09 標題: 請問LOOKUP有進階版嗎?

提示: 作者帳號被禁止或禁止訪問

作者: asimov 時間: 2010-6-4 01:24

先建立資料表格
G2=VLOOKUP(RIGHT(D2,2),資料表格範圍,2,0)
幼兒園建立資料表格時改用"兒園"

資料表格如下
兒園  1
國小  2
國中  3
.  .
.  .

作者: zz5151353 時間: 2010-6-4 08:13

G2

=LOOKUP(2,1/FIND({"幼兒園","國小","國中","高中","學院","護校","大學"},D2),{1,2,3,4,5,5,5})

作者: gong 時間: 2010-6-4 08:42

比較標準用法建議用vlookup(..),如asimov所示
幼兒園就幼兒園應該不用改兒園吧

也提供一種試試
=--MID("1xx2x3x4x5x5x5x",FIND($D2,"幼兒園國小國中高中學院護校大學"),1)

作者: zz5151353 時間: 2010-6-4 17:24

欠缺考慮空白
補上

G2

=LOOKUP(,-FIND({"","幼兒園","國小","國中","高中","學院","護校","大學"},D2),{"",1,2,3,4,5,5,5})

作者: vpower 時間: 2010-6-4 17:31

提示: 作者帳號被禁止或禁止訪問

作者: vpower 時間: 2010-6-4 17:53

提示: 作者帳號被禁止或禁止訪問

作者: vpower 時間: 2010-6-4 17:55

提示: 作者帳號被禁止或禁止訪問

作者: john2006168 時間: 2010-6-5 00:39

我打不開file 你可以先用vlookup 後再加上if(iserror)試一下..

作者: asimov 時間: 2010-6-5 02:08

本帖最後由 asimov 於 2010-6-5 02:10 編輯

出現#REF! 不過依然很感謝您的用心.
vpower 發表於 2010-6-4 17:55

資料表格要建立於不同儲存格
[attach]1144[/attach]
G2=VLOOKUP(RIGHT(D2,2),$I$1：$J$7,2,0)

作者: asimov 時間: 2010-6-5 02:15

我打不開file 你可以先用vlookup 後再加上if(iserror)試一下..
john2006168 發表於 2010-6-5 00:39

如果vlookup使用不出現錯誤#REF!
也就不需要用iserror了

作者: gong 時間: 2010-6-5 11:17

本帖最後由 gong 於 2010-6-5 11:18 編輯

更正原提供參考
=--MID("1234555",SUMPRODUCT({1,2,3,4,5,6,7}*COUNTIF(D2,{"*幼兒園","*國小","*國中","*高中","*學院","*護校","*大學"})),1)

作者: asimov 時間: 2010-6-5 13:40

更正原提供參考
=--MID("1234555",SUMPRODUCT({1,2,3,4,5,6,7}*COUNTIF(D2,{"*幼兒園","*國小","*國中","* ...
gong 發表於 2010-6-5 11:17

版主厲害用"顛覆思維"的做法

小弟冒昧借用您的公式簡化一下
=SUMPRODUCT({1,2,3,4,5,5,5}*COUNTIF(D2,{"*幼兒園","*國小","*國中","*高中","*學院","*護校","*大學"}))

作者: gong 時間: 2010-6-5 14:15

解的好

作者: 爆肝達人 時間: 2010-6-7 15:18

資料表格要建立於不同儲存格

G2=VLOOKUP(RIGHT(D2,2),$I$1：$J$7,2,0)
asimov 發表於 2010-6-5 02:08

超實用^^

剛好看到圖片!!

不然都不太曉得如何使用

作者: vpower 時間: 2010-6-10 21:29

提示: 作者帳號被禁止或禁止訪問

作者: vpower 時間: 2010-6-10 21:31

提示: 作者帳號被禁止或禁止訪問

歡迎光臨麻辣家族討論版版 (http://forum.twbts.com/)