麻辣家族討論版版 - Powered by Discuz! Board

標題: [發問] 修正公式，以利適用變動的內容。 [打印本頁]

作者: Airman 時間: 2019-4-16 18:10 標題: 修正公式，以利適用變動的內容。

本帖最後由 Airman 於 2019-4-16 18:19 編輯

[attach]30413[/attach]

AZ7==SMALL(IF(MAX((LARGE((MATCH(OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),)=COLUMN($B:$AX)-1)*OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),COLUMN(A1))=OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49))*(OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49)/1%%+$B$71:$AX$71))=OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49)/1%%+$B$71:$AX$71,COLUMN($B:$AX)-1),MOD(ROW(A1),7))
陣列公式 ~~ 右拉到BB7再下拉填滿

目前AZ7的公式條件如下~
主條件=$B7:$AX7的前三大的數字(中式排名)；
如果主條件的前三大數字都為單1個時，則將其在$B1:$AX1的同欄對應數字依序填入AZ7︰BB7
副條件1=如果主條件1的其中某排名數，有2個(含)以上時，則選取其在$B71:$AX71的同欄對應數字較大之排名者，
並將選取後的前三大數字之在$B1:$AX1的同欄對應數字依序填入AZ7︰BB7
副條件2=如果主條件1的其中某排名數，有2個(含)以上，且其在$B71:$AX71的同欄對應數字亦相同時，則將該相同排名者全選取，
並將選取後的前三大數字之在$B1:$AX1的同欄對應數字依序填入AZ7︰BB7

修正原因︰
當$B1:$AX1的49個數字非由小而大排列(EX:Sheet1)時，其公式的答案無法隨$B1:$AX1的數字排列變動(EX:Sheet2&Sheet3)而變更。

PS︰這是小弟在本論壇擷取的函數公式，自己試了一天，無法讓AZ7公式都能適用於Sheet1~ Sheet3。

請問︰應該如何修正AZ7公式，以利公式都能適用於Sheet1~ Sheet3
懇請各位先進惠予賜教!謝謝!

作者: ML089 時間: 2019-4-17 09:14

選擇 AZ7:AZ9 三格
編輯欄貼上公式
=IFERROR(SMALL(IF(MAX(IF(COUNTIF($BC9:BC11,$B$1:$AX$1)=0,$B7:$AX7))=$B7:$AX7,$B$1:$AX$1),{1;2;3}),"")
陣列公式，三鍵輸入

選擇 AZ7:AZ9 三格，右拉複製公式

作者: ML089 時間: 2019-4-17 09:16

上公式僅在 Sheet2 測試

先上班去了，等中午我再看看

作者: ML089 時間: 2019-4-17 09:33

1樓公式補充說明，{1;2;3} 是概估同數最多3個，依目前表格可擴充至 1~7

作者: ML089 時間: 2019-4-17 10:36

再補充
往下的複製要選擇 AZ7:BB9，一次一個區域複製

作者: ML089 時間: 2019-4-17 10:48

剛剛檢查前面公式有錯誤

選擇 AZ7:AZ12 六格儲存格，貼上下列公式，以三鍵輸入公式
=IFERROR(SMALL(IF(MAX(IF(COUNTIF($AY7:AY12,$B$1:$AX$1)=0,$B7:$AX7))=$B7:$AX7,$B$1:$AX$1),{1;2;3;4;5;6}),"")

選擇 AZ7:BB13 七格儲存格，下拉至底複製公式

最後一組有異，是小計位置應該在70列位置，自行調整資料位置即可

作者: Airman 時間: 2019-4-17 12:35

回復 6# ML089

ML089版主︰午安!
呵~呵~好久沒有見識到"區域陣列"了~這讓小弟想起"臥龍"大師^^

公式OK~但這只寫到主條件=$B7:$AX7的前三大的數字(中式排名)的公式~
缺少再比對$B71:$AX71的副條件公式︰
副條件1=如果主條件1的其中某排名數，有2個(含)以上時，則選取其在$B71:$AX71的同欄對應數字較大之排名者，
並將選取後的前三大數字之在$B1:$AX1的同欄對應數字依序填入AZ7︰BB7

副條件2=如果主條件1的其中某排名數，有2個(含)以上，且其在$B71:$AX71的同欄對應數字亦相同時，則將該相同排名者全選取，
並將選取後的前三大數字之在$B1:$AX1的同欄對應數字依序填入AZ7︰BB7

以上謹請賜正!謝謝您^^

作者: Airman 時間: 2019-4-17 12:54

回復 6# ML089

不好意思，忘了附上範例~補上~
[attach]30417[/attach]
謝謝您!

作者: hcm19522 時間: 2019-4-17 13:05

=SMALL(IF(MAX((LARGE((MATCH(OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),)=COLUMN($B:$AX)-1)*OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),COLUMN(A1))=OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49))*(OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49)/1%%+$B$71:$AX$71))=OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49)/1%%+$B$71:$AX$71,$B$1:$AX$1),MOD(ROW(A1),7))

OR
BD7:BF7 下拉=IFERROR(INDEX($1:$1,AZ7+1),"")

作者: ML089 時間: 2019-4-17 13:23

回復 8# Airman

我是看你的的答案做的，不是大部分相同嗎?

我有點閱讀障礙，文字敘述不是看得很懂。

你的是2003版EXCEL，沒有IFERROR函數，若可以接受數字文字型態時，公式可以改為
AZ7:AZ12 =TEXT(SMALL(IF(MAX(IF(COUNTIF($AY7:AY12,$B$1:$AX$1)=0,$B7:$AX7))=$B7:$AX7,$B$1:$AX$1,99),{1;2;3;4;5;6}),"[<>99];;")

作者: Airman 時間: 2019-4-17 14:24

回復 9# hcm19522
hcm19522大大:您好!
感謝您的賜正!
只要COLUMN($B:$AX)-1
改成
IFERROR(INDEX($1:$1,AZ7+1),"")
是嗎?
2003版改成
IF(ISERROR(INDEX($1:$1,AZ7+1)),"",INDEX($1:$1,AZ7+1))
可以嗎?
小弟再研究看看^^"

作者: Airman 時間: 2019-4-17 14:36

回復 10# ML089

ML089版大:您好!
區域陣列或文字型皆可。
小弟有將您的6#的公式改為
=IF(ISERROR(SMALL(IF(MAX(IF(COUNTIF($AY7:AY12,$B$1:$AX$1)=0,$B7:$AX7))=$B7:$AX7,$B$1:$AX$1),{1;2;3;4;5;6})),"",SMALL(IF(MAX(IF(COUNTIF($AY7:AY12,$B$1:$AX$1)=0,$B7:$AX7))=$B7:$AX7,$B$1:$AX$1),{1;2;3;4;5;6}))
區域陣列

至於主條件副條件所得的答案，小弟有附在BD:BF供參
如果目前的8#範例您還不能清楚，沒關係!
小弟再做詳細一點並都加文字說明。
作好後再附上供參。
謝謝您^^

作者: hcm19522 時間: 2019-4-17 14:51

本帖最後由 hcm19522 於 2019-4-17 15:02 編輯

回復 11# Airman

非也 (最近為何有3人提此問題)
(方式一)原公式改最後紅字部分 ( COLUMN($B:$AX)-1-->$B$1:$AX$1)

(方式二)原公式當輔助 ,正確結果地方(BD7:BF7) ,另下簡單公式下拉

作者: Airman 時間: 2019-4-17 17:49

本帖最後由 Airman 於 2019-4-17 18:01 編輯

回復 13# hcm19522
hcm19522大大:
我想應該是同樣購買樂透App(最近很夯，G. PLAY商店排行第一名)，因為裡面的表格沒有統計，只能目視人工比對(我原來就是這樣用)。
謝謝您的指導!小弟再試試看^^

作者: Airman 時間: 2019-4-17 17:55

本帖最後由 Airman 於 2019-4-17 18:10 編輯

回復 10# ML089
[attach]30418[/attach]
ML089版主︰
呼~範例做好了^^
請您3個工作表都要看~因為怕圖文說明都放在一個工作表裡會很混亂，所以將3個情況各放在不同的工作表。
PS:
3個工作表的第7列,14列,.....,63列,69列的模擬數字不全同；BD︰BF有正確的答案供參。
為求簡明，只舉某一個排名只有2個同名者，也許也有某2個排名或某3個排名，其中或有3個或4個.....同名者。
以上謹供參考!謝謝您^^

作者: ML089 時間: 2019-4-17 22:13

AZ7:AZ12
=TEXT(SMALL(IF(LARGE($B7:$AX7+$B$71:$AX$71%%,1+COUNTIF($B7:$AX7,">="&INDEX(7:7,MATCH(--AY7,$1:$1,))))=$B7:$AX7+$B$71:$AX$71%%,$B$1:$AX$1,99),{1;2;3;4;5;6}),"[<>99];;")

作者: ML089 時間: 2019-4-17 22:17

[attach]30419[/attach]

作者: Airman 時間: 2019-4-17 23:19

回復 13# hcm19522
hcm19522大大︰晚安!
呵~呵~是小弟想太多了~
一直用INDEX和MATCH函數去改COLUMN($B:$AX)-1，弄了一天，都不是正解，
原來直接將COLUMN($B:$AX)-1改為 $B$1:$AX$1即可。
怪不得發問者沒有提出來，應該是他自己已經改好了!真汗顏^^///

測試完成如需求~
謝您的不吝指導!感恩^^

PS︰
您的幾個相類似的回答題中，小弟有關注到這一題和 http://forum.twbts.com/thread-21664-1-1.html，
因為這二題的統計範圍都很大，卻要能一式完成，實屬不易，所以特別擷取這一題來發問和應用。
後題因為還沒有看到完成需求的結果，所以還在關注中~很期待您的大作^^
最近我都盡量用輔助欄，將複雜的公式拆解成自己會寫的簡單公式，不然老是發問，也不是辦法。

作者: Airman 時間: 2019-4-17 23:20

回復 17# ML089
ML089版大︰晚安!
測試完成如需求~
謝謝您的不吝指導! 感恩^^

作者: Airman 時間: 2019-4-18 03:18

回復 13# hcm19522
hcm19522大大︰
請問︰貴公式如何改為前三小?
將MAX改為MIN；LARGE改為SMALL答案不對^^"

作者: Airman 時間: 2019-4-18 03:18

回復 17# ML089
ML089版大︰
請問︰貴公式如何改為前三小?
將LARGE改為SMALL答案不對^^"

作者: Airman 時間: 2019-4-18 09:03

本帖最後由 Airman 於 2019-4-18 09:04 編輯

回復 13# hcm19522

AZ7=SMALL(IF(MAX((LARGE((MATCH(OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),)=COLUMN($B:$AX)-1)*OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),COLUMN(A1))=OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49))*(OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49)/1%%+$B$71:$AX$71))=OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49)/1%%+$B$71:$AX$71,$B$1:$AX$1),MOD(ROW(A1),7))

hcm19522大大︰
請問︰貴公式如何改為最小,次小,第三小?
將MAX改為MIN；LARGE改為SMALL答案不對^^"
您謝謝^^

作者: Airman 時間: 2019-4-18 09:07

本帖最後由 Airman 於 2019-4-18 09:21 編輯

回復 17# ML089
=TEXT(SMALL(IF(LARGE($B7:$AX7+$B$71:$AX$71%%,1+COUNTIF($B7:$AX7,">="&INDEX(7:7,MATCH(--AY7,$1:$1,))))=$B7:$AX7+$B$71:$AX$71%%,$B$1:$AX$1,99),{1;2;3;4;5;6}),"[<>99];;")

ML089版大︰
請問︰貴公式如何改為最小,次小,第三小?
將LARGE改為SMALL答案不全對^^"
您謝謝^^

另外~
數值型態的最大,次大,第三大,最小,次小,第三小公式要怎麼改?
您謝謝^^

作者: ML089 時間: 2019-4-18 09:39

本帖最後由 ML089 於 2019-4-18 09:45 編輯

回復 23# Airman

選 BH7:BH12，貼上公式，陣列輸入(三鍵輸入)
=TEXT(SMALL(IF(SMALL($B7:$AX7+1/$B$71:$AX$71,1+COUNTIF($B7:$AX7,"<="&INDEX(7:7,MATCH(--BG7,$1:$1,))) )=$B7:$AX7+1/$B$71:$AX$71,$B$1:$AX$1,99),{1;2;3;4;5;6}),"[<>99];;")
選 BH7:BH12 右拉
選 BH7:BJ13 下拉

僅測試一組，其他你對一對吧!

作者: ML089 時間: 2019-4-18 09:47

回復 23# Airman

區域陣列要改為數值型，我還沒有新想法，可以用你上次的方法

把主要的公式 SMALL(.....) 定義程名稱，比較好維護公式。

作者: Airman 時間: 2019-4-18 11:14

回復 25# ML089
[attach]30425[/attach]
ML089版大︰
不好意思，沒有細查到">="，所以沒改到^^"
但改了之後(以您PO的公式)，答案還是只有AZ欄的答案正確，
右拉後~BA和BB二欄的答案不對(與AZ欄相同)
是小弟有哪裡錯了?
請賜正!謝謝您^^
=========================
=IFERROR(SMALL(IF(MAX(IF(COUNTIF($BC9:BC11,$B$1:$AX$1)=0,$B7:$AX7))=$B7:$AX7,$B$1:$AX$1),{1;2;3}),"")
可否能麻煩您將上述公式再+$B71︰$AX71的比對條件之公式PO上嗎?
名稱定義小弟自行處理。
謝謝您^^

作者: ML089 時間: 2019-4-18 11:47

回復 26# Airman

AZ7:AZ12 區域陣列公式
=TEXT(SMALL(IF(SMALL($B7:$AX7+$B$71:$AX$71%%,1+COUNTIF($B7:$AX7,"<="&INDEX(7:7,MATCH(--AY7,$1:$1,))) )=$B7:$AX7+$B$71:$AX$71%%,$B$1:$AX$1,99),{1;2;3;4;5;6}),"[<>99];;")
選AZ7:AZ12右拉

計算SMALL取數位置
注意 --AY7 配合AZ7:AZ12公式的左一格位置，利用 INDEX(MATCH( 查詢上個大小數值，利用COUNTIF算出 <= 該數值有幾個。

71列資料的比較
取大 $B$71:$AX$71%%
取小 1/$B$71:$AX$71

作者: Airman 時間: 2019-4-18 12:42

回復 27# ML089
ML089版大︰午安!
一時還沒辦法消化~有待小弟再多加研習。
謝謝您的耐心教導~感恩^^

作者: Airman 時間: 2019-4-18 20:02

回復 27# ML089
ML089版大︰您好!
計算SMALL取數位置==>已瞭解~謝謝您!
但~
取大 $B$71:$AX$71%%
取小 1/$B$71:$AX$71
還是不太瞭解(第1次接觸到%%)^^"
以貴解公式為例︰
前3大
=TEXT(SMALL(IF(LARGE($B7:$AX7+$B$71:$AX$71%%,1+COUNTIF($B7:$AX7,">="&INDEX(7:7,MATCH(--AY7,$1:$1,))))=$B7:$AX7+$B$71:$AX$71%%,$B$1:$AX$1,99),{1;2;3;4;5;6}),"[<>99];;")
前3小
=TEXT(SMALL(IF(SMALL($B7:$AX7+$B$71:$AX$71%%,1+COUNTIF($B7:$AX7,"<="&INDEX(7:7,MATCH(--AY7,$1:$1,))) )=$B7:$AX7+$B$71:$AX$71%%,$B$1:$AX$1,99),{1;2;3;4;5;6}),"[<>99];;")

為何前3大和前3小都是$B$71:$AX$71%%?

又以h大的公式為例︰
=SMALL(IF(MIN((SMALL((MATCH(OFFSET($B$1,LOOKUP(9^9,$AX65:$AX69,ROW(64:68)),,,49),OFFSET($B$1,LOOKUP(9^9,$AX65:$AX69,ROW(64:68)),,,49),)=COLUMN($B:$AX)-1)*OFFSET($B$1,LOOKUP(9^9,$AX65:$AX69,ROW(64:68)),,,49),COLUMN(A64))=OFFSET($B$1,LOOKUP(9^9,$AX65:$AX69,ROW(64:68)),,,49))*(OFFSET($B$1,LOOKUP(9^9,$AX65:$AX69,ROW(64:68)),,,49)/1%%+$B$71:$AX$71))=OFFSET($B$1,LOOKUP(9^9,$AX65:$AX69,ROW(64:68)),,,49)/1%%+$B$71:$AX$71,$B$1:$AX$1),MOD(ROW(A64),7))
其%%的位置又要如何修改為"取小"?

以上敬請賜教!謝謝您^^

作者: ML089 時間: 2019-4-18 22:34

回復 29# Airman

% = 1/100
%% = 1/10000
123% = 1.23
123%% = 0.0123

目前AZ7的公式條件如下~
主條件=$B7:$AX7的前三大的數字(中式排名)；
如果主條件的前三大數字都為單1個時，則將其在$B1:$AX1的同欄對應數字依序填入AZ7︰BB7
副條件1=如果主條件1的其中某排名數，有2個(含)以上時，則選取其在$B71:$AX71的同欄對應數字較大之排名者，
並將選取後的前三大數字之在$B1:$AX1的同欄對應數字依序填入AZ7︰BB7
副條件2=如果主條件1的其中某排名數，有2個(含)以上，且其在$B71:$AX71的同欄對應數字亦相同時，則將該相同排名者全選取，
並將選取後的前三大數字之在$B1:$AX1的同欄對應數字依序填入AZ7︰BB7

當取大或取小時，你的副條件1沒有改變 "$B71:$AX71的同欄對應數字較大之排名者"，
$B7:$AX7    = ,,,,,81,,,,,71,,,,,63,,,,,,81,,,,,
$B71:$AX71 = ,,,,,412,,362,,,319,,,,412,,
$B7:$AX7 + $B71:$AX71%% = ,,,,,81.0412,,,,71.0362,,,,63.0319,,,,,81.0412
使用 MAX 或 LARGE(...., 1) 都可以取出 81.0412

再去比對 if( LARGE(...,1) = $B7:$AX7 + $B$71:$AX$71%% , 是取出 $B$1:$AX$1,  否 ....)

若，副條件1 改變 "$B71:$AX71的同欄對應數字較 "小" 之排名者"
就使用 $B7:$AX7 + 1/$B71:$AX71

1/100    = 0.01 小數反數為大的小數
1/1000  =0.001  大數反數為小的小數

其他相同不再贅言，有不懂再問吧

作者: ML089 時間: 2019-4-18 23:21

回復 29# Airman

$B7:$AX7 = ,,,,,81,,,,,71,,,,,63,,,,,,81,,,,,
$B71:$AX71 = ,,,,,412,,362,,,319,,,,412,,
(1)
$B7:$AX7 + $B71:$AX71%% = ,,,,,81.0412,,,,71.0362,,,,63.0319,,,,,81.0412
(2)
$B7:$AX7/1%% + $B71:$AX71 = ,,,,,810412,,,,710362,,,,630319,,,,,810412

(1)與(2) 算是異曲同工

作者: Airman 時間: 2019-4-19 01:14

回復 30# ML089
ML089版主︰
請參閱附件!謝謝您^^
[attach]30427[/attach]

作者: ML089 時間: 2019-4-19 09:43

回復 32# Airman

$B7:$AX7 $B$71:$AX$71
取大取小
取大 LARGE($B7:$AX7 + $B$71:$AX$71%%, n) LARGE($B7:$AX7 + 1/$B$71:$AX$71, n)
取小 SMALL($B7:$AX7 + 1/$B$71:$AX$71, n) SMALL($B7:$AX7 + $B$71:$AX$71%%, n)

[attach]30428[/attach]

作者: Airman 時間: 2019-4-19 10:52

回復 33# ML089
ML089版主:您好!
瞭解了~小弟獲益良多。
謝謝您的耐心解惑，不勝感激^^

作者: Airman 時間: 2019-4-19 16:01

本帖最後由 Airman 於 2019-4-19 16:05 編輯

回復 9# hcm19522
h大:
請教您~下列貴解答公式要如何改為前3小名次有並排時，則$B$71:$AX$71取較小值~
=SMALL(IF(MAX((LARGE((MATCH(OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),)=COLUMN($B:$AX)-1)*OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49),COLUMN(A1))=OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49))*(OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49)/1%%+$B$71:$AX$71))=OFFSET($B$1,LOOKUP(9^9,$AX2:$AX7,ROW(1:6)),,,49)/1%%+$B$71:$AX$71,$B$1:$AX$1),MOD(ROW(A1),7))
以上敬請賜教 !謝謝您^^

作者: Airman 時間: 2019-4-19 16:21

回復 9# hcm19522
附上範例檔供參~
[attach]30435[/attach]

作者: hcm19522 時間: 2019-4-19 16:58

回復 35# Airman

參考
https://blog.xuite.net/hcm19522/twblog/587392713

作者: Airman 時間: 2019-4-19 17:44

本帖最後由 Airman 於 2019-4-19 17:46 編輯

回復 37# hcm19522
h大:
貴5欄一區段的解題大作，小弟已拜讀~佩服^^
另外~
能否請您再以35#的原公式作修改?
因為雖經過M大的諸多講解，對其公式是已知前3大和前3小的變化；
但應用到貴公式卻一直跑不出正確答案^^"
不好意思，給您增添麻煩，謝謝您^^
PS因為第一次遇到這種類型的解題公式，所以想多學習。

作者: hcm19522 時間: 2019-4-19 19:08

AZ7:BB7{=RIGHT(SMALL(IF(MATCH($B7:$AX7,$B7:$AX7,)=COLUMN($B:$AX)-1,$B7:$AX7/1%+$B$1:$AX$1),COLUMN(A1)),2)
複製到各行

作者: Airman 時間: 2019-4-19 19:52

回復 39# hcm19522
h大:
呵~呵~公式竟然變成這麼簡短~~厲害~~
粗看應該是缺少名次有並排者，其71列同欄數字也相同時，則該並排者全取的條件。
小弟先研究再說。
謝謝您的不吝指導~感恩^^

作者: hcm19522 時間: 2019-4-20 09:55

回復 40# Airman

修正 {=RIGHT(MIN(IF(SMALL(IF(MATCH($B7:$AX7,$B7:$AX7,)=COLUMN($B:$AX)-1,$B7:$AX7),COLUMN(A1))=$B7:$AX7,$B7:$AX7/1%+$B$1:$AX$1)),2)

作者: Airman 時間: 2019-4-20 11:13

回復 41# hcm19522
h大:
感謝您的再次回應^^
不好意思，還是沒有符合需求^^"
簡單說就是將9#的貴前3大的解答公式，改為前3小(含71列也是取同欄對應數的較小者)。
或請詳見~
http://forum.twbts.com/thread-21687-1-1.html
謝謝您^^

作者: hcm19522 時間: 2019-4-20 11:19

參考http://forum.twbts.com/viewthrea ... a=pageD1&page=2

歡迎光臨麻辣家族討論版版 (http://forum.twbts.com/)