標題:
[發問]
功能問題詢問
[打印本頁]
作者:
xcz1597534@gmai
時間:
2015-11-9 21:34
標題:
功能問題詢問
假設A1~A3三個格子會隨機填入1~5(可重複)
A4要篩選出1~5哪個數字還沒被用過
這該用哪個函數??
作者:
xcz1597534@gmai
時間:
2015-11-9 21:39
補充一下:
最後的結果不是只挑出一個數字就好
是所有還沒被用到的數字都要挑出
作者:
mark761222
時間:
2015-11-10 00:28
本帖最後由 mark761222 於 2015-11-10 00:30 編輯
A4
=IF(COUNTIF(A1:A3,1)>=1,"",1)&IF(COUNTIF(A1:A3,2)>=1,"",2)&IF(COUNTIF(A1:A3,3)>=1,"",3)&IF(COUNTIF(A1:A3,4)>=1,"",4)&IF(COUNTIF(A1:A3,5)>=1,"",5)
複製代碼
IF(COUNTIF(A1:A3,1)>=1,"",1)
COUNIF 收詢範圍1有沒有出現，如果出現1次以上不顯示，沒出現顯示1, 其他全部用&串接起來
作者:
准提部林
時間:
2015-11-10 10:45
回復
2#
xcz1597534@gmai
只有三格，用三次的SUBSTITUTE取代即可：
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(12345,A1,""),A2,""),A3,"")
作者:
xcz1597534@gmai
時間:
2015-11-10 13:27
想請教兩位大大有沒有更簡易的方法
因為我上面只是舉例
真實情況可能範圍會到一百多
這樣函式會寫很長
作者:
准提部林
時間:
2015-11-10 13:37
回復
5#
xcz1597534@gmai
簡問簡答, 提供實例吧!
要讓公式連結字串, 項目多, 不用VBA就沒有簡單的方法,
逐一列出倒比較可行, 例如：列出1~39未出現號碼!!
作者:
hcm19522
時間:
2015-11-10 17:09
http://blog.xuite.net/hcm19522/twblog/335964037
參考
作者:
xcz1597534@gmai
時間:
2015-11-10 21:02
回復
7#
hcm19522
Thanks 我看看
作者:
xcz1597534@gmai
時間:
2015-11-10 21:05
回復
6#
准提部林
好~假設就A1~A100 會隨機填入1~100其中一個數字 (可重複)
A101要找出 1~100哪個數字沒出現過
作者:
准提部林
時間:
2015-11-10 21:27
回復
9#
xcz1597534@gmai
Ｂ１．
陣列公式
：下拉１００格，沒出現的逐一列出
=TEXT(SMALL(IF(ISNA(RANK(ROW($1:$100),A$1:A$100)),ROW($1:$100),999),ROW(A1)),"[<101]0;")
或：Ｂ１為最後結果，下拉１００格，數字以空白分隔
=TRIM(TEXT(SMALL(IF(ISNA(RANK(ROW($1:$100),A$1:A$100)),ROW($1:$100),999),ROW(A1)),"[<101]0;")&" "&B2)
想一個公式在一個儲存格得出結果，用VBA吧∼∼
歡迎光臨 麻辣家族討論版版 (http://forum.twbts.com/)
