標題: [發問] 文書處理-EXCEL-儲存格內選取某個字串 [打印本頁]

---

作者: a22497967    時間: 2015-12-19 15:15     標題: 文書處理-EXCEL-儲存格內選取某個字串

請教各位大大
沖555WELL-USDXXXXXXXXXXX
WELL-USDXXXXXXXXXXX
以上字串2種格式
我希望選取WELL(某個英文字，不一定是WELL)，WELL前面有時是數字，有時沒有就是WELL開頭(某個英文字，不一定是WELL)
請問各位大
我儲存格的參數該怎麼設定呢?

我目前是(假設A4)
=MID(A4,SEARCH("",A4),SEARCH("-",A4)-SEARCH("",A4))
可是這樣的情形下，沖555也會出現
請教一下
我該如何修改呢

---

作者: a22497967    時間: 2015-12-19 16:00

本帖最後由 a22497967 於 2015-12-19 16:02 編輯

這個問題主要是想讓工作更為簡便(沖銷外幣帳款)
我們會打上摘要
工司名-幣別金額-帳單號碼
EX:APPLE-USD30000*32.5-ABC1051010
這樣
小的在研究說
有沒有辦法
我把摘要轉到EXCEL上
工司及幣別、金額、匯率、帳單號碼
就會自動跑出來

---

作者: 准提部林    時間: 2015-12-19 17:14

回復 2# a22497967


1樓2樓說明邏輯有差異, 建議多舉些實例, 或直接上傳檔案~~

---

作者: a22497967    時間: 2015-12-19 18:14

本帖最後由 a22497967 於 2015-12-19 18:15 編輯

資料如附檔
我能直接由其他系統轉出
傳票編號
摘要
借方金額
貸方金額
其他部分都需要自己KEY
量大的時候....十分驚人><
所以想請教一下各位大大
要怎麼設計呢?

---

作者: a22497967    時間: 2015-12-19 18:39

准提部林大哥
剛看了您的部落格
大哥您真的真的好厲害喔.....
偶像><

---

作者: 准提部林    時間: 2015-12-19 19:22

本帖最後由 准提部林 於 2015-12-19 20:41 編輯

１．客戶名．比較麻煩，須確定以下：
　　名稱皆為英文？　第一字若為中文，固定是"沖"？　若含有日期，固定為４位數？
　　=MID(LEFT(H2,FIND("-",H2)-1),(LEFT(H2)="沖")*5+1,19)
２．幣別：=MID(LEFT(H2,FIND(C2&"*",H2)-1),FIND("-",H2)+1,9)　此公式依存〔金額〕
３．金額：=-LOOKUP(,-RIGHT(LEFT(H2,FIND("*",H2)-1),ROW($1:$15)))　此公式正確後，〔幣別〕才會正確
４．匯率：=-LOOKUP(,-MID(H2,FIND("*",H2)+1,ROW($1:$15)))
５．內容：=TRIM(RIGHT(SUBSTITUTE(H2,"-",REPT(" ",50)),50))

先這樣，有時間或有需要再調整∼∼

---

作者: yen956    時間: 2015-12-19 20:17

試試看:
先決條件:  "沖銷碼" 固定5碼, "幣別" 固定3碼, "內容" 固定10碼 (應該吧)       
A2=IF(LEFT(H2,1)="沖",MID(H2,6,FIND("-",H2)-6),MID(H2,1,FIND("-",H2)-1))
B2=MID(H2,FIND("-",H2)+1,3)
C2=--MID(H2,FIND("-",H2)+4,FIND("*",H2)-FIND("-",H2)-4)
D2=--MID(H2,FIND("*",H2)+1,LEN(H2)-FIND("*",H2)-11)
E2=RIGHT(H2,10)
執行結果:
[attach]22888[/attach]

---

作者: a22497967    時間: 2015-12-19 22:52

真的!!!!可以了
兩位真的好厲害
大部分的參數我都看過
可是真的.....還沒辦法如此活用...
太感謝了
我會努力的...><
謝謝兩位大大

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)