標題:
多筆EXECL 之資料,合在一起
[打印本頁]
作者:
tomking
時間:
2011-5-26 00:54
標題:
多筆EXECL 之資料,合在一起
EX:
1. 1.XLS 之SHEET1 頁面 A1:A D3: B
A2:1 B2: 2 C2: 3 D2: 4
..
..
..
2. rt.XLS 之SHEET1 頁面 A1:B D3: R
A2:3 B2: 9 C2: 8 D2: 6
3. ...
4..
合在一起,
變整個LIST
作者:
GBKEE
時間:
2011-5-26 08:33
回復
1#
tomking
合在一起, 變整個LIST
合在哪裡要說清楚
作者:
mark15jill
時間:
2011-5-26 09:48
回復
1#
tomking
方便用一個檔案當例子說明嗎...
不然這樣很籠統
作者:
oobird
時間:
2011-5-27 10:32
資料~匯入外部資料
作者:
tomking
時間:
2011-5-27 12:31
附上附件... 感謝.
作者:
GBKEE
時間:
2011-5-27 14:47
回復
5#
tomking
需求.xls,OS124.xls,OS123.xls 等都開啟的狀態下的程式碼
Option Explicit
Sub Ex()
Dim MyBook As Workbook, B As Workbook, R As Range, i As Long
Set MyBook = Workbooks("需求.XLS")
For Each B In Workbooks '
If B.Name <> MyBook.Name Then
With B.Sheets(1)
For i = 4 To .Cells(Rows.Count, "A").End(xlUp).Row
Set R = MyBook.Sheets("LIST").Cells(Rows.Count, "A").End(xlUp).Offset(1)
R.Resize(, 4) = Array(.[C1], .[E1], .[I2], .[A2])
R.Offset(, 4).Resize(, 11) = .Range(.Cells(i, "A"), .Cells(i, "K")).Value
Next
End With
End If
Next
End Sub
複製代碼
作者:
tomking
時間:
2011-5-28 22:21
回復
6#
GBKEE
DEAR GRKEE
每個需取的EXECEL 檔中,只有一個頁面, 是否有機會,幫忙改成,不用開,來源DATA EXCEL檔,即可取DATA
是否有機會,先將來源DATA 先轉成.csv, 再取data.
以上,請在幫忙
作者:
GBKEE
時間:
2011-5-29 08:01
本帖最後由 GBKEE 於 2011-5-29 10:12 編輯
回復
7#
tomking
"
即可取DATA 是否有機會,先將來源DATA 先轉成.csv, 再取data.
"
看不懂啊
檔案一定要開啟 試試看
Option Explicit
Sub Ex()
Dim R As Range, i As Long, ii As Integer
With Application.FileDialog(msoFileDialogOpen) '檔案對話方塊執行個體
.AllowMultiSelect = True '可複選檔案
.InitialFileName = "D:\TEST" '可修改為你要開啟的目錄
.Show '顯示檔案對話方塊
If .SelectedItems.Count >= 1 Then '選擇的檔案數
For i = 1 To .SelectedItems.Count '依序在選擇的檔案
With Workbooks.Open(.SelectedItems(i)) '開啟檔案
With .Sheets(1)
For ii = 4 To .Cells(Rows.Count, "A").End(xlUp).Row
Set R = Workbooks("需求.XLS").Sheets("LIST").Cells(Rows.Count, "A").End(xlUp).Offset(1)
R.Resize(, 4) = Array(.[C1], .[E1], .[I2], .[A2])
R.Offset(, 4).Resize(, 11) = .Range(.Cells(ii, "A"), .Cells(ii, "K")).Value
Next
End With
.Close False '關閉檔案不存檔
End With
Next
End If
End With
End Sub
複製代碼
作者:
tomking
時間:
2011-6-21 08:26
DEAR GBKEE
THS.
歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)