Board logo

標題: [發問] 備份文件巨集問題 [打印本頁]
作者: mycmyc    時間: 2010-10-19 21:38     標題: 備份文件巨集問題

本帖最後由 mycmyc 於 2010-10-19 22:33 編輯

請問 我模仿他人 做一個 備份巨集

Sub backup_file()
'把檔案作完整的備份在另外的路徑

TmpN1 = Format(Date, "yyyymmdd") '用今天的日期當作另存新檔的檔名
TmpN2 = Format(Time, "s") '用當時的秒數當取檔名的條件
ActiveWorkbook.SaveAs Filename:="C:\" & TmpN1 & "_" & TmpN2 & ".xls", FileFormat _
:=xlNormal, Password:="", WriteResPassword:="", ReadOnlyRecommended:= _
False, CreateBackup:=False

'備份檔案的路徑及檔名
ActiveWorkbook.SaveAs Filename:="E:\macro-test\test2\" & TmpN1 & "_" & TmpN2 & "B" & ".xls", FileFormat _
:=xlNormal, Password:="", WriteResPassword:="", ReadOnlyRecommended:= _
False, CreateBackup:=False

Workbooks.Open "C:\" & TmpN1 & "_" & TmpN2 & ".xls"
Workbooks(TmpN1 & "_" & TmpN2 & "B" & ".xls").Close SaveChanges:=False

End Sub
也做一個按鍵  我想按後 能出現一個信息"你確定要存檔嗎 " 有 "是"  "否"  
這備份檔 很怪 他會儲存到備份檔 但母檔 卻沒儲存到 便跳到 備份檔  
能幫我修正 母檔也儲存 並備份  並維持母檔開啟狀態 嗎
[attach]3289[/attach]

ActiveWorkbook.Save  解決 儲存母檔問題
作者: GBKEE    時間: 2010-10-20 07:48

回復 1# mycmyc
VBA問題  請到程式區
  1. Sub Ex()
  2.     Dim FS As Object, Tmpn1, Tmpn2
  3.     If MsgBox("你確定要存檔嗎 ?", vbYesNo + vbInformation) = vbYes Then
  4.         Set FS = CreateObject("Scripting.FileSystemObject")
  5.         Tmpn1 = "C:\" & Format(Now, "yyyymmdd_s ") & ".xls" '用今天的日期當作另存新檔的檔名
  6.         Tmpn2 = "E:\macro-test\test2\" & Format(Now, "yyyymmdd_s ") & "B.xls" '用今天的日期當作另存新檔的檔名
  7.         ActiveWorkbook.Save
  8.         FS.CopyFile ActiveWorkbook.FullName, Tmpn1
  9.         FS.CopyFile ActiveWorkbook.FullName, Tmpn2
  10.     End If
  11. End Sub
複製代碼
作者: mycmyc    時間: 2010-10-20 09:57

回復 2# GBKEE
  謝謝 訊息 已經解決
  但 ActiveWorkbook.Save  儲存都沒有問題，但是每次都會自動開啟Excel 檔案
     有沒有別的儲存方式可以自動存檔不會開啟 Excel 檔案!!!
      就是要留在主檔(母檔)
作者: GBKEE    時間: 2010-10-20 10:11

回復 3# mycmyc
每次都會自動開啟Excel 檔案   是完全依據我的程式嗎? 不會啊!
附上程式碼來看看?
作者: mycmyc    時間: 2010-10-20 12:13

回復 4# GBKEE

對不起 剛剛在修正後 如你程式ok
請問你 用那個控制 存檔後  還能在主檔上
FS.CopyFile ActiveWorkbook.FullName, Tmpn2
這行嗎?
作者: GBKEE    時間: 2010-10-20 13:33

回復 5# mycmyc
對的
     ActiveWorkbook.Save   '母檔需先做存檔的動作   
     FS.CopyFile ActiveWorkbook.FullName, Tmpn1
     FS.CopyFile ActiveWorkbook.FullName, Tmpn2
作者: mycmyc    時間: 2010-10-20 18:27

回復 6# GBKEE
   謝謝你  了解



歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)