標題:
[發問]
如何將週六及週日給挑選出來 ?
[打印本頁]
作者:
q1a2z5
時間:
2011-4-22 10:57
標題:
如何將週六及週日給挑選出來 ?
5月的日曆表如下 :
日期 星期
1 日
2 一
3 二
4 三
5 四
．
．
．
挑選結果如下：
週六 週日
1
7 8
14 15
21 22
28 29
作者:
ANGELA
時間:
2011-4-22 11:30
A欄日期B欄星期
C1=IF(COUNTIF(B:B,$B$1)<ROW(),"",TEXT(INDEX(A:A,SMALL(IF($B$1:$B$31=$B$1,ROW($1:$31),100),ROW(A1))),"D"))
如果空白用
週日=IF(SMALL(IF(MOD(ROW(INDIRECT("A40664:A40694")),7)=1,ROW($1:$31),100),ROW(A1))=100,"",SMALL(IF(MOD(ROW(INDIRECT("A40664:A40694")),7)=1,ROW($1:$31),100),ROW(A1)))
都是陣列公式
週六改=0
作者:
q1a2z5
時間:
2011-4-25 11:11
回復
2#
ANGELA
那如果要同時找出週六及週日的日期,公式要如何更改?
週六及週日
1
7
8
14
15
21
22
謝謝 !
作者:
ANGELA
時間:
2011-4-25 12:52
{=IF(SMALL(IF(MOD(ROW(INDIRECT("A40664:A40694")),7)<2,ROW($1:$31),100),ROW(A1))=100,"",SMALL(IF(MOD(ROW(INDIRECT("A40664:A40694")),7)<2,ROW($1:$31),100),ROW(A1)))}
作者:
Hsieh
時間:
2011-4-25 14:37
陣列公式
{=IF(ROW(A1)>SUMPRODUCT((WEEKDAY(ROW($40664:$40694),2)>5)*1),"",SMALL(IF(WEEKDAY(ROW($40664:$40694),2)>5,ROW($40664:$40694),""),ROW(A1)))}
作者:
q1a2z5
時間:
2011-5-10 09:44
如果資料是橫式的話，如何同時將星期六及星期日挑選出來呢 :
五月份的日曆如下，
Ａ欄 Ｂ欄 Ｃ欄 Ｄ欄．．．．．
日期 1 2 3
星期 日 一 二
挑選結果如下：
星期六及星期日 1 7 8 14 15．．．
謝謝！
作者:
ANGELA
時間:
2011-5-10 10:21
公式中的ROW(A1) 改成 COLUMN(A1)
作者:
q1a2z5
時間:
2011-5-24 08:10
如果要找每個月的星期六.日的話，要怎麼作呢？
謝謝！
作者:
ANGELA
時間:
2011-5-24 10:42
陣列用多了會造成程式的負擔,反應會很慢,尤其是複雜的陣列.
{=IF(ROW(A1)>SUMPRODUCT((WEEKDAY(ROW($40664:$40694),2)>5)*1),"",SMALL(IF(WEEKDAY(ROW($
40664
:$
40694
),2)>5,ROW($40664:$40694),""),ROW(A1)))}
40664可以用公式date(2011,5,1)替換
40694 用 date(2011,6,0)替換 六月的第0天即是五月底 等於DATE(2011,5,31)
可在a1輸入 2011 b1輸入1 用下列公式即可產生整年的
b2=IF(ROW(A1)>SUMPRODUCT((WEEKDAY(ROW(INDIRECT(DATE($A$1,$B$1+COLUMN(B1)-1,1)&":"&DATE($A$1,$B$1+COLUMN(B1),0))),2)>5)*1),"",SMALL(IF(MOD(ROW(INDIRECT(DATE($A$1,$B$1+COLUMN(A1)-1,1)&":"&DATE($A$1,$B$1+COLUMN(A1),0))),7)<2,ROW(INDIRECT(DATE($A$1,$B$1+COLUMN(A1)-1,1)&":"&DATE($A$1,$B$1+COLUMN(A1),0)))),ROW(A1)))
歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)
