標題: 只顯示沒有重覆的資料 [打印本頁]

---

作者: enoch    時間: 2011-8-23 15:51     標題: 只顯示沒有重覆的資料

各位高手:
有兩欄資料, 如何將兩欄資料合併後
再只顯示沒有重覆的資料
我現時需要加上一欄先將資料合併,
再用countif去顯示, 但可以有更簡方法嗎
請指教:

資料1        資料2        顯示沒有重覆資料
1        a        1a
1        a       
1        b        1b
1        b       
1        c        1c
2        a        2a
2        a       
2        b        2b
2        b       
2        c        2c
2        c       
3        a        3a
3        b        3b
3        c        3c
3        d        3d

---

作者: oobird    時間: 2011-8-23 16:10

=IF(SUMPRODUCT(1*(A$2:A2&B$2:B2=A2&B2))=1,A2&B2,"")

---

作者: enoch    時間: 2011-8-23 17:04

多謝oobird
又是用到sumproduct, 我始終唔明白這公式用法
可否講解sumproduct 點用嗎?

---

作者: oobird    時間: 2011-8-23 19:26

先以SUMPRODUCT
google一下吧。
還有盲點再提出討論

---

作者: man65boy    時間: 2011-8-24 00:19

=IF(SUM(--(COUNTIF($C$2:$C$18,$C$2:$C$18)=1))>=ROW(A1),INDEX($C$2:$C$18,SMALL(IF(COUNTIF($C$2:$C$18,$C$2:$C$18)=1,ROW($C$2:$C$18),""),ROW(A1))-1),"")

陣列公式輸入完須按 Ctrl+Shift+Enter 三鍵才可得到

[attach]7555[/attach]

---

作者: enoch    時間: 2011-8-25 14:42

本帖最後由 enoch 於 2011-8-25 14:45 編輯

睇過說明後, 始終有問題,
sumproduct 類似sumif 及 countif 但還分唔清點用
若以下面例子, 當種類相同, 可以只顯示最大數量的金額嗎?
例如蘋果 :$18  ;橙 $19
請指教

數量  種類  金額
15    蘋果  $5
20    蘋果  $10
35    蘋果  $18
2     橙    $7
3     橙    $19

---

作者: oobird    時間: 2011-8-25 15:18

[attach]7579[/attach]

---

作者: man65boy    時間: 2011-8-25 20:49

有點搞不清楚板大標題是在問甚麼，針對在提問的問題

=INDEX($C$2:$C$6,MATCH(MAX(($B$2:$B$6=E2)*($A$2:$A$6)),$A$2:$A$6,0))

陣列公式輸入完須按 Ctrl+Shift+Enter 三鍵

[attach]7580[/attach]

試看看!!!

---

作者: enoch    時間: 2011-8-26 10:39

本帖最後由 gong 於 2011-8-27 21:38 編輯

不好意思, 是我太懶沒有分開問題,
而兩位高手所教導的使我得益不少

man65boy 的公式出現少少問題:
=INDEX($C$2:$C$6,MATCH(MAX(($B$2:$B$6=E2)*($A$2:$A$6)),$A$2:$A$6,0))
當蘋果與橙的數量相同時, 公式只會取蘋果的金額

---

作者: man65boy    時間: 2011-8-27 13:15

拍事..驗證太少...沒注意到，在試試以下函數

=IF(ISNA(INDEX($C$2:$C$20,MATCH(E2&MAX(IF(($B$2:$B$20=E2),$A$2:$A$20)),$B$2:$B$20&$A$2:$A$20,0))),"",INDEX($C$2:$C$20,MATCH(E2&MAX(IF(($B$2:$B$20=E2),$A$2:$A$20)),$B$2:$B$20&$A$2:$A$20,0)))

陣列公式輸入完須按 Ctrl+Shift+Enter 三鍵
[attach]7614[/attach]

---

作者: gong    時間: 2011-8-27 21:49

本帖最後由 gong 於 2011-8-27 21:52 編輯

陣列
f2{=IF(E2="","",MAX(($B$2:$B$20=E2)*$C$2:$C$20))}

與7樓oobird版主差不多

---

作者: zz5151353    時間: 2013-1-3 13:02

借用10樓 man65boy 兄附件一用
E2  公式
{=INDEX($B$2:$B$20,MATCH(,COUNTIF($E$1:E1,$B$2:$B$20),))&""}

F2 公式

=IF(E2="","",LOOKUP(1,0/(MAX((B$2:B$10=E2)*A$2:A$10)=(B$2:B$10=E2)*A$2:A$10),C$2:C$10))

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)