標題:
[發問]
[發問]如何用迴圈取出陣列值，不斷放到一個固定範圍
[打印本頁]
作者:
yurckr
時間:
2011-7-13 16:57
標題:
[發問]如何用迴圈取出陣列值，不斷放到一個固定範圍
請教以下寫法
For i = 1 To
myarray = Split((Sheets(moneyprlist).Cells(i + 2, 14)), ",", , 1)
For j = 0 To UBound(myarray)
Sheets(moneyprlist).Cells(i + 2, j + 13) = myarray(j)
timer = timer + 1
Next j
If timer = 6 Then
MsgBox "已經搜集六個了可以印囉"
Call ptprint
endif
end sub
我想讓這程式的作用是將陣列裏的值放到 m3:m8 的固定範圍內，一共六個空格，當放滿六個時則清除該飯圍的值
繼續再取出六個值放入該飯圍，直到取完陣列裏所有的值為止
不知道該怎麼寫 請指導 謝謝
作者:
yurckr
時間:
2011-7-16 17:29
請各位高手指導一下怎麼寫 感謝
作者:
GBKEE
時間:
2011-7-16 19:28
回復
2#
yurckr
請附檔上來說清楚
作者:
yurckr
時間:
2011-7-17 17:26
[attach]7033[/attach]
回復
3#
GBKEE
感謝您的關注，想表達的意司已經在檔案中 請您指教謝謝
作者:
GBKEE
時間:
2011-7-17 21:04
本帖最後由 GBKEE 於 2011-7-18 07:37 編輯
回復
4#
yurckr
Sub 按鈕1_Click()
Dim Ar(), Rng As Range, i, ii
With 工作表1
If .Range("a2").End(xlDown).Row = Rows.Count Then Exit Sub '無資料
Ar = .Range("a3", .Range("a3").End(xlDown))
Set Rng = .Range("C3:C8") '輸入區
For i = 1 To UBound(Ar) Step 6 '陣列索引 間隔6
Rng = "" '清除輸入區
For ii = i To i + 5 '
If ii <= UBound(Ar) Then Rng(ii - i + 1) = Ar(ii, 1)
'Rng(ii - i + 1) -> 依序為 輸入區的 1,2,3,4,5,6 的Cells
Next
' .PrintOut '印列
Next
MsgBox "印列完畢"
End With
End Sub
Sub Ex()
Dim Rng As Range
With 工作表1
If .Range("a2").End(xlDown).Row = Rows.Count Then Exit Sub '無資料
Set Rng = .Range("A3") 'A列的數據的第1個位置
Do
.Range("C3:C8") = "" '清除輸入區
.Range("C3:C8") = Rng.Resize(6).Value '輸入區的值=Rng擴充6列後的值
' .PrintOut '印列
Set Rng = Rng.Offset(6) '設定A列的數據往下位移6列
Loop Until Application.CountA(Rng.Resize(6)) = 0
'loop 迴圈 離開條件 Until(直到) -> A列 6列沒有數據
MsgBox "印列完畢"
End With
End Sub
複製代碼
歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)
