標題: 把有斜線的文字儲存格找出,再括弧起來? [打印本頁]

---

作者: Qin    時間: 2011-7-4 12:41     標題: 把有斜線的文字儲存格找出,再括弧起來?

炮天雄(行炮付)
大归尾/当归尾
虎乳
草乌片
白七里/蒺藜
正谷精子
草决明/决明子
温金片/郁金片/乙金片

1)如何找出有斜線(/)的儲存格?
2)再將由斜線(/)開始儲存格內的字括弧起來.

原本資料:
大归尾/当归尾

編輯后:
大归尾(当归尾)

---

作者: Eugene    時間: 2011-7-4 22:51

本帖最後由 Eugene 於 2011-7-4 22:59 編輯

回復 1# Qin

    =IF(ISERROR(FIND("/",A1)),A1,LEFT(A1,FIND("/",A1)-1)&"("&RIGHT(A1,LEN(A1)-FIND("/",A1))&")")

不過，"温金片/郁金片/乙金片"會變成"温金片(郁金片/乙金片)"。可以再參考 LEN 及 REPLACE，去寫判斷式，變成您想要的樣式。

---

作者: Hsieh    時間: 2011-7-4 22:55

回復 1# Qin


    =SUBSTITUTE(SUBSTITUTE(A1&")","/",")("),")","",1)

---

作者: Eugene    時間: 2011-7-4 23:04

回復 3# Hsieh


    謝謝版大，多學了個函數。"SUBSTITUTE" 方便多了！

---

作者: smmriyonk    時間: 2011-12-1 22:41

對不起,己過了許久的這篇文被翻了出來。但是HSIEH大大給予的公式讓學生有些疑惑。
請問各位先進,依照樓主的問題,HSIEH大大給的公式能做出正確的答案,讓學生眼睛為之一亮。但是這行公式學生看了許久,還是不太懂,懇請各位先進指教。

根據HSIEH大大的公式:

=SUBSTITUTE(SUBSTITUTE(A1&")","/",")("),")","",1)

裡行公式裡的A1&")" 和最末的1,指的是什麼意思呢？

懇請各位先進耐心指教,謝謝!

---

作者: Hsieh    時間: 2011-12-1 23:00

回復 5# smmriyonk


    這個公式包含2層的SUBSTITUTE函數
先看內層SUBSTITUTE(A1&")","/",")(")
以A1為"温金片/郁金片/乙金片"為例
A1&")"就成了
温金片/郁金片/乙金片)
再將斜線用")("取代
就會成為
温金片)(郁金片)(乙金片)
這樣的字串跟要求的答案會多了第一個括號")"
外層SUBSTITUTE
就成了=SUBSTITUTE("温金片)(郁金片)(乙金片)",")","",1)
這個函數多了第4個引數1
這個引數可以指定第幾個指定字串被取代
也就是將第1個括號")"用空字串""取代
這樣就能達到要求

---

作者: smmriyonk    時間: 2011-12-1 23:40

回復 6# Hsieh


    太神奇了....
沒想到HSIEH大大這麼快就回覆了學生的疑惑,向您致上十二萬分的謝意。
感謝大大耐心的指導,學生也了解這行公式的完整意思了。原來在公式裡,A1&")",可以直接將")"符號帶入A1字串的最尾處,學生真是受教了,謝謝HSIEH大大,感謝您!

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)