標題: 字元取代 [打印本頁]

---

作者: fangsc    時間: 2016-7-27 11:56     標題: 字元取代

請教以下如何用函數判斷及取代字元.
字串 145001STM, 字串中"00" (字串的第4&5碼)用"-"取代, -更改後為 145-1STM
同時判斷, 如果字串為145010STM , 字串中"0"(字串的第4碼)用"-"取代, -更改後為 145-10STM
感謝.

---

作者: 准提部林    時間: 2016-7-27 14:03

=REPLACE(A1,4,3-LEN(MID(A1,4,2)*10),"-")
=REPLACE(A1,4,3,TEXT(MID(A1,4,3),"-#"))

145001STM　＞　145-1STM
145012STM　＞　145-12STM
145243STM　＞　145-243STM

---

作者: fangsc    時間: 2016-7-27 17:03

回復 2# 准提部林

謝謝版主.
因為會遇到以下的狀況,
145001STM　＞　145-1STM
145012STM　＞　145-12STM
210B001STM　＞　210-1STM
218-xxxx         >     不變 218-xxxx
不在以上範圍的＞　不變 12345xxx
所以把函數串在一起(如下),看起來有點卡卡, 不過答案還是出來了.
=IF(LEFT(F2,4)="210B",(REPLACE(F2,4,3,TEXT(MID(F2,3,1),"-#"))),(IF(LEFT($F2,3)="218",$F2,(IF(ISNUMBER(MID($F2,4,2)*10),(REPLACE($F2,4,3-LEN(MID($F2,4,2)*10),"-")),$F2)))))
感謝你.

---

作者: ML089    時間: 2016-7-28 00:03

=LEFT(A1,3)&SUBSTITUTE(SUBSTITUTE(MID(A1,4,2),"00",0),0,"-")&MID(A1,6,99)

---

作者: hcm19522    時間: 2016-7-28 11:54

=LEFT(A1,3)&"-"&MID(A1,MATCH(,0/MID(MID(A1,4,9),ROW($1:$9),1),)+3,9)

---

作者: ML089    時間: 2016-7-28 17:23

回復 3# fangsc

=LEFT(A1,3)&"-"&MID(A1,5+MAX((MID(A1,5,{1,2,3})=REPT(0,{1,2,3}))*{1,2,3}),99)

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)