標題: [發問] 函數_連續多個同欄的對應值再顯示。 [打印本頁]

---

作者: Airman    時間: 2015-11-17 10:25     標題: 函數_連續多個同欄的對應值再顯示。

參考附件︰http://www.FunP.Net/917358

以不再增加名稱定義為原則。謝謝!

說明︰
名稱定義︰
R_R=$R7； T_3=T$3； T_5=T$5； X=$R7+T$3； Y=T$5-$R7； Z =MOD(T$5+Y,$R$6)
L_1=OR(T$5="",$R7="",$R7>=T$5,X=Y)

連續二個同欄的對應值再顯示。
Sheet1!T7
=IF(L_1,"",IF(OR(SUMIF(OFFSET($I$6,Y,1,,7),SUMIF(OFFSET($I$6,T$5,1,,7),$R$5,OFFSET($I$6,Z,1,,7)),OFFSET($I$6,MOD(Y*2,$R$6),1,,7))=OFFSET($I$6,X,1,,7)),Y,""))  
陣列
即當I欄T5期數的R5值，其在Z期數的同欄對應值，再出現在Y期數；
且該出現在Y期數的對應值，其在MOD(Y*2,$R$6)同欄的對應值，亦有出現在X期數。
則T7顯示Y值，否則顯示空白

連續三個同欄的對應值再顯示。
Sheet2!T7
=IF(L_1,"",IF(OR(SUM((SUMIF(OFFSET($I$6,Y,1,,7),SUMIF(OFFSET($I$6,T$5,1,,7),$R$5,OFFSET($I$6,Z,1,,7)),OFFSET($I$6,MOD(Y*2,$R$6),1,,7))=OFFSET($I$6,T$3,1,,7))*OFFSET($I$6,T$3+1,1,,7))=OFFSET($I$6,X,1,,7)),Y,""))
陣列
即當I欄T5期數的R5值，其在Z期數的同欄對應值，再出現在Y期數；
且該出現在Y期數的對應值，其在Y*2期數的同欄的對應值，亦有出現在T3期數；
且該出現在T3期數的對應值，其在T3+1期數的同欄對應值，亦有出現在X期數。
則T7顯示Y值，否則顯示空白

需求︰
請教更簡化的函數公式。

以上  懇請各位先進、前輩不吝賜教!  謝謝!

---

作者: Airman    時間: 2015-11-18 00:01

因應~本題基於『對應值再顯示』時的"欄位不同"而無法簡化~
恕將需求~『對應值再顯示』改為『對應值再顯示於"同欄位"』~謝謝!

詳如新附件:
http://www.FunP.Net/920227

---

作者: 准提部林    時間: 2015-11-18 22:07

回復 2# Airman

假如是這個意思：
{08,11,14,17,23,33,30}__T$5
{03,04,09,10,27,31,13}__Z
       ↓
{01,04,10,26,34,43,41}__Y
{13,29,30,32,33,34,43}__MOD(Y*2,$R$6)
       ↓
{04,29,31,37,42,48,45}__T$3
{01,12,26,29,37,43,49}__T$3+1
       ↓
{02,12,30,38,40,49,08}__X

Sheet2．Ｔ７：陣列
=IF(L_1,"",IF(AND(N(OFFSET($I$6,CHOOSE({1,2,3},Z,MOD(Y*2,$R$6),T$3+1),MATCH($R$5,OFFSET($I$6,T$5,1,,7),),))=N(OFFSET($I$6,CHOOSE({1,2,3},Y,T$3,X),MATCH($R$5,OFFSET($I$6,T$5,1,,7),),))),Y,""))
　
或：
=IF(L_1,"",IF(AND(MMULT({1,-1},N(OFFSET($I$6,CHOOSE({1,2,3;4,5,6},Z,MOD(Y*2,$R$6),T$3+1,Y,T$3,X),MATCH($R$5,OFFSET($I$6,T$5,1,,7),),)))=0),Y,""))

{4,29,12;4,29,12}　兩個區塊相減皆為０，成立∼∼
未多實測，試看看吧！（也想不出其他方法了）

---

作者: Airman    時間: 2015-11-18 23:29

回復 3# 准提部林

准大:
測試OK了~2個公式也分別成功套上Sheet1~
謝謝您的耐心指導~感恩
晚安

---

歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)