標題:
[發問]
如何在查找對應中加入遇到3A、13A、23A...辨識為4、14、24...
[打印本頁]
作者:
olisun
時間:
2020-8-5 13:19
標題:
如何在查找對應中加入遇到3A、13A、23A...辨識為4、14、24...
本帖最後由 olisun 於 2020-8-5 13:22 編輯
在成交明細中，如果成交房屋有購買車位，則會在成交明細自動抓取該車位所對應的房屋戶別。 我設定=VLOOKUP(IF(VALUE(LEFT(控表!B19,LEN(控表!B19)-1))<=12,"B4F/"&LEFT(控表!B20,LEN(控表!B20)-1),IF(VALUE(LEFT(控表!B19,LEN(控表!B19)-1))<=25,"B3F/"&LEFT(控表!B20,LEN(控表!B20)-1),IF(VALUE(LEFT(控表!B19,LEN(控表!B19)-1))<=39,"B2F/"&LEFT(控表!B20,LEN(控表!B20)-1),"B1F/"&LEFT(控表!B20,LEN(控表!B20)-1)))),成交明細!$E$2:$AF$51,28,FALSE)。
因為消費者對4有忌諱，因此遇4就會以3A來代替(3A=4、23A=24、33A=34、43A=44)，但是遇到3A、23A、33A、43A，就會有問題。請問要如何設定當遇到3A...等，自動辨識為4...
[attach]32371[/attach]
[attach]32372[/attach][attach]32373[/attach]
作者:
准提部林
時間:
2020-8-5 15:25
X定義名稱改:
=VALUE(SUBSTITUTE(LEFT(控表!A2,LEN(控表!A2)-1),"3A",4))
C2公式:
=LOOKUP("z",IF({1,0},"",VLOOKUP("B"&MATCH(-X,-{999,39,25,12})&"F/"&X,成交明細!$E$2:$J$49,6,)&""))
或
=LOOKUP("z",IF({1,0},"",VLOOKUP("B"&5-MATCH(X,{0,13,26,40})&"F/"&X,成交明細!$E$2:$J$49,6,)&""))
作者:
jcchiang
時間:
2020-8-5 15:30
回復
1#
olisun
把名稱X=VALUE(LEFT(控表!G5,LEN(控表!G5)-1))增加判斷
X=IF(RIGHT(LEFT(控表!G5,LEN(控表!G5)-1),1)="A",VALUE(LEFT(控表!G5,LEN(控表!G5)-2)),VALUE(LEFT(控表!G5,LEN(控表!G5)-1)))
位置請自行調整
作者:
准提部林
時間:
2020-8-5 15:31
本帖最後由 准提部林 於 2020-8-5 15:33 編輯
43A = 44
第一個4還是同樣有忌~~
用3A3A 又有點怪
何不將4全用另一英文字與ABF避開取代,例如:V
4=V
14=1V
44=VV
作者:
olisun
時間:
2020-8-5 17:07
本帖最後由 olisun 於 2020-8-5 17:20 編輯
回復
2#
准提部林
受教了，原來還可以使用取代這個方法，另外請問當中的Z和B個代表甚麼?
作者:
olisun
時間:
2020-8-5 17:08
本帖最後由 olisun 於 2020-8-5 17:21 編輯
回復
3#
jcchiang
感謝，我就是這個點搞不清楚
作者:
olisun
時間:
2020-8-5 17:10
回復
4#
准提部林
謝謝，因為建築師的請照圖編號就是這樣編，如果用VV，大家會搞混
作者:
准提部林
時間:
2020-8-5 17:22
回復
5#
olisun
"z" 給lookup當索引, 除錯用, 不好解釋,
"B" >>
B
3F/13
不然用這個:
=IFERROR(VLOOKUP("B"&MATCH(-X,-{999,39,25,12})&"F/"&X,成交明細!$E$2:$J$49,6,)&"","")
作者:
olisun
時間:
2020-8-5 18:03
回復
8#
准提部林
不好意思，二種式子套進去，C2變成空白
作者:
olisun
時間:
2020-8-5 18:22
本帖最後由 olisun 於 2020-8-5 18:26 編輯
回復
8#
准提部林
抱歉，式子沒問題，是我弄錯了。不過成交明細6車、23A是有賣掉的，但是對應結果是空白
[attach]32374[/attach]
作者:
准提部林
時間:
2020-8-5 19:14
回復
10#
olisun
6大 = B4F/6
成交明細沒有~~
作者:
olisun
時間:
2020-8-7 00:11
回復
11#
准提部林
[attach]32380[/attach]
作者:
olisun
時間:
2020-8-7 01:17
回復
11#
准提部林
不好意思，有A的對應出來都是空白
作者:
jcchiang
時間:
2020-8-7 09:22
回復
13#
olisun
1.因為准大依你的需求將3A改為4
=VALUE(SUBSTITUTE(LEFT(控表!A2,LEN(控表!A2)-1),
"3A",4
))
但在"成交明細"資料仍是3A,所以找不到
把公式內的定義X改為定義Y即可
原資料定義Y=LEFT(控表!A2,LEN(控表!A2)-1)
=LOOKUP("z",IF({1,0},"",VLOOKUP("B"&MATCH(-X,-{999,39,25,12})&"F/"&
Y
,成交明細!$E$2:$J$49,6,)&""))
2.我提供的沒有將3A改為4,因為依你的資料3 & 4的車位樓層一樣(X<=12,X<=25,X<=39),所以直接用3來判斷
作者:
准提部林
時間:
2020-8-7 09:58
回復
12#
olisun
"車位號碼"有兩欄, 沒注意~~
=IFERROR(LOOKUP(1,-FIND("B"&MATCH(-X,-{999,39,25,12})&"F/"&X&"_",成交明細!$E$1:$E$49&"_"&成交明細!$G$1:$G$49&"_"),成交明細!$J$1:$J$49),"")
作者:
olisun
時間:
2020-8-7 10:01
本帖最後由 olisun 於 2020-8-7 10:08 編輯
回復
8#
准提部林
謝謝，不過有A的一樣是空白，另外請教一下MATCH(-X,-{999,39,25,12})這當中的-是甚麼作用?
作者:
olisun
時間:
2020-8-7 10:06
回復
14#
jcchiang
明白，謝謝
作者:
准提部林
時間:
2020-8-7 10:31
定義名稱:
X:=--SUBSTITUTE(LEFT(控表!A2,LEN(控表!A2)-1),"3A",4)
Y:'="B"&SUM(N(控表!X<={0,12,25,39,999}))&"F/"&控表!X
C2:
=LOOKUP("z",CHOOSE({1,2,3},"",VLOOKUP(Y,成交明細!$E:$J,6,),VLOOKUP(Y,成交明細!$G:$J,4,)))
或
=IFERROR(IFERROR(VLOOKUP(Y,成交明細!$E:$J,6,),VLOOKUP(Y,成交明細!$G:$J,4,)),"")
作者:
准提部林
時間:
2020-8-7 11:03
定義Y, 改成:
="B"&SUM(N(X<={0,12,25,39,999}))&"F/"&LEFT(A2,LEN(A2)-1)
[attach]32382[/attach]
看得眼都花~~
作者:
olisun
時間:
2020-8-7 11:22
回復
19#
准提部林
收到，謝謝指導
歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)
