標題: [發問] 當出現數字的欄位不一定時,如何用一致性公式求答案? [打印本頁]

---

作者: PJChen    時間: 2017-8-6 16:07     標題: 當出現數字的欄位不一定時,如何用一致性公式求答案?

求J欄的答案,該如何代入一致性的公式？   [attach]27591[/attach]
順位       
1        訂單數量
2        BOM
3        請購數量
4        採購數量
5        進貨數量
6        領料數量
*******
1        B,H是被減數的欄位
2        (A,D:H)-(H+ B)=J欄的答案
3        (A,D:H)欄只能用其中一個數字
4        該用哪一個數字以順位決定
5        當第1順位有數字時,用該數字-(H+ B)=J
6        每個順位都有數字時,以第1順位為優先
7        (A,D:H)欄,哪個欄位會出現數字,沒有一定

---

作者: PJChen    時間: 2017-8-6 17:39

補充：空的欄位要補0,不是空格.

---

作者: fengetianxia    時間: 2017-8-7 10:26

=OFFSET(A2,0,IF(A2<>"",1,MIN(IF(D2:H2<>"",COLUMN(D2:H2),9^9)))-1,1,1)-B2-H2
數組公式

---

作者: 准提部林    時間: 2017-8-7 11:40

本帖最後由 准提部林 於 2017-8-7 11:55 編輯

一般公式：
=IF(COUNT(A2,D2:H2),1/LOOKUP(9^9,1/N(OFFSET(A2,,{7,6,5,4,3,0}))),0)-B2-H2

或：陣列公式（三鍵輸入）
=IFERROR(IF(A2,A2,HLOOKUP("*",IF(D2:H2,D2:H2&""),1,))-B2-H2,0)

---

作者: PJChen    時間: 2017-8-7 21:45

回復 4# 准提部林
感謝大大,
二個公式都可以求得正確答案.

回復 4# fengetianxia
謝謝您,
不過代出的答案無法完全正確.

---

作者: PJChen    時間: 2017-8-7 23:13

回復 4# 准提部林

請教大大,

在實際作業中,有某些無效訂單,會導致所有的儲存格全部為0，但又不能刪除該列,這時我希望可以在J欄的待配顯示為0，請問該如何修改公式？

---

作者: Hsieh    時間: 2017-8-8 09:25

回復 6# PJChen
=IFERROR(LOOKUP(2,1/(N(OFFSET(A2,,{7,6,5,4,3,0}))<>0),N(OFFSET(A2,,{7,6,5,4,3,0})))-H2-B2,0)

---

作者: 准提部林    時間: 2017-8-8 10:56

回復 6# PJChen


=IF(SUM(A2,D2:H2),1/LOOKUP(9^9,1/N(OFFSET(A2,,{7,6,5,4,3,0})))-B2-H2,0)
第二個陣列公式IFERROR, 本來就可以除錯為0

若有問題, 最好提供檔案及實例~~~

---

作者: PJChen    時間: 2017-8-8 12:01

回復 7# Hsieh

咦,...大大 公式又不太一樣了,多學到一種,感謝.

---

作者: PJChen    時間: 2017-8-8 12:06

回復 8# 准提部林

是的,第一種全部儲存格為0時,會出現#N/A,看到Hsieh的公式之後,我知道可以在您原公式稍加修改也成.

=IFERROR(IF(COUNT(A10,D10:H10),1/LOOKUP(9^9,1/N(OFFSET(A10,,{7,6,5,4,3,0}))),0)-B10-H10,0)

第2種是原本就可以除錯.

感謝...

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)