麻辣家族討論版版 - Powered by Discuz! Board

標題: [發問] Listbox取資料問題 [打印本頁]

作者: Michelle-W 時間: 2016-8-9 16:40 標題: Listbox取資料問題

因最近剛碰自訂表單的部分
有爬問看了一下我想要的寫法
目前有個疑問
請問我的表單在sheet1
資料記錄在sheet2
要如何修改目前的程式碼才能讓Listbox1顯示sheet2 A欄全部的資料??
[attach]24882[/attach]
但A欄的資料會持續增加
目前也不曉得該如何修改.RowSource = "A2:A9"
可以自動讀取A欄有資料的部分??

請問有人可以指點一下嗎?
感謝感謝~~~
[attach]24883[/attach]

作者: c_c_lai 時間: 2016-8-9 16:59

回復 1# Michelle-W
請參考請問出勤系統設計

作者: Michelle-W 時間: 2016-8-9 17:21

回復 2# c_c_lai

我稍早有看過這篇
但我不懂為什麼她的Listbox可以顯示別的工作表的資料
看不太懂她的Listbox的程式碼意思...
還是您可以協助解釋一下她的意思?
為什麼Listbox可以顯示資料

非常感謝

Private Sub ListBox1_Change()
Dim AA(), xi As Integer

With ListBox1
      For xi = 0 To .ListCount - 1
         If .Selected(xi) = True Then
            AA = Application.Index(ListBox1.List, xi + 1)
            ' 陣列中抽出指定的元素陣列(這裡是一維陣列)
            TextBox2.Value = AA(1)
            TextBox3.Value = AA(2)
            TextBox4.Value = AA(3)
            TextBox5.Value = AA(5)
            comEnable TextBox5.Value, IIf(TextBox5.Value = "DA", True, False)
         End If
      Next
End With
End Sub

作者: lpk187 時間: 2016-8-9 17:21

Private Sub CommandButton1_Click()
'輸入的資料回傳至儲存格記錄
With Sheet2
'Set a = .[A65536].End(xlUp).Offset(1, 0)
'a.Resize(, 1) = Array(TextBox1)
ro = .[A65536].End(xlUp).Row + 1
.Cells(ro, 1) = TextBox1.Value
TextBox1.Value = ""
ListB1 '重設 ListBox1
End With
End Sub
Private Sub UserForm_Initialize()
ListB1
End Sub
Public Sub ListB1()
ro = Sheet2.[A65536].End(xlUp).Row
With ListBox1
.MultiSelect = fmMultiSelectMulti
.RowSource = "Sheet2!A2:A" & ro '如何使其資料顯示sheet2-A欄有資料的部分??
.ColumnCount = 2
End With
End Sub

複製代碼

回復 1# Michelle-W

作者: Michelle-W 時間: 2016-8-9 17:30

回復 4# lpk187

謝謝!!
您還幫我修改了CommandButton的程式碼
我還沒想到可以在CommandButton上面直接更新Listbox
非常感謝^^"

作者: c_c_lai 時間: 2016-8-9 17:33

回復 3# Michelle-W

Private Sub 列表框_Change()
Dim AA(), xi As Integer
With 列表框
For xi = 0 To .ListCount - 1
' 判斷列表框 (ListBox1) 是否有被點選
If .Selected(xi) = True Then
' 取出該行之數據，存入 AA 陣列中
AA = Application.Index(列表框.List, xi + 1)
' 陣列中抽出指定的元素陣列 (這裡是一維陣列)
工號.Value = AA(1)
姓名.Value = AA(2)
組別.Value = AA(3)
出勤站別.Value = AA(5)
' 同時存入出勤站別、出勤時數、以及改變可操機數之旗標
comEnable 出勤站別.Value, IIf(出勤站別.Value = "DA", True, False)
Exit For
End If
Next
End With
overTime
End Sub

複製代碼

作者: c_c_lai 時間: 2016-8-9 17:37

本帖最後由 c_c_lai 於 2016-8-9 17:42 編輯

回復 3# Michelle-W
模組：

Sub DA出勤()
Dim rng As Range
With DA出勤更新.列表框
'.MultiSelect = fmMultiSelectMulti ' => 1 : 列表框 (ListBox1) 屬性設定可複選
' fmMultiSelectSingle 0 只能選取一個專案( 預設)。
' fmMultiSelectSimple 1 按下空白鍵或按下滑鼠鍵，可以選取、
' 取消選取清單中的專案。
' fmMultiSelectExtended 2 按下SHIFT 並按下滑鼠鍵，或按下SHIFT
' 並按下一個方向鍵，可選取一個範圍內的所有專案。按下CTRL 並
' 按下滑鼠鍵，可選取或取消選取一個專案。
' .Visible = False
' .ColumnHeads = True
.ColumnCount = 5
' 指定下拉式清單方塊或清單方塊的顯示行數。
.ColumnWidths = "60,80,60,80,60"
' 指定多行下拉式清單方塊或清單方塊中的各行寬度。
End With
With Sheets("人力資料庫")
.Select
' Set rng = Range(.Range("C2:E" & .[E2].End(xlDown).Row), .Range("G2:G" & .[G2].End(xlDown).Row))
'Set rng = .Range("C2:E" & .[E2].End(xlDown).Row)
Set rng = Range(.[C1], .[G1].End(xlDown))
DA出勤更新.列表框.RowSource = rng.Address
End With
Sheets("操作介面").Select
DA出勤更新.Show
End Sub

複製代碼

附上備註 ( ' ) 可幫助你明白其為何及其作用。
[attach]24884[/attach]

作者: Michelle-W 時間: 2016-8-10 08:43

回復 7# c_c_lai

謝謝C大大
有您的解釋，我比較容易理解各程式碼的邏輯與作用了
真的非常感謝~~!!!

作者: Michelle-W 時間: 2016-8-10 15:48

回復 7# c_c_lai

C大~不好意思請教您一下
我想要選擇Listbox1中多個不連續的資料，可以存至sheet1的A欄中
資料是累積的，但我目前的程式碼執行起來怪怪的，請問哪邊錯了QQ?
可以麻煩您指點一下嗎? 感恩~

Private Sub CommandButton1_Click()
Dim AA(), xi As Integer
With ListBox1
      For xi = 0 To .ListCount - 1
         '  判斷列表框 (ListBox1) 是否有被點選
         If .Selected(xi) = True Then
            '  取出該行之數據，存入 AA 陣列中
            AA = Application.Index(ListBox1.List, xi + 1)
            Range("A1").Select
            Selection.End(xlUp).Select
            Sheets("sheet1").Range("a" & ActiveCell.Row + 1) = AA
            Exit For
         End If
      Next
End With

End Sub

作者: c_c_lai 時間: 2016-8-10 19:33

回復 9# Michelle-W
            Range("A1").Select
            Selection.End(xlUp).Select
            Sheets("sheet1").Range("a" & ActiveCell.Row + 1) = AA

你這三行指的是？

作者: GBKEE 時間: 2016-8-11 06:02

本帖最後由 GBKEE 於 2016-8-11 06:07 編輯

回復 9# Michelle-W

Private Sub CommandButton1_Click()
Dim AA(), xi As Integer
With ListBox1
For xi = 0 To .ListCount - 1
' 判斷列表框 (ListBox1) 是否有被點選
If .Selected(xi) = True Then
' 取出該行之數據，存入 AA 陣列中
AA = Application.Index(ListBox1.List, xi + 1)
Range("A1").Select
'*******************
Selection.End(xlUp).Select
'***'xlUp 往上 "A1"的往上還是在"A1"
Sheets("sheet1").Range("a" & ActiveCell.Row + 1) = AA
Exit For
End If
Next
End With
End Sub

複製代碼

A欄中資料如何累積的請說明
是這樣嗎?

Option Explicit
Private Sub Ex_CommandButton1_Click()
Dim AA(), xi As Integer
With ListBox1
For xi = 0 To .ListCount - 1
' 判斷列表框 (ListBox1) 是否有被點選
If .Selected(xi) = True Then
' 取出該行之數據，存入 AA 陣列中
AA = Application.Index(ListBox1.List, xi + 1)
With Range("A" & xi + 1)
'.Cells = AA
.Cells = .Cells + AA '資料是累積的
' Exit For '離開 For 迴圈
'*******************
'Listbox1中多個不連續的資料, Exit For 就不執行下一個 .Selected(xi) = True
'******************************
End If
Next
End With
End Sub
Option Explicit
Private Sub CommandButton1_Click()
Dim AA(), xi As Integer
With ListBox1
For xi = 0 To .ListCount - 1
' 判斷列表框 (ListBox1) 是否有被點選
If .Selected(xi) = True Then
' 取出該行之數據，存入 AA 陣列中
AA = Application.Index(ListBox1.List, xi + 1)
With Range("A" & Rows.Count).End(xlUp) '.Offset(1) '**還是下一儲存格
.Cells = AA
'還是 .Cells = .Cells + AA '資料是累積的
End With
'***Count 屬性傳回一個 Long (長整數)，等於在一個集合物件中的物件數目。
'Rows.Count : 工作表的最後一列
' ***Offset 屬性套用至 Range 物件時用 Offset 屬性。
'傳回 Range 物件，用以代表某個指定區域以外的範圍。唯讀。
'expression.Offset(RowOffset, ColumnOffset)
'Range("A" & Rows.Count).End(xlUp).Offset(1)
'工作表A欄底部 , 往上到有資料的儲存格, 的下一儲存格
'Exit For
End If
Next
End With
End Sub

複製代碼

作者: Michelle-W 時間: 2016-8-11 11:10

回復 10# c_c_lai

我想要將Listbox中所選擇的資料寫入A欄
可能邏輯寫錯了導致您看不懂QQ"

作者: Michelle-W 時間: 2016-8-11 11:16

回復 11# GBKEE

就是點選Listbox中的資料，填入sheet3的A欄
我自己嘗試過即使選擇了三筆，A欄資料也只會出現1筆

想要達到的功能如下圖
[attach]24903[/attach]
[attach]24904[/attach]

另外我也想要在Listbox點選可以刪除的功能
目前的程式碼會一直出現無法辨認的錯誤
不懂錯在哪邊QQ
不曉得可否一起幫我看看
感恩

[attach]24905[/attach]

作者: lpk187 時間: 2016-8-11 13:15

回復 13# Michelle-W

Private Sub 刪除_Click()
'還沒處理完,一直錯誤
Dim i As Integer
For i = home.ListBox1.ListCount - 1 To 0 Step -1 '程式所在位置在 home表單中可以省略 home.
If ListBox1.Selected(i) Then '即然等於True 就不用等於True了
home.ListBox1.RemoveItem (i) 'ListBox1的 list所指定的是清單來源，也就是說清單來源有改變ListBox1的清單才會改變
'所以這裡用RemoveItem是錯誤的，正確方式，應該刪除 Sheet2的資料，這裡先不幫你修正
End If
Next
End Sub

複製代碼

Private Sub 匯入_Click()
Dim AA(), xi As Integer
With ListBox1
For xi = 0 To .ListCount - 1
' 判斷列表框 (ListBox1) 是否有被點選
If .Selected(xi) Then '即然等於True 就不用等於True了
' 取出該行之數據，存入 AA 陣列中
AA = Application.Index(ListBox1.List, xi + 1)
''下列語句必須加入.End(xlUp)，這裡已幫你修正
With Sheets("sheet3").Range("A" & Rows.Count).End(xlUp).Offset(1) '.Offset(1) '**還是下一儲存格
'''''''''''''''''''''
'下面2個語法依你的需求擇一
.Cells = AA '單一儲存格使用
.Resize(, UBound(AA)) = AA '若使用多欄多列必須指定有多少的儲存格給它
'''''''''''
'還是 .Cells = .Cells + AA '資料是累積的
End With
'***Count 屬性傳回一個 Long (長整數)，等於在一個集合物件中的物件數目。
'Rows.Count : 工作表的最後一列
' ***Offset 屬性套用至 Range 物件時用 Offset 屬性。
'傳回 Range 物件，用以代表某個指定區域以外的範圍。唯讀。
'expression.Offset(RowOffset, ColumnOffset)
'Range("A" & Rows.Count).End(xlUp).Offset(1)
'工作表A欄底部 , 往上到有資料的儲存格, 的下一儲存格
'Exit For
End If
Next
End With
ListB1 '匯入後重新設定ListBox1
End Sub

複製代碼

作者: lpk187 時間: 2016-8-11 14:55

Private Sub 刪除_Click()
Dim arr() '設定一個空白陣列
Dim i As Integer
n = 0
For i = ListBox1.ListCount - 1 To 0 Step -1
If ListBox1.Selected(i) Then
n = n + 1
ReDim Preserve arr(1 To n) '重設陣列數目，增加陣列數目，
arr(n) = i + 2 '將欲刪除的列號記錄在陣列中，+2是從 (RowSource = "Sheet2!A2:A" & ro) 的A2計算列號
End If
Next
For Each ar In arr
Sheet2.Rows(ar).Delete '將記錄在陣列的列號一一刪除
Next
ListB1 '刪除後重設ListBox1
'這裡會分2個迴圈刪除是因為，當刪除Sheet2中記錄時會使得其他ListBox1.Selected為False
'(也就是說所有已選取的資料會變成無選取狀態)以致於只能刪除一列，
'故只有先記錄欲刪除的列號，再刪除其資料
End Sub

複製代碼

回復 13# Michelle-W

作者: Michelle-W 時間: 2016-8-11 15:36

回復 15# lpk187
回復 11# GBKEE
回復 10# c_c_lai

謝謝你還幫我解釋刪除的程式碼錯誤，我剛有自己研究了一下怎麼刪除儲存格
不過還是您比較快~哈哈

非常謝謝各位前輩們提供的程式碼
最重要的是都還有附上講解，讓小妹我能更快進入狀況
覺得很溫暖^^
非常感謝!!!

作者: GBKEE 時間: 2016-8-11 15:50

回復 16# Michelle-W
整理一下你的程式碼
可了解看看

Option Explicit
Dim Rng As Range, Msg As Boolean
Private Sub UserForm_Initialize()
Msg = MsgBox("ListBox 清單的來源。" & vbLf & "Yes=使用RowSource" & vbLf & "No= 使用List(陣列)", vbYesNo) = vbYes
ListB1
End Sub
Public Sub ListB1()
Dim RO As Integer
With Sheet2
RO = IIf(.Cells(Rows.Count, 1).End(xlUp).Row > 2, .Cells(Rows.Count, 1).End(xlUp).Row, 2)
Set Rng = .Range("A2:A" & RO)
End With
With ListBox1
.MultiSelect = fmMultiSelectMulti
If Msg Then
.RowSource = Rng.Address(, , , 1, 1)
Else
.List = Rng.Value
End If
.ColumnCount = Rng.Columns.Count
End With
End Sub
Private Sub 新增_Click()
'輸入的資料回傳至儲存格記錄
Dim RO As Integer
With Sheet2
RO = .[A65536].End(xlUp).Row + 1
.Cells(RO, 1) = TextBox1.Value
TextBox1.Value = ""
ListB1 '重設 ListBox1
End With
End Sub
Private Sub 刪除_Click()
Dim i As Integer, r As String, E As Variant
For i = home.ListBox1.ListCount - 1 To 0 Step -1
If home.ListBox1.Selected(i) = True Then
If Msg = False Then '**ListBox 清單的來源。No= 使用List(陣列)
home.ListBox1.RemoveItem (i)
ElseIf Msg = True Then '**ListBox 清單的來源。Yes=使用RowSource
r = IIf(r <> "", r & "," & i + 1, i + 1)
End If
End If
Next
If Msg = True Then
For Each E In Split(r, ",")
Rng.Rows(E).Delete '**刪除範圍中的資料 Yes=使用RowSource
Next
ListB1
End If
End Sub
Private Sub 匯入_Click()
Dim AA, xi As Integer
With ListBox1
For xi = 0 To .ListCount - 1
' 判斷列表框 (ListBox1) 是否有被點選
If .Selected(xi) = True Then
' 取出該行之數據，存入 AA 陣列中
AA = Application.Index(ListBox1.List, xi + 1)
'With Sheets("sheet3").Range("A" & Rows.Count).Offset(1) '.Offset(1) '**還是下一儲存格
With Sheets("sheet3").Range("A" & Rows.Count).End(xlUp).Offset(1) '.Offset(1) '**還是下一儲存格
.Cells = .Cells + AA
'還是 .Cells = .Cells + AA '資料是累積的
End With
End If
Next
End With
End Sub

複製代碼

作者: afu9240 時間: 2018-3-14 14:44

回復 15# lpk187

[attach]28440[/attach]

大大
想請教一下如果Listbox資料欄位比較多要如何匯入儲存格,依照您給的code要如何修改呢~~求解惑

歡迎光臨麻辣家族討論版版 (http://forum.twbts.com/)