標題: 同時比對二個值 [打印本頁]

---

作者: papaya    時間: 2018-4-22 11:48     標題: 同時比對二個值

[attach]28586[/attach]

測試檔[attach]28587[/attach]

文字說明︰
目前K2的公式只指定比對B欄︰H欄的各單列有顯示$J$1值，然後將K2的公式右移下拉填滿，
    則K欄︰R欄可顯示在B欄︰H欄有比對$J$1值的往下$J$2列之A欄︰H欄資料。
    EX︰Sheet1的J2=1時，則顯示K2︰R4的資料
EX︰Sheet2的J2=2時，則顯示K2︰R4的資料

想將K2公式指定B欄︰H欄各單列有顯示的比對值改為當列同時有顯示$I$1和$J$1二個數值，
即K2公式改變後，則Sheet1和Sheet2的K欄︰R欄應只顯示K2︰R2的資料。

請教︰
K2的函數公式要如何重新再編寫?
謝謝!

---

作者: papaya    時間: 2018-4-24 16:12

簡化說明︰
比對一個值($J$1)
K2
=INDEX(A:A,SMALL(IF($B$2:$H$50=$J$1,ROW($B$2:$H$50)+$J$2,4^8),ROW(A1)))&""

比對二個值($J$1&$I$1)
K2
=INDEX(A:A,SMALL(IF(($B$2:$H$50=$J$1)*($B$2:$H$50=$I$1),ROW($B$2:$H$50)+$J$2,4^8),ROW(A1)))&""

請教︰
比對二個值($J$1&$I$1)
K2正確的函數公式要如何重新再編寫?
謝謝!

---

作者: 准提部林    時間: 2018-4-24 19:21

回復 2# papaya

只要有一個相同就成立???
陣列公式
=INDEX(A:A,SMALL(IF(MMULT(COUNTIF($I$1:$J$1,$B$2:$H$50),{1;1;1;1;1;1;1})>0,ROW($2:$50)+$J$2,4^8),ROW($A1)))&""

同時兩個相同:
=INDEX(A:A,SMALL(IF(MMULT(COUNTIF($I$1:$J$1,$B$2:$H$50),{1;1;1;1;1;1;1})=2,ROW($2:$50)+$J$2,4^8),ROW($A1)))&""

---

作者: papaya    時間: 2018-4-24 19:48

回復 3# 准提部林

感謝您的回覆和熱心的指導。
答案正確誠如需求!感恩!

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)