標題: [發問] 請問這一段公式可以簡化嗎？ [打印本頁]

---

作者: 星空乂羽翼    時間: 2023-6-8 11:03     標題: 請問這一段公式可以簡化嗎？

請問以下公式可以簡化嗎?

=INDEX($C$2:$D$9,MATCH("R1",$A$2:$A$9,0),MATCH($I$1,$C$1:$D$1,0))+INDEX($C$2:$D$9,MATCH("R2",$A$2:$A$9,0),MATCH($I$1,$C$1:$D$1,0))+INDEX($C$2:$D$9,MATCH("R3",$A$2:$A$9,0),MATCH($I$1,$C$1:$D$1,0))

麻煩各位大大了，謝謝 !

---

作者: 星空乂羽翼    時間: 2023-6-8 11:20

回復 1# 星空乂羽翼

以下為後學自行簡化的
=SUM(INDEX($C$2:$D$9,MATCH({"R1","R2","R3"},$A$2:$A$9,0),MATCH($I$1,$C$1:$D$1,0)))

不知是否各位大大有更好的寫法呢?

---

作者: hcm19522    時間: 2023-6-8 11:22

本帖最後由 hcm19522 於 2023-6-8 11:50 編輯

I5{=SUM(IFERROR(VLOOKUP(T(IF({1},F2:F9)),A:D,3+(I1=D1),),))
主鍵可重複=SUMPRODUCT(COUNTIF(F:F,A2:A9)*OFFSET(C2:C9,,D1=I1))

---

作者: 星空乂羽翼    時間: 2023-6-8 11:35

回復 3# hcm19522
感謝前輩的回覆
請問可以附上說明嗎?

---

作者: ML089    時間: 2023-6-8 13:43

本帖最後由 ML089 於 2023-6-8 18:23 編輯

=SUM(SUMIF(A:A,"R"&{1,2,3},OFFSET(C:C,,N(I1=D1),)))
需要用 CTRL+SHIFT+ENTER 三鍵輸入公式

---

作者: ML089    時間: 2023-6-8 18:36

=SUM(LOOKUP("R"&{1,2,3},A:A,OFFSET(C:C,,N(I1=D1))))
這公式也可以

---

作者: 星空乂羽翼    時間: 2023-6-9 16:04

回復 6# ML089

感謝大大解說及教學
後學受教了
果然公式可以很多變
全看怎麼應用
感謝前輩教學！

---

作者: 准提部林    時間: 2023-6-10 09:35

=SUMPRODUCT(SUMIF(A:A,F2:F9,OFFSET(C:C,,MATCH(I1,C1:E1,)-1)))

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)