標題: 不同列金額相乘加總問題 [打印本頁]

---

作者: msmplay    時間: 2016-8-24 21:08     標題: 不同列金額相乘加總問題

[attach]25039[/attach]

請問如何以公式統計D欄與F欄金額
說明:
C欄與E欄統計數據，來自「數據來源」對應產品欄列數字加總，例如C5=SUM(數據來源!E5:G6)、D6=SUM(數據來源!E7:G9)
D欄與F欄統計金額，則來自「數據來源」對應產品欄列數字加總，再相乘「數據來源」D欄金額後加總

目前遇到問題如下:
C產品於「數據來源」D5:D6金額均為9999，故總數量可以統一相乘9999
但D產品於「數據來源」D7為16732、D8為16999、D9為24499，所以需要三列數量相乘對應D欄金額後再加總，才能得出總金額

想請問以上是否可以公式達成呢？


[attach]25040[/attach]

---

作者: zyzzyva    時間: 2016-8-24 23:23

回復 1# msmplay
這應該用sumproduct就可以了吧？ex: D7=SUMPRODUCT(數據來源!D7:D9,數據來源!E7:E9)

---

作者: ML089    時間: 2016-8-26 17:15

本帖最後由 ML089 於 2016-8-27 20:26 編輯

D3 =SUMPRODUCT(數據來源!$D$3:$D$55*數據來源!$E$3:$P$55*
(LOOKUP(ROW($3:$55),ROW($3:$55)/(數據來源!$A$3:$A$55<>""),數據來源!$A$3:$A$55)=LOOKUP("嫻",$A$3:$A3))*
(LOOKUP(ROW($3:$55),ROW($3:$55)/(數據來源!$B$3:$B$55<>""),數據來源!$B$3:$B$55)=$B3)*
(LOOKUP(COLUMN($E:$P),COLUMN($E:$P)/(數據來源!$E$1:$P$1<>""),數據來源!$E$1:$P$1)=C$1))

D3公式下拉，再複製至F欄

---

作者: hcm19522    時間: 2016-8-27 11:18

本帖最後由 hcm19522 於 2016-8-27 11:21 編輯

D3=SUMPRODUCT((LOOKUP(ROW($3:$55),ROW($3:$55)/(數據來源!B$3:B$55<>""),數據來源!B$3:B$55)=B3)*(LOOKUP(ROW($3:$55),ROW($3:$55)/(數據來源!A$3:A$55<>""),數據來源!A$3:A$55)=LOOKUP(1,0/(A$3:A3<>""),A$3:A3))*數據來源!D$3:D$55*數據來源!E$3:G$55)
F3=SUMPRODUCT((LOOKUP(ROW($3:$55),ROW($3:$55)/(數據來源!B$3:B$55<>""),數據來源!B$3:B$55)=B3)*(LOOKUP(ROW($3:$55),ROW($3:$55)/(數據來源!A$3:A$55<>""),數據來源!A$3:A$55)=LOOKUP(1,0/(A$3:A3<>""),A$3:A3))*數據來源!D$3:D$55*數據來源!H$3:P$55)
F3 :複製D3不含 "=" 到F3 ,加 "=" ,再改E$3:G$55-->H$3:P$55

---

作者: msmplay    時間: 2016-8-29 22:15

回復 4# hcm19522

h大謝謝你~~~~~

---

作者: hcm19522    時間: 2016-8-30 15:02

回復 5# msmplay
請教二問題
一 .壓縮檔如何做 我經YAHOO FUNP 處理下載很慢   二 .SINGNATURE 底下文字 如產生

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)