標題: [發問] 兩個工作表的 commandbar [打印本頁]

---

作者: s13030029    時間: 2019-7-24 17:01     標題: 兩個工作表的 commandbar

我有自製工具列，但是當我開啟兩個檔案，要關閉其中一個檔案時，兩個檔案的commandbar都會被刪掉，要怎樣才能關掉一個檔案時，還能保留工作列?????????
[attach]31071[/attach]
[attach]31072[/attach]

---

作者: s13030029    時間: 2019-7-24 17:05

回復 1# s13030029
Thisworkbook 程式碼

1. '自訂工具列
   
2.     Dim Abar As CommandBar    '宣告工具列物件
   
3. 
   
4. Private Sub Workbook_Open()
   
5.     C = MsgBox("功能選單在上方工具列的「增益集」裡!!!", vbExclamation, "使用方法")
   
6.     For Each Abar In Application.CommandBars
   
7.         If Not Abar.BuiltIn Then Abar.Delete
   
8.     Next
   
9. 
   
10.     '宣告工具列按鈕物件
    
11.     Dim myButton1 As CommandBarButton  '選擇使用說明
    
12.     Dim myButton2 As CommandBarButton  '選擇管制計畫表
    
13.    
    
14.    '新增一個工具列
    
15.     Set Abar = Application.CommandBars.Add(Name:="畫面選擇")
    
16. With Abar
    
17. '畫面選擇----------------------------------------------
    
18.         '使用說明
    
19.         Set myButton1 = .Controls.Add(msoControlButton)
    
20.         With myButton1
    
21.             .Style = msoButtonIconAndCaption '同時顯示文字和小圖示
    
22.             .BeginGroup = True
    
23.             .Caption = "使用說明"            '顯示在工具列上的按鈕文字
    
24.             '.TooltipText = "畫面選擇"        '滑鼠移過去時，所顯示的提示文字
    
25.             .FaceId = 487                    '小圖示
    
26.             .Tag = "MyCustomTag"
    
27.            .OnAction = "選擇使用說明"        '設定按下此鍵時所要執行的巨集
    
28.         End With
    
29.         '管制計畫表
    
30.         Set myButton2 = .Controls.Add(msoControlButton)
    
31.         With myButton2
    
32.             .Style = msoButtonIconAndCaption '同時顯示文字和小圖示
    
33.             .BeginGroup = True
    
34.             .Caption = "管制計畫表"          '顯示在工具列上的按鈕文字
    
35.             '.TooltipText = "畫面選擇"        '滑鼠移過去時，所顯示的提示文字
    
36.             .FaceId = 69                     '小圖示
    
37.             .Tag = "MyCustomTag"
    
38.            .OnAction = "選擇管制計畫表"      '設定按下此鍵時所要執行的巨集
    
39.         End With
    
40.         .Position = msoBarTop                '工具列擺放在上層
    
41.         .Visible = True
    
42. End With
    
43. End Sub
    
44. 
    
45. Private Sub Workbook_BeforeClose(Cancel As Boolean)
    
46.     Dim Abar As CommandBar
    
47.     For Each Abar In Application.CommandBars
    
48.         If Not Abar.BuiltIn Then Abar.Delete
    
49.     Next
    
50. End Sub

複製代碼

---

作者: jackyq    時間: 2019-7-24 18:03

Private Sub Workbook_BeforeClose(Cancel As Boolean)
   
        If Excel.Application.Workbooks.Count = 1 Then
        Dim Abar As CommandBar
        For Each Abar In Application.CommandBars
            If Not Abar.BuiltIn Then Abar.Delete
        Next
        End If
        
    End Sub

---

作者: s13030029    時間: 2019-7-24 21:13

回復 3# jackyq
原來如此~瞭解了~謝謝~~

---

作者: s13030029    時間: 2019-8-6 14:47

回復 3# jackyq

大大妳好~
我有遇到一個問題，就是現在我有兩檔案，但是是不一樣的commandbar，我先打開一個後，再打開第二個時，第二個的commandbar會蓋掉第一個的commandbar，該怎麼辦@@

---

作者: jackyq    時間: 2019-8-6 15:54

本帖最後由 jackyq 於 2019-8-6 15:56 編輯

Private Sub Workbook_Open()

'    For Each Abar In Application.CommandBars
'         If Not Abar.BuiltIn Then Abar.Delete
'     Next

    '宣告工具列按鈕物件
    Dim myButton1 As CommandBarButton  '選擇使用說明
    Dim myButton2 As CommandBarButton  '選擇管制計畫表
   
   '新增一個工具列
    on error resume next
    Set Abar = Application.CommandBars.Add(Name:="畫面選擇")
   if err then exit sub
    on error goto 0
    C = MsgBox("功能選單在上方工具列的「增益集」裡!!!", vbExclamation, "使用方法")

With Abar
'畫面選擇----------------------------------------------
        '使用說明
        Set myButton1 = .Controls.Add(msoControlButton)
        With myButton1
            .Style = msoButtonIconAndCaption '同時顯示文字和小圖示
            .BeginGroup =

.................................................

---

作者: s13030029    時間: 2019-8-7 08:26

回復 6# jackyq [
謝謝大大~~
這樣的方法是可以用
就是同時顯示
但是還要想想要如何避免使用者去按到不是該檔案的工具列才行@@
畢竟巨集用的不一樣...Orz

---

作者: jackyq    時間: 2019-8-7 09:04

'自訂工具列
Dim Abar As CommandBar    '宣告工具列物件
Dim 已提示 As Boolean


Private Sub Workbook_Open()
    If 已提示 = False Then
       已提示 = True
       C = MsgBox("功能選單在上方工具列的「增益集」裡!!!", vbExclamation, "使用方法")
    End If
    For Each Abar In Application.CommandBars
        If Not Abar.BuiltIn Then Abar.Delete
    Next

    '宣告工具列按鈕物件
    Dim myButton1 As CommandBarButton  '選擇使用說明
    Dim myButton2 As CommandBarButton  '選擇管制計畫表
   
   '新增一個工具列
    Set Abar = Application.CommandBars.Add(Name:="畫面選擇")
With Abar
'畫面選擇----------------------------------------------
        '使用說明
        Set myButton1 = .Controls.Add(msoControlButton)
        With myButton1
            .Style = msoButtonIconAndCaption '同時顯示文字和小圖示
            .BeginGroup = True
            .Caption = "使用說明"            '顯示在工具列上的按鈕文字
            '.TooltipText = "畫面選擇"        '滑鼠移過去時，所顯示的提示文字
            .FaceId = 487                    '小圖示
            .Tag = "MyCustomTag"
           .OnAction = "選擇使用說明"        '設定按下此鍵時所要執行的巨集
        End With
        '管制計畫表
        Set myButton2 = .Controls.Add(msoControlButton)
        With myButton2
            .Style = msoButtonIconAndCaption '同時顯示文字和小圖示
            .BeginGroup = True
            .Caption = "管制計畫表"          '顯示在工具列上的按鈕文字
            '.TooltipText = "畫面選擇"        '滑鼠移過去時，所顯示的提示文字
            .FaceId = 69                     '小圖示
            .Tag = "MyCustomTag"
           .OnAction = "選擇管制計畫表"      '設定按下此鍵時所要執行的巨集
        End With
        .Position = msoBarTop                '工具列擺放在上層
        .Visible = True
End With
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Dim Abar As CommandBar
    For Each Abar In Application.CommandBars
        If Not Abar.BuiltIn Then Abar.Delete
    Next
End Sub

Private Sub Workbook_WindowActivate(ByVal Wn As Window)
Workbook_Open
End Sub

---

作者: s13030029    時間: 2019-8-7 13:19

回復 8# jackyq
謝謝大大~這是我要的~~
不過我想請問下面這段是什麼樣的用法???
Private Sub Workbook_WindowActivate(ByVal Wn As Window)
Workbook_Open
End Sub
是當視窗活動時再執行一次Workbook_Open嗎?

---

作者: jackyq    時間: 2019-8-7 21:14

回復 9# s13030029


視窗從 非活動 變成 活動 的那一霎那

再執行一次Workbook_Open

---

作者: s13030029    時間: 2019-8-8 08:11

回復 10# jackyq
那這個可以寫在巨集裡嗎?

---

作者: jackyq    時間: 2019-8-8 12:21

回復 9# s13030029


Private Sub Workbook_WindowActivate(ByVal Wn As Window)

End Sub

這段只能放 ThisWorkBook 裡面

否則不起作用

硬要放 module 要弄點麻煩的手段才能辦到

---

作者: s13030029    時間: 2019-8-8 13:03

回復 12# jackyq

瞭解~謝謝你的幫忙~~

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)