標題: 請問一個vlookup的問題 [打印本頁]

---

作者: yan2463    時間: 2016-4-15 19:38     標題: 請問一個vlookup的問題

請問一個用相同股利及股利5%內的個股
如附件[attach]23862[/attach]

---

作者: 准提部林    時間: 2016-4-16 13:10

本帖最後由 准提部林 於 2016-4-16 13:11 編輯

Ａ１４．陣列公式：下拉
=INDEX(權息!A:A,SMALL(IF(ABS(ROUND(1-權息!D$3:D$2000/F$3,2))<=5%,ROW(D$3:D$2000),4^8),ROW(A1)))&""
　
Ｂ１４．一般公式：右拉．下拉
=IF($A14="","",VLOOKUP(--$A14,權息!$A:$D,2*COLUMN(A$1),))
　
　[attach]23883[/attach]

---

作者: yan2463    時間: 2016-4-16 19:53

回復 2# 准提部林

謝謝你,己經可以使用了

---

作者: yan2463    時間: 2016-4-18 09:18

回復 2# 准提部林

想再請問一個問題,若我也想找出正負5%的個股,公式不知如何寫

---

作者: 准提部林    時間: 2016-4-18 14:40

回復 4# yan2463


那公式就是正負5%

---

作者: yan2463    時間: 2016-4-19 07:24

回復 5# 准提部林

謝謝你,不好意思真的不懂公式

---

作者: yan2463    時間: 2016-4-20 13:46

回復 6# yan2463

想請問若我在權息中的N欄增加了一個股價欄位
想用股價的上下5%為條件,不是要修改用個公式
有試過好像不行

---

作者: yan2463    時間: 2016-4-22 08:51

回復 7# yan2463

另有二個問題是
問題二:R3以下列出,以C3的股價5%的個股
問題三:W3以下列出,以P3相同的個股
不知如何公式應該如何寫[attach]23924[/attach]

    如附件

---

作者: 准提部林    時間: 2016-4-22 10:33

Ｒ３．陣列公式：
=INDEX(權息!A:A,SMALL(IF(ISERR(0/(ABS(ROUND(1-權息!N$3:N$2000/C$3,2))<=5%)),4^8,ROW(D$3:D$2000)),ROW(A1)))&""
Ｓ３：=IF($R3="","",VLOOKUP(--$R3,權息!$A:$N,2,))
Ｔ３：=IF($R3="","",VLOOKUP(--$R3,權息!$A:$N,14,))
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
權息工作表．Ｏ３公式修改：
=IF(ISNA(VLOOKUP($A3,產業別!$A:$D,4,0)),"",VLOOKUP($A3,產業別!$A:$D,4,0))
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
Ｗ３．陣列公式：
=INDEX(權息!A:A,SMALL(IF(權息!O$3:O$2000=$P$3,ROW(D$3:D$2000),4^8),ROW(A1)))&""
Ｘ３：=IF($W3="","",VLOOKUP(--$W3,權息!$A:$O,2,))
Ｙ３：=IF($W3="","",VLOOKUP(--$W3,權息!$A:$O,15,))

---

作者: yan2463    時間: 2016-4-22 11:10

回復 9# 准提部林

謝謝你的幫忙,己經可以使用

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)