Board logo

標題: [發問] 讀取及歸類資料 [打印本頁]
作者: 198188    時間: 2023-12-20 11:57     標題: 讀取及歸類資料

左邊是資料檔，右邊是結果
根據左邊的每個櫃的排列表，在右邊分別顯示出每個櫃的明細SR號碼

[attach]37157[/attach][attach]37157[/attach][attach]37157[/attach]
作者: singo1232001    時間: 2023-12-22 05:40

回復 1# 198188


    Sub test()
r = Cells(Rows.Count, 1).End(3).Row
c = 7
Range("H2:J1000").ClearContents
For i = 3 To r
If Cells(i, 1).Value <> "" Then
tx = Split(Cells(i, 1).Value, " ")(0)
mr = Cells(i, 1).MergeArea.Count
If mr > 0 Then
For Each Z In Cells(i, 2).Resize(mr - 1, 5)
If UCase(Z.Value) Like "*SR*" Then
sp = Split(Z.Value, "(")(0)
sp = Replace(sp, "上架", "")
sp = Replace(sp, "下架", "")
sp = Replace(sp, " ", "")
tx = tx & "▲" & sp
End If

Next
c = c + 1
sp0 = Split(tx, "▲")
Cells(2, c).Resize(UBound(sp0) + 1, 1) = Application.Transpose(sp0)
End If
End If
Next
End Sub
作者: 198188    時間: 2023-12-22 09:15

回復 2# singo1232001


        非常感謝！能不能有注釋一下，這樣我可以更好理解每句用意，如果格式或者表格有變動，也可以自己做出修改。:handshake
作者: singo1232001    時間: 2023-12-22 17:21

回復 3# 198188

GPT4
Sub test()
    ' 定義變量並初始化變量r為第一列最後一個非空行的行號
    r = Cells(Rows.Count, 1).End(xlUp).Row
    ' 初始化輸出起始的列號c為第7列（即G列）
    c = 7

    ' 清除從H2到J1000的內容，為新的輸出做準備
    Range("H2:J1000").ClearContents

    ' 從第三行開始迴圈，直到最後一個非空行
    For i = 3 To r
        ' 檢查當前行第一列的單元格是否不為空
        If Cells(i, 1).Value <> "" Then
            ' 通過分割單元格值並取第一個元素來提取任務代碼
            tx = Split(Cells(i, 1).Value, " ")(0)
            ' 確定當前單元格合併區域的數量
            mr = Cells(i, 1).MergeArea.Count
            ' 如果存在合併的單元格
            If mr > 0 Then
                ' 遍歷合併區域中的每個單元格，排除第一個單元格（因此使用mr - 1）
                For Each Z In Cells(i, 2).Resize(mr - 1, 5)
                    ' 如果單元格包含"SR"字樣
                    If UCase(Z.Value) Like "*SR*" Then
                        ' 分割值以獲取SR編號，去除括號
                        sp = Split(Z.Value, "(")(0)
                        ' 從SR編號中移除"上架"、"下架"和空格
                        sp = Replace(sp, "上架", "")
                        sp = Replace(sp, "下架", "")
                        sp = Replace(sp, " ", "")
                        ' 用"▲"作為分隔符，將SR編號附加到任務代碼後面
                        tx = tx & "▲" & sp
                    End If
                Next
                ' 移動到下一列輸出位置
                c = c + 1
                ' 通過分隔符"▲"分割編譯後的任務代碼和SR編號
                sp0 = Split(tx, "▲")
                ' 將SR編號數組轉置並從當前列開始寫入工作表
                Cells(2, c).Resize(UBound(sp0) + 1, 1) = Application.Transpose(sp0)
            End If
        End If
    Next
End Sub
這段VBA宏的目的是將任務列表中的“SR”編號根據第一列指定的任務整理到不同的列中。它會先清除指定範圍的內容，接著處理資料並分割字串，最後將整理好的輸出轉置至工作表中。這些註解應該能幫助你理解這個宏的邏輯和流程。
作者: 准提部林    時間: 2023-12-23 14:45

使用陣列處理//A欄不合併也可以..只認非空
Sub Test_A1()
Dim Arr, Brr, i&, j%, R&, Rx&, C%, X%, T$
Arr = Range([f1], [a65536].End(3).MergeArea)
ReDim Brr(1 To UBound(Arr) * 5, 1 To 99)
For i = 3 To UBound(Arr)
    T = Split(Arr(i, 1) & " ", " ")(0)
    If T Like "BF工程[#]###" Then C = C + 1: R = 1: Brr(R, C) = T
    For j = 2 To UBound(Arr, 2)
        T = Split(Arr(i, j) & " ", " ")(1)
        If T Like "SR####(*" Then R = R + 1: Brr(R, C) = Split(T, "(")(0)
    Next j
    If R > Rx Then Rx = R
Next i
With Range("H2")
     .CurrentRegion.Clear
     .Resize(Rx, C) = Brr
End With
End Sub
作者: Andy2483    時間: 2023-12-25 15:03

本帖最後由 Andy2483 於 2023-12-26 08:36 編輯

謝謝論壇,謝謝各位前輩
後學藉此帖練習陣列與字典,學習方案如下,請各位前輩指教
執行前:
[attach]37178[/attach]

執行結果:
[attach]37179[/attach]

Option Explicit
Sub TEST()
Dim 資料陣列, 空陣列, 字典, 代號$, i&, j%, 結果列號&, 結果欄號%, 結果欄數%, 最大列數%, 工程別$, 關鍵字$
Set 字典 = CreateObject("Scripting.Dictionary")
關鍵字 = Left([B2], 4)
資料陣列 = Range([F3], [B65536].End(3)(2, 0))
ReDim 空陣列(1 To 1000, 1 To 100)
For i = 1 To UBound(資料陣列) - 1
   If InStr(資料陣列(i, 1), 關鍵字) = 0 Then GoTo i01
   結果欄號 = IIf(工程別 <> 資料陣列(i, 1), 結果欄號 + 1, 結果欄號)
   字典(i) = 結果欄號
   工程別 = 資料陣列(i, 1)
   字典(結果欄號 & "/r") = 1
   空陣列(1, 結果欄號) = Split(資料陣列(i, 1), " ")(0)
   資料陣列(i + 1, 1) = IIf(資料陣列(i + 1, 1) = "", 資料陣列(i, 1), 資料陣列(i + 1, 1))
i01: Next
結果欄數 = 結果欄號
For j = 2 To UBound(資料陣列, 2)
   For i = 1 To UBound(資料陣列)
      代號 = Split(資料陣列(i, j) & " ", " ")(1)
      If Not 代號 Like "[A-Z][A-Z]####*" Or 字典(i) = 0 Then GoTo i02
      結果欄號 = 字典(i)
      結果列號 = 字典(結果欄號 & "/r")
      結果列號 = 結果列號 + 1: 字典(結果欄號 & "/r") = 結果列號
      空陣列(結果列號, 字典(i)) = Left(代號, 6)
      If 最大列數 < 結果列號 Then 最大列數 = 結果列號
i02: Next
Next
With [H2]
     .CurrentRegion.ClearContents
     .Resize(最大列數, 結果欄數) = 空陣列
End With
End Sub
作者: 198188    時間: 2023-12-29 14:10

回復 5# 准提部林

執行時，到    Brr(R, C) = Split(T, "(")(0)這裏出錯。
能不能注釋一下程式的意思，方便我可以學習，謝謝！
作者: 198188    時間: 2023-12-30 10:03

[attach]37210[/attach][attach]37211[/attach]回復 2# singo1232001


送貨單
根據每個sheet  從左邊送貨單資料抽取資料，複製到右邊。
根據A欄的資料複製有尺寸的資料到N欄，同時複製欄B到欄P & 欄C到欄Q然後把這欄的資料分割開到欄O, R, S, T,
之後複製欄O到欄V , 然後根據欄O的貨架號讀取欄G 到欄W, 欄F 到欄X, 欄J到欄Y

排架表
根據BF 裏欄A的資料，有#001 - #009 （這個不固定有多少個）複雜新的SHEET 以#001 - #009 分別命名
BF 裏欄A 的#001 ，裏面有一些SR****，根據這些SR**** 讀取排架表裏面的資料複製到SHEET #001 裏面，然後做一個樞紐分析表
BF 裏欄A 的#002 ，裏面有一些SR****，根據這些SR**** 讀取排架表裏面的資料複製到SHEET #002裏面，然後做一個樞紐分析表
BF 裏欄A 的#003 ，裏面有一些SR****，根據這些SR**** 讀取排架表裏面的資料複製到SHEET #003裏面，然後做一個樞紐分析表
BF 裏欄A 的#004 ，裏面有一些SR****，根據這些SR**** 讀取排架表裏面的資料複製到SHEET #004裏面，然後做一個樞紐分析表
如此類推
作者: 198188    時間: 2023-12-30 10:04

[attach]37212[/attach][attach]37213[/attach]回復 5# 准提部林

送貨單
根據每個sheet  從左邊送貨單資料抽取資料，複製到右邊。
根據A欄的資料複製有尺寸的資料到N欄，同時複製欄B到欄P & 欄C到欄Q然後把這欄的資料分割開到欄O, R, S, T,
之後複製欄O到欄V , 然後根據欄O的貨架號讀取欄G 到欄W, 欄F 到欄X, 欄J到欄Y

排架表
根據BF 裏欄A的資料，有#001 - #009 （這個不固定有多少個）複雜新的SHEET 以#001 - #009 分別命名
BF 裏欄A 的#001 ，裏面有一些SR****，根據這些SR**** 讀取排架表裏面的資料複製到SHEET #001 裏面，然後做一個樞紐分析表
BF 裏欄A 的#002 ，裏面有一些SR****，根據這些SR**** 讀取排架表裏面的資料複製到SHEET #002裏面，然後做一個樞紐分析表
BF 裏欄A 的#003 ，裏面有一些SR****，根據這些SR**** 讀取排架表裏面的資料複製到SHEET #003裏面，然後做一個樞紐分析表
BF 裏欄A 的#004 ，裏面有一些SR****，根據這些SR**** 讀取排架表裏面的資料複製到SHEET #004裏面，然後做一個樞紐分析表
如此類推
作者: 准提部林    時間: 2023-12-30 16:47

回復 7# 198188


執行沒問題!!!
split 用來分割文字, "(" 是分割符
作者: 准提部林    時間: 2023-12-31 11:46

回復 9# 198188

先給"送貨單"//
程式碼沒什特別~~
[attach]37214[/attach]
作者: 准提部林    時間: 2024-1-1 13:03

回復 9# 198188

排架表..迴圈多層, 自行研究//
[attach]37216[/attach]
作者: 198188    時間: 2024-1-2 10:07

回復 11# 准提部林

因爲繁簡體問題，導致亂碼，導致無法運行。 因爲沒有原文，我無法修正亂碼部分。可否發一下原文給我修正。
Sub 戈()
Dim Arr, Xrr, Yrr, i&, j%, V, T$, T1$, TR, x&, y&
Call 睲埃戈
Arr = Range([L1], [A65536].End(xlUp).MergeArea)
ReDim Xrr(1 To UBound(Arr), 1 To 7)
ReDim Yrr(1 To UBound(Arr), 1 To 4)
For i = 15 To UBound(Arr)
    T = Arr(i, 1): V = Val(Arr(i, 10))
    If T Like "*L *W *H *" Then
       TR = Split(T, Chr(10)): T1 = Trim(TR(0))
       x = x + 1
       Xrr(x, 1) = T  'A 逆Τへ计沮
       Xrr(x, 2) = T1 '砯琜腹
       Xrr(x, 3) = Arr(i, 2) 'N.W.(瞓)
       Xrr(x, 4) = Arr(i, 3) 'G.W.(を)
       Xrr(x, 5) = Val(Mid(TR(3), 2)) 'W
       Xrr(x, 6) = Val(Mid(TR(2), 2)) 'L
       Xrr(x, 7) = Val(Mid(TR(4), 2)) 'H
    End If
    '----------------------------------
    If T1 <> "" And Arr(i, 6) <> "" And V <> 0 Then
       y = y + 1
       Yrr(y, 1) = T1 '砯琜腹
       Yrr(y, 2) = Arr(i, 7) '竚
       Yrr(y, 3) = Arr(i, 6) 'ず甧
       Yrr(y, 4) = V '计秖
    End If
i01: Next i
If x = 0 Then Exit Sub
With [N3].Resize(x, 7)
     .Value = Xrr
     .Borders.LineStyle = 1
     .WrapText = False
End With
With [v3].Resize(y, 4)
     .Value = Yrr
     .Borders.LineStyle = 1
End With
End Sub

Sub 睲埃?)
Range([T3], [N65536].End(xlUp)(3)).Delete Shift:=xlUp
Range([Y3], [V65536].End(xlUp)(3)).Delete Shift:=xlUp
End Sub
作者: 198188    時間: 2024-1-2 10:09

回復 12# 准提部林
因爲繁簡體問題，導致亂碼，導致無法運行。 因爲沒有原文，我無法修正亂碼部分。可否發一下原文給我修正。

Sub ╊だ()
Attribute ╊だ.VB_Description = "矗场狶  2024/1/1 魁籹エ栋"
Attribute ╊だ.VB_ProcData.VB_Invoke_Func = " \n14"
Dim Arr, Brr, Drr, Xrr, Yrr, xD, xS As Worksheet, vS As Worksheet, R&, S$, T$, i&, j&, k%, x&, y%, N&
Call 埃
Set xD = CreateObject("Scripting.Dictionary")
Set vS = Sheets("逼琜"): Xrr = vS.[a8:f8]
Arr = Range(vS.[b1], vS.[d65536].End(xlUp))
For i = 9 To UBound(Arr)
    T = Arr(i, 2)
    If T Like "SR####" Then xD(T) = vS.Cells(i, 2).MergeArea.Resize(, 5).Value
Next i
'-----------------------------
Set xS = Sheets("BF")
Arr = Range(xS.[f1], xS.[a65536].End(xlUp).MergeArea)
For i = 2 To UBound(Arr)
    If Arr(i, 1) Like "BF祘[#]###*" Then
       S = Mid(Arr(i, 1), 5, 4): N = 0
       Brr = xS.Cells(i, 1).MergeArea.Resize(, 5).Value
       ReDim Yrr(1 To 2000, 1 To 6)
       N = N + 1
       For y = 1 To 6: Yrr(N, y) = Xrr(1, Mid(123645, y, 1)): Next
       For j = 1 To UBound(Brr)
           For k = 2 To UBound(Brr, 2)
               If Brr(j, k) Like "*琜*SR####*" Then
                  T = Mid(Brr(j, k), 4, 6)
                  Drr = xD(T)
                  If IsArray(Drr) Then
                     For x = 1 To UBound(Drr)
                         N = N + 1
                         Yrr(N, 1) = "=row()-1"
                         Yrr(N, 2) = Drr(1, 1)
                         Yrr(N, 3) = Drr(1, 2)
                         Yrr(N, 4) = Drr(1, 5)
                         Yrr(N, 5) = Drr(1, 3)
                         Yrr(N, 6) = Drr(1, 4)
                     Next x
                  End If
               End If
           Next k
       Next j
       '-----------------------------------
       If N <= 1 Then GoTo i01
       Set vS = Sheets.Add(after:=vS): vS.Name = S
       With vS.[a1].Resize(N, 6)
            .Value = Yrr
            .Borders.LineStyle = 1
            .Sort Key1:=.Item(3), Order1:=xlAscending, _
                  Key2:=.Item(4), Order2:=xlAscending, _
                  Key3:=.Item(2), Order3:=xlAscending, Header:=xlYes
            T = "'" & S & "'!" & .Address
       End With
       '-----------------------------------
       ActiveWorkbook.PivotCaches.Add(SourceType:=xlDatabase, SourceData:=T).CreatePivotTable TableDestination:=vS.Range("i1"), TableName:="Pvt_1"
       vS.PivotTables("Pvt_1").AddFields RowFields:=vS.Range("C1"), ColumnFields:=vS.Range("d1")
       vS.PivotTables("Pvt_1").PivotFields(vS.Range("F1").Text).Orientation = xlDataField
    End If
    Application.CommandBars("PivotTable").Visible = False
i01: Next i
End Sub

Sub 埃()
Dim xS As Worksheet
Application.DisplayAlerts = False
For Each xS In Sheets
    If xS.Name Like "[#]###" Then xS.Delete
Next
End Sub


Sub ttt()
MsgBox Val("11 22")
End Sub
Sub Macro2()
'
' Macro2 エ栋
' 矗场狶  2024/1/1 魁籹エ栋
'

'
'   Columns("B:F").Select
  ActiveWorkbook.PivotCaches.Add(SourceType:=xlDatabase, SourceData:="'#001'!C1:f86").CreatePivotTable TableDestination:=Range("i1"), TableName:="枷だ猂1"
    'ActiveSheet.PivotTables("枷だ猂1").SmallGrid = False
    ActiveSheet.PivotTables("枷だ猂1").AddFields RowFields:=Range("C1"), ColumnFields:=Range("d1")
    ActiveSheet.PivotTables("枷だ猂1").PivotFields(Range("F1").Text).Orientation = xlDataField
End Sub
作者: 准提部林    時間: 2024-1-2 14:16

＜送貨單＞

Sub 取出資料()
Dim Arr, Xrr, Yrr, i&, j%, V, T$, T1$, TR, x&, y&
Call 清除資料
Arr = Range([L1], [A65536].End(xlUp).MergeArea)
ReDim Xrr(1 To UBound(Arr), 1 To 7)
ReDim Yrr(1 To UBound(Arr), 1 To 4)
For i = 15 To UBound(Arr)
    T = Arr(i, 1): V = Val(Arr(i, 10))
    If T Like "*L *W *H *" Then
       TR = Split(T, Chr(10)): T1 = Trim(TR(0))
       x = x + 1
       Xrr(x, 1) = T  'A 欄有尺寸的數據
       Xrr(x, 2) = T1 '貨架號
       Xrr(x, 3) = Arr(i, 2) 'N.W.(淨重)
       Xrr(x, 4) = Arr(i, 3) 'G.W.(毛重)
       Xrr(x, 5) = Val(Mid(TR(3), 2)) 'W
       Xrr(x, 6) = Val(Mid(TR(2), 2)) 'L
       Xrr(x, 7) = Val(Mid(TR(4), 2)) 'H
    End If
    '----------------------------------
    If T1 <> "" And Arr(i, 6) <> "" And V <> 0 Then
       y = y + 1
       Yrr(y, 1) = T1 '貨架號
       Yrr(y, 2) = Arr(i, 7) '位置
       Yrr(y, 3) = Arr(i, 6) '內容
       Yrr(y, 4) = V '數量
    End If
i01: Next i
If x = 0 Then Exit Sub
With [N3].Resize(x, 7)
     .Value = Xrr
     .Borders.LineStyle = 1
     .WrapText = False
End With
With [v3].Resize(y, 4)
     .Value = Yrr
     .Borders.LineStyle = 1
End With
End Sub

Sub 清除資料()
Range([T3], [N65536].End(xlUp)(3)).Delete Shift:=xlUp
Range([Y3], [V65536].End(xlUp)(3)).Delete Shift:=xlUp
End Sub
作者: 准提部林    時間: 2024-1-2 14:17

＜排架表＞

Sub 拆分工作表()
Dim Arr, Brr, Drr, Xrr, Yrr, xD, xS As Worksheet, vS As Worksheet, R&, S$, T$, i&, j&, k%, x&, y%, N&
Call 刪除工作表
Set xD = CreateObject("Scripting.Dictionary")
Set vS = Sheets("排架表"): Xrr = vS.[a8:f8]
Arr = Range(vS.[b1], vS.[d65536].End(xlUp))
For i = 9 To UBound(Arr)
    T = Arr(i, 2)
    If T Like "SR####" Then xD(T) = vS.Cells(i, 2).MergeArea.Resize(, 5).Value
Next i
'-----------------------------
Set xS = Sheets("BF")
Arr = Range(xS.[f1], xS.[a65536].End(xlUp).MergeArea)
For i = 2 To UBound(Arr)
    If Arr(i, 1) Like "BF工程[#]###*" Then
       S = Mid(Arr(i, 1), 5, 4): N = 0
       Brr = xS.Cells(i, 1).MergeArea.Resize(, 5).Value
       ReDim Yrr(1 To 2000, 1 To 6)
       N = N + 1
       For y = 1 To 6: Yrr(N, y) = Xrr(1, Mid(123645, y, 1)): Next
       For j = 1 To UBound(Brr)
           For k = 2 To UBound(Brr, 2)
               If Brr(j, k) Like "*架*SR####*" Then
                  T = Mid(Brr(j, k), 4, 6)
                  Drr = xD(T)
                  If IsArray(Drr) Then
                     For x = 1 To UBound(Drr)
                         N = N + 1
                         Yrr(N, 1) = "=row()-1"
                         Yrr(N, 2) = Drr(1, 1)
                         Yrr(N, 3) = Drr(1, 2)
                         Yrr(N, 4) = Drr(1, 5)
                         Yrr(N, 5) = Drr(1, 3)
                         Yrr(N, 6) = Drr(1, 4)
                     Next x
                  End If
               End If
           Next k
       Next j
       '-----------------------------------
       If N <= 1 Then GoTo i01
       Set vS = Sheets.Add(after:=vS): vS.Name = S
       With vS.[a1].Resize(N, 6)
            .Value = Yrr
            .Borders.LineStyle = 1
            .Sort Key1:=.Item(3), Order1:=xlAscending, _
                  Key2:=.Item(4), Order2:=xlAscending, _
                  Key3:=.Item(2), Order3:=xlAscending, Header:=xlYes
            T = "'" & S & "'!" & .Address
       End With
       '-----------------------------------
       ActiveWorkbook.PivotCaches.Add(SourceType:=xlDatabase, SourceData:=T).CreatePivotTable TableDestination:=vS.Range("i1"), TableName:="Pvt_1"
       vS.PivotTables("Pvt_1").AddFields RowFields:=vS.Range("C1"), ColumnFields:=vS.Range("d1")
       vS.PivotTables("Pvt_1").PivotFields(vS.Range("F1").Text).Orientation = xlDataField
    End If
    Application.CommandBars("PivotTable").Visible = False
i01: Next i
End Sub

Sub 刪除工作表()
Dim xS As Worksheet
Application.DisplayAlerts = False
For Each xS In Sheets
    If xS.Name Like "[#]###" Then xS.Delete
Next
End Sub
作者: 198188    時間: 2024-1-2 16:16

回復 16# 准提部林


    未免因爲中文亂碼無法運行，改了英文，但是出來的答案跟需求不一樣。
第一, 序號不是COPY  “SR/排架表" 裏的序號，而是每次按順序
第二，樓層有部分也不是根據“SR/排架表" 裏樓層
第三, 單元應該也是按照“SR/排架表" 裏單元讀取，不過出來的是所有貨架序號裏的第一個單元
舉例 下面是SR / 拍架表
序号        货架编号        货架序号        单元        数量        楼层
8                      GS201        SR2001                 FC130               1        02F       
9                                                                 FC117          1        02F       
10                                                                 FC116               1        02F       
11                                                                 FC133            1        06F       
12                                                                 FC117                1        02F       
13                                                                 FC118                1        06F       
14                                                                 FC133                1        06F       
然後BF 裏面有SR2001
出來的效果是下面這樣，就是直接COPY SR2001裏面的所有内容，然後貨架和貨架序號變成不合并，而且填滿每行。
序号        货架编号        货架序号        楼层        单元        数量
8                 GS201                 SR2001         02F                 FC130           1
9                 GS201                 SR2001                02F                 FC117           1
10                 GS201                 SR2001                02F          FC116           1
11                 GS201                 SR2001          02F          FC130       1
12                 GS201           SR2001                02F          FC117            1
13                 GS201                 SR2001                02F          FC116            1
14                 GS201                 SR2001                 02F         FC130             1
作者: 准提部林    時間: 2024-1-2 19:46

回復 17# 198188

疏忽沒改到//
Yrr(N, 4) = Drr(1, 5)
Yrr(N, 5) = Drr(1, 3)
Yrr(N, 6) = Drr(1, 4)
改成//
Yrr(N, 4) = Drr(x, 5)
Yrr(N, 5) = Drr(x, 3)
Yrr(N, 6) = Drr(x, 4)
作者: 准提部林    時間: 2024-1-2 19:49

回復 17# 198188

序號是用公式, 右方的有排序, 若不想排序就去掉吧!!!
作者: 198188    時間: 2024-1-3 08:04

回復 19# 准提部林

    Yrr(N, 1) = "=row()-1" 刪除了這個后，序號便空白，怎樣才能讀取SR 的相應序號？我試過改下面的方式，都顯示錯誤，不能執行程式。
     Yrr(N, 1) = Drr(x, -1)
     Yrr(N, 1) = Drr(x, 0)
     Yrr(N, 1) = Drr(1, -1)
     Yrr(N, 1) = Drr(1, 0)
作者: 准提部林    時間: 2024-1-3 14:08

回復 20# 198188

模擬的看不出來如何做序號, 之前用猜的//
[attach]37230[/attach]
作者: 198188    時間: 2024-1-3 14:49

回復 21# 准提部林


    感謝幫忙
作者: 198188    時間: 2024-2-6 15:00

回復 5# 准提部林


    https://forum.twbts.com/thread-24186-1-1.html
准大大，可否幫我看看這個帖子？
作者: 198188    時間: 2024-3-18 10:03

回復 21# 准提部林


    准大，不知道哪裏問題，只能出現SHEET "BF" 欄B-欄E 的資料，欄F 無法讀出來。



歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)